WeierstrassHalfPeriodW1
WeierstrassHalfPeriodW1[{g2,g3}]
gives the half-period ω1 for Weierstrass elliptic functions corresponding to the invariants {g2,g3}.
Details
- Mathematical function, suitable for both symbolic and numerical manipulation.
- The half-periods define the fundamental period parallelogram for the Weierstrass elliptic functions.
- WeierstrassHalfPeriodW1 gives the first element ω1 returned by WeierstrassHalfPeriods.
- WeierstrassHalfPeriodW1 can be evaluated to arbitrary numerical precision.
- WeierstrassHalfPeriodW1 can be used with CenteredInterval objects. »
Examples
open all close allBasic Examples (3)
WeierstrassHalfPeriodW1[{11.0, 7}]Plot the real and imaginary parts of the first half-period:
Plot3D[{Re[WeierstrassHalfPeriodW1[{g2, g3}]], Im[WeierstrassHalfPeriodW1[{g2, g3}]]}, {g2, -4, 4}, {g3, 2, 10}]Compute the value of the Weierstrass 
function at the first half-period:
WeierstrassP[WeierstrassHalfPeriodW1[{11, 7}], {11, 7}]N[%]Scope (8)
Evaluate to arbitrary precision:
N[WeierstrassHalfPeriodW1[{11, 7}], 50]The precision of the output tracks the precision of the input:
WeierstrassHalfPeriodW1[{11, 7.00000000000000000000000000000000000}]Evaluate symbolically for the equianharmonic case:
WeierstrassHalfPeriodW1[{0, 1}]Evaluate symbolically for the lemniscatic case:
WeierstrassHalfPeriodW1[{1, 0}]WeierstrassHalfPeriodW1 has both singularities and discontinuities:
FunctionSingularities[WeierstrassHalfPeriodW1[{x, y}], x]//QuietFunctionDiscontinuities[WeierstrassHalfPeriodW1[{x, y}], x]//QuietWeierstrassHalfPeriodW1 is neither non-negative nor non-positive:
FunctionSign[WeierstrassHalfPeriodW1[{x, y}], {x, y}]However, it is positive in the first quadrant:
FunctionSign[{WeierstrassHalfPeriodW1[{x, y}], x > 0 && y > 0}, {x, y}, StrictInequalities -> True]WeierstrassHalfPeriodW1 is neither convex nor concave:
FunctionConvexity[WeierstrassHalfPeriodW1[{x, y}], {x, y}]WeierstrassHalfPeriodW1 can be used with CenteredInterval objects:
WeierstrassHalfPeriodW1[{CenteredInterval[1 + I, (1 + I) / 10 ^ 9], CenteredInterval[3 / 4, 1 / 10 ^ 9]}]TraditionalForm formatting:
WeierstrassHalfPeriodW1[{Subscript[g, 2], Subscript[g, 3]}]//TraditionalFormApplications (3)
Plot WeierstrassP over its real period:
Plot[WeierstrassP[u, {11, 7}], {u, 0, 2WeierstrassHalfPeriodW1[{11, 7.}]}]Compute the elliptic modulus 
corresponding to the pair of Weierstrass invariants 
and 
:
modulus[{g2_, g3_}] := Module[{ω1, ω3, τ},
ω1 = WeierstrassHalfPeriodW1[{g2, g3}];
ω3 = WeierstrassHalfPeriodW3[{g2, g3}];
τ = ω3 / ω1;
InverseEllipticNomeQ[Exp[I Pi τ]]
]modulus[{12.0, 7.0}]Compute the first lattice root ![TemplateBox[{{g, _, 2}, {g, _, 3}}, WeierstrassE1]](Files/WeierstrassHalfPeriodW1.en/5.png "TemplateBox[{{g, _, 2}, {g, _, 3}}, WeierstrassE1]"){kind=small}
:
e1[{g2_, g3_}] := Module[{ω1, ω3, τ, q},
ω1 = WeierstrassHalfPeriodW1[{g2, g3}];
ω3 = WeierstrassHalfPeriodW3[{g2, g3}];
τ = ω3 / ω1;q = Exp[I Pi τ];
(Pi / (2ω1)) ^ 2(EllipticTheta[2, q] ^ 4 + 2EllipticTheta[4, q] ^ 4) / 3
]e1[{12.0, 7.0}]Compare with the built‐in function value:
WeierstrassE1[{12.0, 7.0}]Compare with the expression in terms of WeierstrassP:
WeierstrassP[WeierstrassHalfPeriodW1[{12.0, 7.0}], {12.0, 7.0}]Properties & Relations (4)
WeierstrassHalfPeriods returns the pair 
and 
:
WeierstrassHalfPeriods[{8., -0.2}]{WeierstrassHalfPeriodW1[{8, -0.2}], WeierstrassHalfPeriodW3[{8, -0.2}]}WeierstrassP is periodic, with periods equal to twice the half-periods:
WeierstrassP[z + 2WeierstrassHalfPeriodW1[{g2, g3}], {g2, g3}]WeierstrassP[z + 2WeierstrassHalfPeriodW2[{g2, g3}], {g2, g3}]WeierstrassP[z + 2WeierstrassHalfPeriodW3[{g2, g3}], {g2, g3}]The half-periods 
, 
and 
of Weierstrass elliptic functions are not linearly independent:
Block[{g2 = 5, g3 = 1`20},
FindIntegerNullVector[{WeierstrassHalfPeriodW1[{g2, g3}], WeierstrassHalfPeriodW2[{g2, g3}], WeierstrassHalfPeriodW3[{g2, g3}]}]]This identity holds for all arguments:
0 == %.{WeierstrassHalfPeriodW1[{Subscript[g, 2], Subscript[g, 3]}], WeierstrassHalfPeriodW2[{Subscript[g, 2], Subscript[g, 3]}], WeierstrassHalfPeriodW3[{Subscript[g, 2], Subscript[g, 3]}]}//TraditionalFormWeierstrassP[z + WeierstrassHalfPeriodW1[{Subscript[g, 2], Subscript[g, 3]}] + WeierstrassHalfPeriodW2[{Subscript[g, 2], Subscript[g, 3]}] + WeierstrassHalfPeriodW3[{Subscript[g, 2], Subscript[g, 3]}], {Subscript[g, 2], Subscript[g, 3]}]WeierstrassHalfPeriodW1 gives a zero of WeierstrassPPrime in the lattice cell:
WeierstrassPPrime[WeierstrassHalfPeriodW1[{g2, g3}], {g2, g3}]Related Links
MathWorld
The Wolfram Functions SiteText
Wolfram Research (2017), WeierstrassHalfPeriodW1, Wolfram Language function, https://reference.wolfram.com/language/ref/WeierstrassHalfPeriodW1.html (updated 2023).
CMS
Wolfram Language. 2017. "WeierstrassHalfPeriodW1." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2023. https://reference.wolfram.com/language/ref/WeierstrassHalfPeriodW1.html.
APA
Wolfram Language. (2017). WeierstrassHalfPeriodW1. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/WeierstrassHalfPeriodW1.html