WOLFRAM

Wolfram Language & System Documentation Center

AASTriangle[α,β,a]

returns a filled triangle with angles α and β and side length a, where a is adjacent to one angle only.

Details and Options
Details and Options Details and Options
Background & Context
Examples  
Basic Examples  
Scope  
Graphics  
Specification  
Styling  
Regions  
Applications  
Properties & Relations  
Neat Examples  
See Also
Related Guides
History
Cite this Page

AASTriangle

AASTriangle[α,β,a]

returns a filled triangle with angles α and β and side length a, where a is adjacent to one angle only.

Details and Options

  • AASTriangle is also known as angle-angle-side triangle.
  • AASTriangle can be used as a primitive in 2D graphics and as a geometric region in 2D.
  • The given (blue) and computed (red) parameters for an AASTriangle:
  • AASTriangle returns a Triangle with at the origin, on the positive axis, and in the half-plane .
  • AASTriangle allows the length a to be any positive number and the angles α and β to be positive such that α+β<π.

Background & Context

  • AASTriangle constructs an angle-angle-side triangle. In particular, AASTriangle[α,β,a] returns the Triangle in TemplateBox[{}, Reals]^2 with vertices , and located at the origin, on the positive axis and in the upper half-plane, respectively, with α∠BAC, β∠ABC and a the length of the side opposite . By the AAS theorem, the triangle so specified is unique (up to geometric congruence). AASTriangle allows the length a to be any positive number and the angles α and β to be positive numbers satisfying α+β<π. The arguments of AASTriangle may be exact or approximate numeric expressions.
  • The Triangle objects returned by AASTriangle can be used as 2D graphics primitives or geometric regions.
  • AASTriangle is related to a number of other symbols. ASATriangle, SASTriangle and SSSTriangle return two-dimensional triangles constructed using different angle and/or side specifications. Finally, AASTriangle is a special case of Triangle, in the sense that AASTriangle[α,β,a] is equivalent to Triangle[{{0,0},{a Csc[α] Sin[α+β],0},{a Cot[α] Sin[β],a Sin[β]}}].

Examples

open all close all

Basic Examples  (4)

A triangle with , , and :

Wolfram Language code: AASTriangle[Pi / 6, Pi / 3, 1]

An AASTriangle:

Wolfram Language code: Graphics[AASTriangle[Pi / 6, Pi / 3, 1]]

Different styles applied to AASTriangle:

Wolfram Language code: ℛ = AASTriangle[Pi / 6, Pi / 3, 1]; {Graphics[{Pink, ℛ}], Graphics[{EdgeForm[Thick], Pink, ℛ}], Graphics[{EdgeForm[Dashed], Pink, ℛ}], Graphics[{EdgeForm[Directive[Thick, Dashed, Blue]], Pink, ℛ}]}

Area and centroid:

Wolfram Language code: ℛ = AASTriangle[Pi / 6, Pi / 3, 1];
Wolfram Language code: Area[ℛ]

Centroid:

Wolfram Language code: RegionCentroid[ℛ]

Scope  (14)

Graphics  (4)

Specification  (2)

AASTriangle evaluates to Triangle with one point at the origin and one edge on the axis:

Wolfram Language code: t = AASTriangle[Pi / 4, Pi / 3, 1]
Wolfram Language code: Graphics[{Pink, t}, Frame -> True]

A triangle with a symbolic angle:

Wolfram Language code: t = AASTriangle[Pi / 4, β, 1]

Plot them:

Wolfram Language code: Table[Graphics[t, ImageSize -> Tiny, PlotLabel -> β], {β, 2π / 8, 5π / 8, π / 8}]

Styling  (2)

Color directives specify the face color:

Wolfram Language code: Table[Graphics[{c, AASTriangle[Pi / 6, Pi / 3, 1]}], {c, {Red, Green, Blue, Yellow}}]

FaceForm and EdgeForm can be used to specify the styles of the interior and boundary:

Wolfram Language code: Graphics[{FaceForm[Pink], EdgeForm[Directive[Thick, Dashed, Blue]], AASTriangle[Pi / 6, Pi / 3, 1]}]

Regions  (10)

Embedding dimension is the dimension of the space in which the triangle lives:

Wolfram Language code: ℛ = AASTriangle[Pi / 6, Pi / 3, 1];
Wolfram Language code: RegionEmbeddingDimension[ℛ]

Geometric dimension is the dimension of the triangle itself:

Wolfram Language code: RegionDimension[ℛ]

Membership testing:

Wolfram Language code: ℛ = AASTriangle[Pi / 6, Pi / 3, 1];
Wolfram Language code: {RegionMember[ℛ, {1, 1 / 2}], RegionMember[ℛ, {1, 1}]}

Conditions for membership:

Wolfram Language code: RegionMember[ℛ, {x, y}]

Area:

Wolfram Language code: ℛ = AASTriangle[Pi / 6, Pi / 3, 1];
Wolfram Language code: {Area[ℛ], RegionMeasure[ℛ]}

Centroid:

Wolfram Language code: c = RegionCentroid[ℛ]
Wolfram Language code: Graphics[{{Pink, ℛ}, {Black, Point[c]}}]

Distance from a point to an AASTriangle:

Wolfram Language code: ℛ = AASTriangle[Pi / 6, Pi / 3, 1];
Wolfram Language code: RegionDistance[ℛ, {1, 1}]

Visualize it:

Wolfram Language code: {Plot3D[Evaluate@RegionDistance[ℛ, {x, y}], {x, -1, 3}, {y, -1, 2}, MeshFunctions -> {#3&}, Mesh -> 5], ContourPlot[Evaluate@RegionDistance[ℛ, {x, y}], {x, -2, 4}, {y, -2, 3}, Contours -> {{0.5, Red}, {1, Green}, {1.5, Blue}}]}

Signed distance from a point:

Wolfram Language code: ℛ = AASTriangle[Pi / 6, Pi / 3, 1];
Wolfram Language code: SignedRegionDistance[ℛ, {1, 1 / 2}]
Wolfram Language code: Plot3D[SignedRegionDistance[ℛ, {x, y}], {x, -1, 3}, {y, -1, 2}, MeshFunctions -> {#3&}, Mesh -> {{0}}, MeshShading -> {Red, Green}]

Nearest point:

Wolfram Language code: ℛ = AASTriangle[Pi / 6, Pi / 3, 1];
Wolfram Language code: RegionNearest[ℛ, {1, 1}]

Visualize it:

Wolfram Language code: pts = Table[RegionCentroid[ℛ] + 2{Cos[k 2 π / 16], Sin[k 2 π / 16]}, {k, 0., 15}]; nst = RegionNearest[ℛ, #]& /@ pts;
Wolfram Language code: Legended[Graphics[{{Thick, Gray, ℛ}, {Thin, Gray, Line[Transpose[{pts, nst}]]}, {Red, Point[pts]}, {Blue, Point[nst]}}], PointLegend[{Red, Blue}, {"start", "nearest"}]]

A triangle is bounded:

Wolfram Language code: ℛ = AASTriangle[Pi / 6, Pi / 3, 1];
Wolfram Language code: BoundedRegionQ[ℛ]

Find its range:

Wolfram Language code: rr = RegionBounds[ℛ]
Wolfram Language code: Graphics[{ℛ, {EdgeForm[{Dashed, Red}], Opacity[0.2, Yellow], Cuboid@@Transpose[rr]}}]

Integrate over an AASTriangle:

Wolfram Language code: ℛ = AASTriangle[Pi / 6, Pi / 3, 1];
Wolfram Language code: Integrate[1, {x, y}∈ℛ]
Wolfram Language code: Integrate[x y, {x, y}∈ℛ]

Optimize over it:

Wolfram Language code: ℛ = AASTriangle[Pi / 6, Pi / 3, 1];
Wolfram Language code: Minimize[{(x - 1)^2(3y - 1)^2 + 1, {x, y}∈ℛ}, {x, y}]

Solve equations over an AASTriangle:

Wolfram Language code: ℛ = AASTriangle[Pi / 6, Pi / 3, 1];
Wolfram Language code: Reduce[x^2 + y^2 == 1 && {x, y}∈ℛ, {x, y}]

Applications  (2)

A triangle with two equal angles is an isosceles triangle:

Wolfram Language code: IsoscelesTriangle[α_, s_] := AASTriangle[α, α, s]
Wolfram Language code: t = IsoscelesTriangle[3π / 8, 1]

Visualize it:

Wolfram Language code: Region[t]

Find the area:

Wolfram Language code: Area@IsoscelesTriangle[α, s]

The circumcircle of an AASTriangle can be found using Circumsphere:

Wolfram Language code: tri = AASTriangle[Pi / 4, Pi / 3, 1.]

The circumcircle passes through the three corner points:

Wolfram Language code: circ = Circumsphere[First@tri];
Wolfram Language code: Graphics[{{LightGray, circ}, {LightBlue, tri}, {Black, Point[First@tri]}}]

Find the midpoints for each edge of the triangle:

Wolfram Language code: midpts = RegionCentroid[Line[#]]& /@ Subsets[First@tri, {2}]
Wolfram Language code: Graphics[{{LightBlue, tri}, Point[midpts]}]

The perpendicular bisectors are lines from the circumcenter to the midpoints:

Wolfram Language code: center = First[circ]; bisectors = Line[{center, #}]& /@ midpts;
Wolfram Language code: Graphics[{{LightBlue, tri}, {Point[center], Point[midpts]}, {Red, Dashed, bisectors}}]

Properties & Relations  (2)

AASTriangle is a specialized case of Triangle:

Wolfram Language code: AASTriangle[α, β, a]

Any AASTriangle can be represented by a Polygon:

Wolfram Language code: Subscript[ℛ, 1] = AASTriangle[Pi / 6, Pi / 3, 1]; Subscript[ℛ, 2] = Polygon[{{0, 0}, {2, 0}, {3 / 2, Sqrt[3] / 2}}];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

Neat Examples  (1)

Varying an angle:

Wolfram Language code: Graphics[{Opacity[0.15], Table[{ColorData["Rainbow"][Rescale[β, {0.1, 0.9}]], AASTriangle[1, 1 + β, 1]}, {β, 0.1, 0.9, 0.04}]}]
Wolfram Research (2014), AASTriangle, Wolfram Language function, https://reference.wolfram.com/language/ref/AASTriangle.html.

Text

Wolfram Research (2014), AASTriangle, Wolfram Language function, https://reference.wolfram.com/language/ref/AASTriangle.html.

CMS

Wolfram Language. 2014. "AASTriangle." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/AASTriangle.html.

APA

Wolfram Language. (2014). AASTriangle. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/AASTriangle.html

BibTeX

@misc{reference.wolfram_2026_aastriangle, author="Wolfram Research", title="{AASTriangle}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/AASTriangle.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_aastriangle, organization={Wolfram Research}, title={AASTriangle}, year={2014}, url={https://reference.wolfram.com/language/ref/AASTriangle.html}, note=[Accessed: 12-June-2026]}