WOLFRAM

Wolfram Language & System Documentation Center

SASTriangle[a,γ,b]

returns a filled triangle with sides of length a and b and angle γ between them.

Details and Options
Details and Options Details and Options
Background & Context
Examples  
Basic Examples  
Scope  
Graphics  
Specification  
Styling  
Regions  
Applications  
Properties & Relations  
Neat Examples  
See Also
Related Guides
History
Cite this Page

SASTriangle

SASTriangle[a,γ,b]

returns a filled triangle with sides of length a and b and angle γ between them.

Details and Options

  • SASTriangle is also known as side-angle-side triangle.
  • SASTriangle can be used as a primitive in 2D graphics and as a geometric region in 2D.
  • The given (blue) and computed (red) parameters for an SASTriangle:
  • SASTriangle returns a Triangle with A at the origin, B on the positive axis, and C in the half-plane .
  • SASTriangle allows the lengths a and b to be any positive numbers and the angle γ strictly between 0 and .

Background & Context

  • SASTriangle constructs a side-angle-side triangle. In particular, SASTriangle[a,γ,b] represents the Triangle in TemplateBox[{}, Reals]^2 with vertices , and located at the origin, on the positive axis and in the upper half-plane, respectively, with a and b the lengths of the sides opposite vertices and and γ∠ACB. By the SAS theorem, the triangle so specified is unique (up to geometric congruence). SASTriangle allows the lengths a and b to be any positive numbers and the angle γ to be a positive value satisfying . The arguments of SASTriangle may be exact or approximate numeric expressions.
  • The Triangle objects returned by SASTriangle can be used as 2D graphics primitives or geometric regions.
  • SASTriangle is related to a number of other symbols. AASTriangle, ASATriangle and SSSTriangle return two-dimensional triangles constructed using different angle and/or side specifications. SASTriangle is a special case of Triangle, in the sense that SASTriangle[a,γ,b] is equivalent to Triangle[{{0,0},{x,0},{y,z}}] for xSqrt[a^2+b^2-2 a b Cos[γ]], y(b^2-a bCos[γ])/Sqrt[a^2+b^2-2 a b Cos[γ]] and z(a b Sin[γ])/Sqrt[a^2+b^2-2 a b Cos[γ]].

Examples

open all close all

Basic Examples  (4)

A triangle with , , and :

Wolfram Language code: SASTriangle[1, Pi / 2, 2]

An SASTriangle:

Wolfram Language code: Graphics[SASTriangle[1, Pi / 2, 2]]

Different styles applied to an SASTriangle:

Wolfram Language code: ℛ = SASTriangle[1, Pi / 2, 2]; {Graphics[{Pink, ℛ}], Graphics[{EdgeForm[Thick], Pink, ℛ}], Graphics[{EdgeForm[Dashed], Pink, ℛ}], Graphics[{EdgeForm[Directive[Thick, Dashed, Blue]], Pink, ℛ}]}

Area and centroid:

Wolfram Language code: ℛ = SASTriangle[1, Pi / 2, 2];
Wolfram Language code: Area[ℛ]
Wolfram Language code: RegionCentroid[ℛ]

Scope  (14)

Graphics  (4)

Specification  (2)

SASTriangle evaluates to Triangle with one point at the origin and one edge on the axis:

Wolfram Language code: t = SASTriangle[1, Pi / 4, 2]
Wolfram Language code: Graphics[{Pink, t}, Frame -> True]

A triangle with symbolic edge length:

Wolfram Language code: SASTriangle[1, Pi / 2, b]

Plot them:

Wolfram Language code: Table[Graphics[%, ImageSize -> Tiny, PlotLabel -> b], {b, 0.5, 3.5}]

Styling  (2)

Color directives specify the face color:

Wolfram Language code: Table[Graphics[{c, SASTriangle[1, Pi / 2, 2]}], {c, {Red, Green, Blue, Yellow}}]

FaceForm and EdgeForm can be used to specify the styles of the interior and boundary:

Wolfram Language code: Graphics[{FaceForm[Pink], EdgeForm[Directive[Thick, Dashed, Blue]], SASTriangle[1, Pi / 2, 2]}]

Regions  (10)

Embedding dimension is the dimension of the space the triangle lives in:

Wolfram Language code: ℛ = SASTriangle[1, Pi / 2, 2];
Wolfram Language code: RegionEmbeddingDimension[ℛ]

Geometric dimension is the dimension of the shape itself:

Wolfram Language code: RegionDimension[ℛ]

Membership testing:

Wolfram Language code: ℛ = SASTriangle[1, Pi / 2, 2];
Wolfram Language code: {RegionMember[ℛ, {1, 1 / 2}], RegionMember[ℛ, {2, 1}]}

Conditions for membership:

Wolfram Language code: RegionMember[ℛ, {x, y}]

Area:

Wolfram Language code: ℛ = SASTriangle[1, Pi / 2, 2];
Wolfram Language code: {Area[ℛ], RegionMeasure[ℛ]}

Centroid:

Wolfram Language code: c = RegionCentroid[ℛ]
Wolfram Language code: Graphics[{{Pink, ℛ}, {Black, Point[c]}}]

Distance from a point to an SASTriangle:

Wolfram Language code: ℛ = SASTriangle[1, Pi / 2, 2];
Wolfram Language code: RegionDistance[ℛ, {2, 1}]//Simplify

Visualize it:

Wolfram Language code: {Plot3D[Evaluate@RegionDistance[ℛ, {x, y}], {x, -1, 3}, {y, -1, 2}, MeshFunctions -> {#3&}, Mesh -> 5], ContourPlot[Evaluate@RegionDistance[ℛ, {x, y}], {x, -2, 4}, {y, -2, 3}, Contours -> {{0.5, Red}, {1, Green}, {1.5, Blue}}]}

Signed distance from a point:

Wolfram Language code: ℛ = SASTriangle[1, Pi / 2, 2];
Wolfram Language code: SignedRegionDistance[ℛ, {1, 1 / 3}]

Now plot it:

Wolfram Language code: Plot3D[SignedRegionDistance[ℛ, {x, y}], {x, -1, 3}, {y, -1, 2}, MeshFunctions -> {#3&}, Mesh -> {{0}}, MeshShading -> {Red, Green}]

Nearest point:

Wolfram Language code: ℛ = SASTriangle[1, Pi / 2, 2];
Wolfram Language code: RegionNearest[ℛ, {2, 1}]

Visualize it:

Wolfram Language code: pts = Table[RegionCentroid[ℛ] + 2{Cos[k 2 π / 16], Sin[k 2 π / 16]}, {k, 0., 15}]; nst = RegionNearest[ℛ, #]& /@ pts;
Wolfram Language code: Legended[Graphics[{{Thick, Gray, ℛ}, {Thin, Gray, Line[Transpose[{pts, nst}]]}, {Red, Point[pts]}, {Blue, Point[nst]}}], PointLegend[{Red, Blue}, {"start", "nearest"}]]

A triangle is bounded:

Wolfram Language code: ℛ = SASTriangle[1, Pi / 2, 2];
Wolfram Language code: BoundedRegionQ[ℛ]

Find its range:

Wolfram Language code: rr = RegionBounds[ℛ]
Wolfram Language code: Graphics[{ℛ, {EdgeForm[{Dashed, Red}], Opacity[0.1, Yellow], Cuboid@@Transpose[rr]}}]

Integrate over an SASTriangle:

Wolfram Language code: ℛ = SASTriangle[1, Pi / 2, 2];
Wolfram Language code: Integrate[1, {x, y}∈ℛ]
Wolfram Language code: Integrate[x y, {x, y}∈ℛ]

Optimize over it:

Wolfram Language code: ℛ = SASTriangle[1, Pi / 2, 2];
Wolfram Language code: Minimize[{(x - 1)^2(3y - 1)^2 + 1, {x, y}∈ℛ}, {x, y}]

Solve equations over an SASTriangle:

Wolfram Language code: ℛ = SASTriangle[1, Pi / 2, 2];
Wolfram Language code: Reduce[x^2 + y^2 == 1 && {x, y}∈ℛ, {x, y}]

Applications  (2)

A triangle with two equal sides is an isosceles triangle:

Wolfram Language code: IsoscelesTriangle[s_, α_] := SASTriangle[s, α, s]
Wolfram Language code: t = IsoscelesTriangle[1, π / 2]

Visualize it:

Wolfram Language code: Region[t]

Find its area:

Wolfram Language code: Area@IsoscelesTriangle[s, α]

The circumcircle of an SASTriangle can be found using Circumsphere:

Wolfram Language code: tri = SASTriangle[2, Pi / 3, 3.]

The circumcircle passes through the three corner points:

Wolfram Language code: circ = Circumsphere[First@tri];
Wolfram Language code: Graphics[{{LightGray, circ}, {LightBlue, tri}, {Black, Point[First@tri]}}]

Find the midpoints for each edge of the triangle:

Wolfram Language code: midpts = RegionCentroid[Line[#]]& /@ Subsets[First@tri, {2}]
Wolfram Language code: Graphics[{{LightBlue, tri}, Point[midpts]}]

The perpendicular bisectors are lines from the circumcenter to the midpoints:

Wolfram Language code: center = First[circ]; bisectors = Line[{center, #}]& /@ midpts;
Wolfram Language code: Graphics[{{LightBlue, tri}, {Point[center], Point[midpts]}, {Red, Dashed, bisectors}}]

Properties & Relations  (2)

SASTriangle is a specialized case of Triangle:

Wolfram Language code: SASTriangle[a, γ, b]

Any SASTriangle can be represented by a Polygon:

Wolfram Language code: Subscript[ℛ, 1] = SASTriangle[3, Pi / 2, 4]; Subscript[ℛ, 2] = Polygon[{{0, 0}, {5, 0}, {(16/5), (12/5)}}];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

Neat Examples  (1)

Varying one angle:

Wolfram Language code: Graphics[{Opacity[0.15], Table[{ColorData["Rainbow"][Rescale[α, {5π / 10, 9π / 10}]], SASTriangle[1, α, 1]}, {α, 5π / 10, 9π / 10, π / 30}]}]
Wolfram Research (2014), SASTriangle, Wolfram Language function, https://reference.wolfram.com/language/ref/SASTriangle.html.

Text

Wolfram Research (2014), SASTriangle, Wolfram Language function, https://reference.wolfram.com/language/ref/SASTriangle.html.

CMS

Wolfram Language. 2014. "SASTriangle." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/SASTriangle.html.

APA

Wolfram Language. (2014). SASTriangle. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/SASTriangle.html

BibTeX

@misc{reference.wolfram_2026_sastriangle, author="Wolfram Research", title="{SASTriangle}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/SASTriangle.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_sastriangle, organization={Wolfram Research}, title={SASTriangle}, year={2014}, url={https://reference.wolfram.com/language/ref/SASTriangle.html}, note=[Accessed: 12-June-2026]}