WOLFRAM

Wolfram Language & System Documentation Center

VectorQ[expr]

gives True if expr is a list, none of whose elements are themselves lists, and gives False otherwise.

VectorQ[expr,test]

gives True only if test yields True when applied to each of the elements in expr.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Applications  
Properties & Relations  
See Also
Tech Notes
Related Guides
History
Cite this Page

VectorQ

VectorQ[expr]

gives True if expr is a list, none of whose elements are themselves lists, and gives False otherwise.

VectorQ[expr,test]

gives True only if test yields True when applied to each of the elements in expr.

Details

  • A vector is a list whose elements can be considered scalars.
  • A vector is also known as a flat list, a depth-1 array or a rank-1 array.
  • Possible representations of a vector include: »
  • {…} or List[…]an ordinary list
    SparseArray[…]a sparse list
    TabularColumn[…], QuantityArray[…], SymmetrizedArray[…], etc.a structured list
  • The empty list {} is a zero-length vector. »
  • Common values of test in VectorQ[expr,test] for use with numeric vectors include:
  • NumberQtest if expr is a vector of explicit numbers
    NumericQtest if expr is a vector of numeric expressions
    Positivetest if expr is a vector of positive numbers
    RealValuedNumberQtest if expr is a vector of numbers with head Integer, Rational or Real
    RealValuedNumericQtest if expr is a vector of numeric expressions with real values
  • Structural tests commonly used include:
  • IntegerQtest if expr is a vector of integers
    PolynomialQ[#,x]&test if expr is a vector of polynomials in x
    QuantityQtest if expr is a vector of quantities
    StringQtest if expr is a vector of strings

Examples

open all close all

Basic Examples  (3)

Test whether an object is a vector:

Wolfram Language code: VectorQ[{a, b, c}]

This is not a vector because there is an element that is itself a list:

Wolfram Language code: VectorQ[{1, {2, 3}}]

And this is not a vector as x is not any sort of a list:

Wolfram Language code: VectorQ[x]

Use specific tests to restrict particular kinds of numbers:

Wolfram Language code: VectorQ[{1, π, Sin[2]}, NumericQ]
Wolfram Language code: VectorQ[{1, π, Sin[2]}, NumberQ]

Scope  (7)

Many different heads can represent a vector:

Wolfram Language code: VectorQ[SparseArray[{{1} -> a, {5} -> b}]]
Wolfram Language code: VectorQ[TabularColumn[{1, 2, 3}, "Integer8"]]
Wolfram Language code: VectorQ[Quantity[{1.3, 2.2, 3.3}, "Meters"]]

Test for a vector with numeric entries:

Wolfram Language code: VectorQ[{E, 1, π, 2, Sin[1], Cos[2]}, NumericQ]

Test for a matrix with explicit numbers:

Wolfram Language code: VectorQ[{E, 1, π, 2, Sin[1], Cos[2]}, NumberQ]

Test for a vector of real-valued numeric quantities:

Wolfram Language code: VectorQ[{1, Pi, Sin[1], Sqrt[2]}, RealValuedNumericQ]

Faster test for explicit real-valued numbers:

Wolfram Language code: VectorQ[{1, Pi, Sin[1], 3 / 4}, RealValuedNumberQ]

Test for a vector of integers:

Wolfram Language code: VectorQ[Range[10], IntegerQ]

Test for a vector of numbers that are integers when rounded to two decimal places:

Wolfram Language code: VectorQ[{1, 1.005, 1.997}, Abs[# - Round[#]] < 0.005&]

Test for a vector of strings:

Wolfram Language code: VectorQ[{"a", "b", "c"}, StringQ]
Wolfram Language code: VectorQ[{"a", "b", x}, StringQ]

Test for a vector of polynomials in x:

Wolfram Language code: VectorQ[{1, x, 1 + x, x ^ 2 + 2x + 1}, PolynomialQ[#, x]&]
Wolfram Language code: VectorQ[{1, x, Sin[x], Exp[x]}, PolynomialQ[#, x]&]

Generalize VectorQ using a test:

Wolfram Language code: VectorQ[{{1}, {2, 3}}, ListQ]

The tested expression is not a vector by the standard definition:

Wolfram Language code: VectorQ[{{1}, {2, 3}}]

Applications  (1)

Define a function that only evaluates for vector arguments:

Wolfram Language code: f[v_ ? VectorQ] := Module[{v1 = Take[v, {1, -1, 2}], v2 = Take[v, {2, -1, 2}], n}, n = Length[v2]; v2 = (v2 - PadRight[v1, n, v1] ^ 2); v1 -= Range[Length[v1]]; v1.v1 + (Range[n]v2).v2];

Numerically find the minimum of the functions with components:

Wolfram Language code: TableForm[Quiet[Table[FindMinimum[f[v], {v, RandomReal[1, n]}], {n, 1, 5}]]]

Properties & Relations  (5)

An empty list is considered a zero-length vector:

Wolfram Language code: VectorQ[{}]

VectorQ[expr] is equivalent to ArrayQ[expr,1]:

Wolfram Language code: v = RandomReal[1, 3]
Wolfram Language code: {VectorQ[v], ArrayQ[v, 1]}

VectorQ[expr,test] is equivalent to Array[expr,1,test]:

Wolfram Language code: {VectorQ[v, MachineNumberQ], ArrayQ[v, 1, MachineNumberQ]}
Wolfram Language code: {VectorQ[v, IntegerQ], ArrayQ[v, 1, IntegerQ]}

For a matrix m, VectorQ[m,VectorQ] gives True:

Wolfram Language code: m = (| | | | - | - | | 1 | 2 | | 3 | 4 |); {MatrixQ[m], VectorQ[m, VectorQ]}

The converse of this statement is False:

Wolfram Language code: n = {{1, 2}, {3}}; {MatrixQ[n], VectorQ[n, VectorQ]}

VectorQ effectively uses AllowedHeads"ListLike":

Wolfram Language code: vec = SparseArray[{1, 2}]; expr = f[1, 2];
Wolfram Language code: {VectorQ[vec], VectorQ[expr]}
Wolfram Language code: {ArrayDepth[vec, AllowedHeads -> "ListLike"], ArrayDepth[expr, AllowedHeads -> "ListLike"]}
Wolfram Language code: {Dimensions[vec, AllowedHeads -> "ListLike"], Dimensions[expr, AllowedHeads -> "ListLike"]}

A function equivalent to VectorQ for ordinary lists:

Wolfram Language code: testf = MatchQ[#, List[args___ ? (Not[ListQ[#]]&)]]&
Wolfram Language code: vectors = {{}, {1, 2}, {1, {2}}, {{1, 2}}};
Wolfram Language code: TableForm[Table[{v, VectorQ[v], testf[v]}, {v, vectors}], TableDepth -> 2]
Wolfram Research (1988), VectorQ, Wolfram Language function, https://reference.wolfram.com/language/ref/VectorQ.html (updated 2003).

Text

Wolfram Research (1988), VectorQ, Wolfram Language function, https://reference.wolfram.com/language/ref/VectorQ.html (updated 2003).

CMS

Wolfram Language. 1988. "VectorQ." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2003. https://reference.wolfram.com/language/ref/VectorQ.html.

APA

Wolfram Language. (1988). VectorQ. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/VectorQ.html

BibTeX

@misc{reference.wolfram_2026_vectorq, author="Wolfram Research", title="{VectorQ}", year="2003", howpublished="\url{https://reference.wolfram.com/language/ref/VectorQ.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_vectorq, organization={Wolfram Research}, title={VectorQ}, year={2003}, url={https://reference.wolfram.com/language/ref/VectorQ.html}, note=[Accessed: 12-June-2026]}