WOLFRAM

Wolfram Language & System Documentation Center

"CATHDatabase" (Service Connection)

Connect to the CATH Database API using the Wolfram Language to get information about protein domains and superfamilies.

Connecting & Authenticating

ServiceConnect["CATHDatabase"] creates a connection to the CATH database API.

Requests

ServiceExecute["CATHDatabase","request",params] sends a request to the CATH database API, using parameters params. The following give possible requests.

BioMolecule Structures

"BioMolecule" — get BioMolecule structure of a protein domain

Parameters:
  • "CATHDomainID"NoneCATH Domain ID

    • Protein Domain Summary

    "DomainDetails" — get information about a protein domain

    Parameters:
  • "CATHDomainID"NoneCATH Domain ID

    • Protein Superfamilies

    "Superfamilies" — get a list of all the protein superfamilies in the database

    Parameters:

    Protein Superfamily Details

    "SuperfamilyDetails" — get information about a protein superfamily

    Parameters:
  • "CATHSuperfamilyID"NoneCATH superfamily ID

    • Protein Superfamily Domains

    "SuperfamilyDomains" — get a list of all the protein domains in a superfamily

    Parameters:
  • "CATHSuperfamilyID"NoneCATH superfamily ID

    • Protein PDB IDs

    "PDBStructureIDs" — get a list of all the PDB structure IDs of proteins that contain at least one domain in the superfamily

    Parameters:
  • "CATHSuperfamilyID"NoneCATH superfamily ID

    • Graph of a Protein Superfamily

    "SuperfamilyGraph" — get the Graph of organization and hierarchy of domains in a protein superfamily

    Parameters:
  • "CATHSuperfamilyID"NoneCATH superfamily ID

    • Hierarchy of a Protein Superfamily

    "SuperfamilyHierarchy" — get information about domains at different levels of hierarchy of a protein superfamily

    Parameters:
  • "CATHSuperfamilyID"NoneCATH superfamily ID
    "Level"9level of hierarchy

    • Functional Families

    "FunctionalFamilies" — get all the functional families in a protein superfamily

    Parameters:
  • "CATHSuperfamilyID"NoneCATH superfamily ID

    • Functional Family Details

    "FunctionalFamilyDetails" — get detailed information about a functional family

    Parameters:
  • "CATHSuperfamilyID"NoneCATH superfamily ID
    "FunctionalFamilyID"Nonefunctional family ID

    • Functional Family Alignment

    "FunctionalFamilyAlignment" — get multiple sequence alignment of domains in a given functional family

    Parameters:
  • "CATHSuperfamilyID"NoneCATH superfamily ID
    "FunctionalFamilyID"Nonefunctional family ID

    • Information about Enzymes

    "EnzymeInformation" — get information about the enzymes associated with a superfamily

    Parameters:
  • "CATHSuperfamilyID"NoneCATH superfamily ID

    • Custom Domain Search

    "DomainSearch" — get list of domains associated with a specific amino acid sequence

    Parameters:
  • "BioSequence"Nonea BioSequence of type "Peptide"

    • Notes & Issues

    The CATH database provides a hierarchical classification of protein domains, derived from experimentally determined structures and organized by their three-dimensional features and evolutionary relationships.
    Domains are assigned Class(C), Architecture(A), Topology(T) and Homologous Superfamily(H), with further classifications for sequence similarity levels. Each domain has a unique identifier called the CATHSOLID ID.
    CATH also integrates functional annotations, including enzyme classifications and ligand interactions, and provides precomputed sequence alignments and domain family groupings.
    A protein domain is a self-stabilizing region of a polypeptide chain that folds independently into a compact three-dimensional structure. Many proteins contain multiple domains, and domains with very similar structures can occur in different proteins.
    Molecular evolution treats domains as modular building blocks that can be recombined to generate proteins with distinct functions.
    While a protein is the complete polypeptide chain with its biological roles, domains often serve as specific functional units.
    In systems like CATH, domains are grouped into superfamilies when there is evidence of common ancestry. CATH-Gene3D further organizes each superfamily into Functional Families that group domains sharing the same function.

    Examples

    open all close all

    Basic Examples  (3)

    Create a new connection to the CATH database:

    Wolfram Language code: cathdb = ServiceConnect["CATHDatabase"]

    Get the BioMolecule corresponding to a protein domain:

    Wolfram Language code: ServiceExecute[cathdb, "BioMolecule", <|"CATHDomainID" -> ExternalIdentifier["CATHDomainID", "3bd3A00"]|>]

    Visualize the BioMolecule:

    Wolfram Language code: BioMoleculePlot3D[%]

    Get details about the specific domain, with DomainID given as a string. The first four letters ("3bd3") of the domain ID corresponds to the PDB ID of the protein, followed by the chain ID ("A"), followed by the domain number in the chain ("00"):

    Wolfram Language code: ServiceExecute["CATHDatabase", "DomainDetails", <|"CATHDomainID" -> "3bd3A00"|>]

    The "BioSequence" is based on the residues observed in the ATOM records of the PDB file for this structure. The "COMBSSequence" is based on the residues observed in the SEQRES records of the PDB file for this structure. This can sometimes contain extra residues that were not able to be resolved in the 3D coordinates. Here is one such example:

    Wolfram Language code: ServiceExecute["CATHDatabase", "DomainDetails", <|"CATHDomainID" -> ExternalIdentifier["CATHDomainID", "1a22A00"]|>]

    Get details about the immunoglobulin superfamily:

    Wolfram Language code: ServiceExecute["CATHDatabase", "SuperfamilyDetails", <|"CATHSuperfamilyID" -> ExternalIdentifier["CATHSuperfamilyID", "2.60.40.10"]|>]

    Scope  (8)

    Get a list of all protein superfamilies in the CATH database:

    Wolfram Language code: ServiceExecute["CATHDatabase", "Superfamilies", <||>]

    Get a list of all protein domains belonging to a specific superfamily. CATHSOLID is the further classification of a protein superfamily based on sequence similarity and each domain has an unique CATHSOLID ID:

    Wolfram Language code: ServiceExecute["CATHDatabase", "SuperfamilyDomains", <|"CATHSuperfamilyID" -> "1.10.8.10"|>]

    Get a list of all the PDB structure IDs that contains at least one protein domain in a superfamily:

    Wolfram Language code: ServiceExecute["CATHDatabase", "PDBStructureIDs", <|"CATHSuperfamilyID" -> ExternalIdentifier["CATHSuperfamilyID", "1.10.8.10"]|>]//Shallow

    Get information about domains at different levels of hierarchy for a protein superfamily:

    Wolfram Language code: ServiceExecute["CATHDatabase", "SuperfamilyHierarchy", <|"CATHSuperfamilyID" -> ExternalIdentifier["CATHSuperfamilyID", "1.10.8.10"]|>]

    Define the level for which you want the domain information. The minimum level is 4 for CATH classification and the maximum level is 9 for all the way up to CATHSOLID:

    Wolfram Language code: ServiceExecute["CATHDatabase", "SuperfamilyHierarchy", <|"CATHSuperfamilyID" -> ExternalIdentifier["CATHSuperfamilyID", "1.10.8.10"], "Level" -> 6|>]

    Get all the functional families (domains having similar function) in a protein superfamily:

    Wolfram Language code: ServiceExecute["CATHDatabase", "FunctionalFamilies", <|"CATHSuperfamilyID" -> ExternalIdentifier["CATHSuperfamilyID", "1.10.8.10"]|>]

    Get detailed information about a functional family:

    Wolfram Language code: ServiceExecute["CATHDatabase", "FunctionalFamilyDetails", <|"CATHSuperfamilyID" -> ExternalIdentifier["CATHSuperfamilyID", "1.10.8.10"], "FunctionalFamilyID" -> 1|>]

    Get the multiple sequence alignment for domains related to a functional family:

    Wolfram Language code: ServiceExecute["CATHDatabase", "FunctionalFamilyAlignment", {"CATHSuperfamilyID" -> ExternalIdentifier["CATHSuperfamilyID", "1.10.8.10"], "FunctionalFamilyID" -> 2}]

    Get information about the enzymes associated with a superfamily:

    Wolfram Language code: ServiceExecute["CATHDatabase", "EnzymeInformation", {"CATHSuperfamilyID" -> ExternalIdentifier["CATHSuperfamilyID", "1.10.8.10"]}]

    Generalizations & Extensions  (2)

    Obtain a Graph for a superfamily where domains are grouped by their CATHSOLID IDs:

    Wolfram Language code: graph = ServiceExecute["CATHDatabase", "SuperfamilyGraph", <|"CATHSuperfamilyID" -> ExternalIdentifier["CATHSuperfamilyID", "1.10.8.10"]|>]

    Here is a neater way to see the organization and hierarchy based on CATHSOLID classification:

    Wolfram Language code: vertexStyle = Thread[VertexList[graph] -> ColorData["Rainbow"] /@ Rescale[GraphDistance[graph, #, "1"]& /@ VertexList[graph]]]; colors = (ColorData["Rainbow"] /@ Rescale@Range@9)[[-6 ;; -1]]; labels = {"Level 1: Same superfamily (CATH)", "Level 2: 35% sequence similarity (CATHS)", "Level 3: 60% sequence similarity (CATHSO)", "Level 4: 95% sequence similarity (CATHSOL)", "Level 5: 100% sequence similarity (CATHSOLI)", "Level 6: 100% sequence similarity, unique domains (CATHSOLID)"}; legend = SwatchLegend[colors, labels, LegendMarkers -> "Bubble"]; Legended[Graph[graph, VertexLabels -> Placed["Name", Tooltip], VertexStyle -> vertexStyle, GraphLayout -> "RadialEmbedding"], Placed[legend, Bottom]]

    Get information about the domains associated with a specific amino acid sequence. Here, search for a sequence found in a protein in the ESM Metagenomic Atlas that is similar to known protein structures in nature:

    Wolfram Language code: ServiceExecute["CATHDatabase", "DomainSearch", {"BioSequence" -> ServiceExecute["ESMAtlas", "Sequence", {"MGnifyID" -> "MGYP003566250623"}]}]

    See how the first domain obtained from CATH Database search aligns with the structure in the ESM Metagenomic Atlas. Obtain the structures of the domain and from the ESM Metagenomic Atlas:

    Wolfram Language code: {biomolDomain, biomolESM} = {ServiceExecute["CATHDatabase", "BioMolecule", {"CATHDomainID" -> %[[1, "ExampleCATHDomainID"]]}], ServiceExecute["ESMAtlas", "PredictedStructure", {"MGnifyID" -> ExternalIdentifier["MGnifyProteinID", "MGYP003566250623"]}]}

    Visualize the two structures:

    Wolfram Language code: BioMoleculePlot3D /@ {biomolESM, biomolDomain}

    Align the two structures:

    Wolfram Language code: bmalign = BioMoleculeAlign[biomolESM, biomolDomain]

    Visualize the alignment:

    Wolfram Language code: BioMoleculePlot3D[{biomolESM, bmalign}, PlotLegends -> {"ESMAtlas", "CATH protein domain"}]

    Neat Examples  (1)

    Visualize a domain in a protein using the information from the output of "DomainDetails" request:

    Wolfram Language code: domainPlot[id_] := Module[ {domainDetails, resIDs, biomol, chains, chainsAndResidues}, domainDetails = ServiceExecute["CATHDatabase", "DomainDetails", {"CATHDomainID" -> id}]; resIDs = Normal[domainDetails["Residues", All, "ResidueID"]]; biomol = BioMolecule[domainDetails["PDBStructureID"]]; chains = Keys@Select[biomol["AuthorChainIDs"], # === domainDetails["PDBSegments", 1, 1]&]; chainsAndResidues = Cases[Flatten[KeyValueMap[Thread @* List, biomol["ResidueIDs"][[chains]]], 1], {_, Alternatives@@resIDs}]; BioMoleculePlot3D[biomol, ColorRules -> Append[Thread[chainsAndResidues -> StandardRed], _ -> StandardGray] ] ]

    Here is the N terminal domain of glutamine synthetase highlighted in red:

    Wolfram Language code: domainPlot["4acfA01"]

    And here is another domain in the heavy chain of human immunoglobulin G1:

    Wolfram Language code: domainPlot[ExternalIdentifier["CATHDomainID", "1hzhH01"]]