WOLFRAM

Wolfram Language & System Documentation Center

ToRadicals[expr]

attempts to express all Root objects in expr in terms of radicals.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Generalizations & Extensions  
Options  
Assumptions  
Cubics  
Quartics  
Properties & Relations  
Possible Issues  
See Also
Tech Notes
Related Guides
History
Cite this Page

ToRadicals

ToRadicals[expr]

attempts to express all Root objects in expr in terms of radicals.

Details and Options

  • ToRadicals can always give expressions in terms of radicals when the highest degree of the polynomial that appears in any Root object is four.
  • There are some cases in which expressions involving radicals can in principle be given, but ToRadicals cannot find them.
  • If Root objects in expr contain parameters, ToRadicals[expr] may yield a result that is not equal to expr for all values of the parameters.
  • ToRadicals automatically threads over lists, as well as equations, inequalities, and logic functions.
  • ToRadicals takes the following options:
  • Assumptions Automaticassumptions on parameters
    Cubics Truewhether to use explicit radicals to solve all cubics
    Quartics Truewhether to use explicit radicals to solve all quartics

Examples

open all close all

Basic Examples  (2)

Convert Root objects to radicals:

Wolfram Language code: ToRadicals[Root[# ^ 3 + # + 11&, 1] + Root[# ^ 5 - 2&, 3]]

Convert a parametric Root object:

Wolfram Language code: ToRadicals[Root[# ^ 3 + a # - a ^ 2&, 1]]

Find the range of real a for which the radical representation is equal to the Root object:

Wolfram Language code: Reduce[% == Root[# ^ 3 + a # - a ^ 2&, 1], a, Reals]

Scope  (3)

All cubic Root objects can be converted into radicals:

Wolfram Language code: ToRadicals[Root[# ^ 3 - 5# ^ 2 - 7# + 9&, 1]]

All quartic Root objects can be converted into radicals:

Wolfram Language code: ToRadicals[Root[# ^ 4 + 3# ^ 3 - 5# ^ 2 - 7# + 9&, 1]]

Some higher‐degree Root objects can be represented in terms of radicals:

Wolfram Language code: ToRadicals[Root[# ^ 8 - 4# ^ 7 + 14# ^ 6 - 28# ^ 5 + 82# ^ 4 - 122# ^ 3 + 221# ^ 2 - 164# + 399&, 1]]
Wolfram Language code: Root[Cyclotomic[102, x], x, 1]
Wolfram Language code: ToRadicals[%]

ToRadicals also works with AlgebraicNumber objects:

Wolfram Language code: ToRadicals[AlgebraicNumber[Root[# ^ 3 - 11# + 3&, 1], {1, 2, 3}]]

Generalizations & Extensions  (1)

ToRadicals converts trigonometric functions of rational multiples of :

Wolfram Language code: ToRadicals[Sin[7Pi / 16]]
Wolfram Language code: ToRadicals[Tan[Pi / 19]]

Options  (6)

Assumptions  (2)

The setting of Assumptions affects conversion of parametric Root objects:

Wolfram Language code: rt = Root[(# - a)(# ^ 2 - a)&, 1]

With the default Automatic setting, the result may not be equivalent to the Root object:

Wolfram Language code: ToRadicals[rt]

When an assumption is given, the Root object is converted only if an equivalent result is found:

Wolfram Language code: ToRadicals[rt, Assumptions -> a >= 0]
Wolfram Language code: ToRadicals[rt, Assumptions -> a < 0]
Wolfram Language code: ToRadicals[rt, Assumptions -> True]

With AssumptionsNone, parametric Root objects are not converted:

Wolfram Language code: ToRadicals[Root[# ^ 3 - a&, 1] + Root[# ^ 3 - 2&, 1], Assumptions -> None]

Cubics  (2)

With Cubics->False the general formulas for solving cubic equations are not used:

Wolfram Language code: ToRadicals[Root[# ^ 3 - 5# ^ 2 - 7# + 9&, 1], Cubics -> False]

Converting some cubic Root objects does not require the general formulas:

Wolfram Language code: ToRadicals[Root[# ^ 3 - 3&, 1], Cubics -> False]

Quartics  (2)

With Quartics->False the general formulas for solving quartic equations are not used:

Wolfram Language code: ToRadicals[Root[# ^ 4 + 3# ^ 3 - 5# ^ 2 - 7# + 9&, 1], Quartics -> False]

Converting some quartic Root objects does not require the general formulas:

Wolfram Language code: ToRadicals[Root[# ^ 4 - 7# ^ 2 + 3&, 1], Quartics -> False]

Properties & Relations  (2)

RootReduce[ToRadicals[r]]==r for any algebraic number r given as a Root object:

Wolfram Language code: r = Root[# ^ 4 + 3# ^ 3 - 5# ^ 2 - 7# + 9&, 1];
Wolfram Language code: RootReduce[ToRadicals[r]] == r

By default Reduce will not produce radical solutions for general cubics:

Wolfram Language code: Reduce[x ^ 3 + x + 17 == 0, x]

Use ToRadicals to convert:

Wolfram Language code: ToRadicals[%]

Alternatively set Cubics->True:

Wolfram Language code: Reduce[x ^ 3 + x + 17 == 0, x, Cubics -> True]

Possible Issues  (3)

In this case ToRadicals succeeds on the unreduced expression:

Wolfram Language code: e = Sqrt[2] + Root[# ^ 3 + 11# + 3&, 1];
Wolfram Language code: ToRadicals[{e, RootReduce[e]}]

In this case ToRadicals succeeds on the reduced expression:

Wolfram Language code: e = RootReduce[Sqrt[2] + Root[# ^ 3 + 11# + 3&, 1]] - Sqrt[2];
Wolfram Language code: ToRadicals[{e, RootReduce[e]}]

ToRadicals converts Root objects containing parameters:

Wolfram Language code: ToRadicals[Root[# ^ 3 - a&, 1]]

The result may not be equal to the Root object for some values of the parameter:

Wolfram Language code: {Root[# ^ 3 - a&, 1], %} /. {{a -> -1}, {a -> 1}}
Wolfram Research (1996), ToRadicals, Wolfram Language function, https://reference.wolfram.com/language/ref/ToRadicals.html (updated 2010).

Text

Wolfram Research (1996), ToRadicals, Wolfram Language function, https://reference.wolfram.com/language/ref/ToRadicals.html (updated 2010).

CMS

Wolfram Language. 1996. "ToRadicals." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2010. https://reference.wolfram.com/language/ref/ToRadicals.html.

APA

Wolfram Language. (1996). ToRadicals. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ToRadicals.html

BibTeX

@misc{reference.wolfram_2026_toradicals, author="Wolfram Research", title="{ToRadicals}", year="2010", howpublished="\url{https://reference.wolfram.com/language/ref/ToRadicals.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_toradicals, organization={Wolfram Research}, title={ToRadicals}, year={2010}, url={https://reference.wolfram.com/language/ref/ToRadicals.html}, note=[Accessed: 13-June-2026]}