WOLFRAM

Wolfram Language & System Documentation Center

TogglerBar[x,{val1,val2,…}]

represents a toggler bar with setting x and with toggler buttons for values vali to include in the list x.

TogglerBar[Dynamic[x],{val1,val2,…}]

takes the setting to be the dynamically updated current value of x, with the values in the list x being reset every time a toggler button is clicked.

TogglerBar[x,{val1lbl1,val2lbl2,…}]

represents a toggler bar in which the toggler button associated with value vali has label lbli.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Options  
Appearance  
BaselinePosition  
Enabled  
Applications  
Properties & Relations  
See Also
Tech Notes
Related Guides
History
Cite this Page

TogglerBar

TogglerBar[x,{val1,val2,…}]

represents a toggler bar with setting x and with toggler buttons for values vali to include in the list x.

TogglerBar[Dynamic[x],{val1,val2,…}]

takes the setting to be the dynamically updated current value of x, with the values in the list x being reset every time a toggler button is clicked.

TogglerBar[x,{val1lbl1,val2lbl2,…}]

represents a toggler bar in which the toggler button associated with value vali has label lbli.

Details and Options

  • Multiple toggler buttons in a TogglerBar can be depressed at the same time. The values associated with all depressed buttons are given in a list.
  • The vali and lbli can be strings, boxes, graphics or any other expressions, including dynamic expressions. »
  • The following options can be given:
  • Appearance Automaticthe overall appearance of the toggler bar
    BaselinePosition Automaticalignment relative to surrounding text
    BaseStyle{}base style specifications for the toggler bar
    Enabled Automaticwhether the toggler bar is enabled, or grayed out
  • Possible settings for the Appearance option include:
  • "Horizontal"equally spaced horizontally
    "Vertical"equally spaced vertically
    "Row"laid out like text, allowing linewrapping
  • Appearance->"Vertical"->{h,w} will display the controls in a grid with the specified number of columns and rows, vertically filling each column in turn. Appearance->"Horizontal"->{h,w} horizontally fills the rows instead.
  • If one of h or w is Automatic, it is taken to be the smallest number so that all the controls will fit in the resulting grid. If both h and w are Automatic, they are calculated so the grid has roughly the same number of rows as columns.
  • The settings for BaseStyle are appended to the default style typically given by the "TogglerBar" style in the current stylesheet.

Examples

open all close all

Basic Examples  (2)

Create togglers with a specified state:

Wolfram Language code: TogglerBar[{2, 5}, Range[5]]

Dynamically change the value of :

Wolfram Language code: {TogglerBar[Dynamic[x], Range[5]], Dynamic[x]}

Scope  (2)

Include labels:

Wolfram Language code: TogglerBar[{1}, {1 -> " I ", 2 -> " II ", 3 -> " III "}]

Values and labels can be any expression:

Wolfram Language code: g = Plot[Sin[x], {x, 0, 2π}, Axes -> False, ImageSize -> 40]; f = Sqrt[y]Tan[α y - β]; s = "αβγ";
Wolfram Language code: {TogglerBar[Dynamic[x], {g, f, s}], Dynamic[x]}

Options  (6)

Appearance  (3)

Set the orientation:

Wolfram Language code: Table[TogglerBar[{}, Range[3], Appearance -> a], {a, {"Horizontal", "Vertical"}}]

"Row" allows linewrapping while "Horizontal" does not:

Wolfram Language code: TogglerBar[{}, Range[30], Appearance -> "Horizontal"]
Wolfram Language code: TogglerBar[{}, Range[30], Appearance -> "Row"]

Specify a three-column layout, with elements ordered vertically:

Wolfram Language code: TogglerBar[Dynamic[props], CityData["Properties"], Appearance -> "Vertical" -> {Automatic, 3}]

BaselinePosition  (1)

Align with surrounding text:

Wolfram Language code: Row[Table[TogglerBar[{2, 5}, Range[5], BaselinePosition -> p], {p, {Top, Center, Bottom}}], "xxx"]

Enabled  (2)

By default, TogglerBar is enabled:

Wolfram Language code: TogglerBar[{}, Range[5]]

By setting Enabled->False, the toggler bar is disabled but visible in its current state:

Wolfram Language code: TogglerBar[{2, 5}, Range[5], Enabled -> False]

Applications  (1)

Select what harmonics to show:

Wolfram Language code: DynamicModule[{x = {Graphics[{}, ImageSize -> 100, AspectRatio -> 1 / GoldenRatio]}, g = Table[Plot[Sin[n x], {x, 0, 2π}, ImageSize -> 100, Ticks -> None], {n, 3}]}, {TogglerBar[Dynamic[x], g], Dynamic[Show[x]]} ]

Properties & Relations  (2)

CheckboxBar is a special case of TogglerBar:

Wolfram Language code: {CheckboxBar[Dynamic[x], Range[5]], Dynamic[x]}
Wolfram Language code: {TogglerBar[Dynamic[y], Range[5]], Dynamic[y]}

TogglerBar is built using Toggler and can be used to track a list of values:

Wolfram Language code: {TogglerBar[Dynamic[x], Range[5]], Dynamic[x]}
Wolfram Language code: {Toggler[Dynamic[y]], Dynamic[y]}
Wolfram Research (2007), TogglerBar, Wolfram Language function, https://reference.wolfram.com/language/ref/TogglerBar.html.

Text

Wolfram Research (2007), TogglerBar, Wolfram Language function, https://reference.wolfram.com/language/ref/TogglerBar.html.

CMS

Wolfram Language. 2007. "TogglerBar." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/TogglerBar.html.

APA

Wolfram Language. (2007). TogglerBar. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/TogglerBar.html

BibTeX

@misc{reference.wolfram_2026_togglerbar, author="Wolfram Research", title="{TogglerBar}", year="2007", howpublished="\url{https://reference.wolfram.com/language/ref/TogglerBar.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_togglerbar, organization={Wolfram Research}, title={TogglerBar}, year={2007}, url={https://reference.wolfram.com/language/ref/TogglerBar.html}, note=[Accessed: 13-June-2026]}