WOLFRAM

Wolfram Language & System Documentation Center

ASATriangle[α,c,β]

returns a filled triangle with angles α and β and side length c, and c is adjacent to both angles.

Details and Options
Details and Options Details and Options
Background & Context
Examples  
Basic Examples  
Scope  
Graphics  
Specification  
Styling  
Regions  
Applications  
Properties & Relations  
Neat Examples  
See Also
Related Guides
History
Cite this Page

ASATriangle

ASATriangle[α,c,β]

returns a filled triangle with angles α and β and side length c, and c is adjacent to both angles.

Details and Options

  • ASATriangle is also known as angle-side-angle triangle.
  • ASATriangle can be used as a primitive in 2D graphics and as a geometric region in 2D.
  • The given (blue) and computed (red) parameters for an ASATriangle:
  • ASATriangle returns a Triangle with at the origin, on the positive axis, and in the half-plane .
  • ASATriangle allows the length c to be any positive number and the angles α and β to be positive and such that α+β<π.

Background & Context

  • ASATriangle constructs an angle-side-angle triangle. In particular, ASATriangle[α,c,β] represents the Triangle in TemplateBox[{}, Reals]^2 with vertices , and located at the origin, on the positive axis and in the upper half-plane, respectively, with α∠BAC, β∠ABC and c the length of the side opposite . By the ASA theorem, the triangle so specified is unique (up to geometric congruence). ASATriangle allows the length c to be any positive number and the angles α and β to be positive values satisfying α+β<π. The arguments of ASATriangle may be exact or approximate numeric expressions.
  • The Triangle objects returned by ASATriangle can be used as 2D graphics primitives or geometric regions.
  • ASATriangle is related to a number of other symbols. AASTriangle, SASTriangle and SSSTriangle return two-dimensional triangles constructed using different angle and/or side specifications. ASATriangle is a special case of Triangle, in the sense that ASATriangle[α,c,β] is equivalent to Triangle[{{0,0},{c,0},{c x,c y}}] for xCos[α] Csc[α+β] Sin[β] and yCsc[α+β] Sin[α] Sin[β].

Examples

open all close all

Basic Examples  (4)

A triangle with , , and :

Wolfram Language code: ASATriangle[Pi / 6, 1, Pi / 3]

An ASATriangle:

Wolfram Language code: Graphics[ASATriangle[Pi / 6, 1, Pi / 3]]

Different styles applied to ASATriangle:

Wolfram Language code: ℛ = ASATriangle[Pi / 6, 1, Pi / 3]; {Graphics[{Pink, ℛ}], Graphics[{EdgeForm[Thick], Pink, ℛ}], Graphics[{EdgeForm[Dashed], Pink, ℛ}], Graphics[{EdgeForm[Directive[Thick, Dashed, Blue]], Pink, ℛ}]}

Area and centroid:

Wolfram Language code: ℛ = ASATriangle[Pi / 6, 1, Pi / 3];
Wolfram Language code: Area[ℛ]

Centroid:

Wolfram Language code: RegionCentroid[ℛ]

Scope  (14)

Graphics  (4)

Specification  (2)

ASATriangle evaluates to Triangle with one point at the origin and one edge on the axis:

Wolfram Language code: t = ASATriangle[Pi / 4, 1, Pi / 4]
Wolfram Language code: Graphics[{Pink, t}, Frame -> True]

A triangle with a symbolic angle:

Wolfram Language code: t = ASATriangle[Pi / 4, 1, β]

Plot them:

Wolfram Language code: Table[Graphics[t, ImageSize -> Tiny, PlotLabel -> β], {β, π / 4, 5π / 8, π / 8}]

Styling  (2)

Color directives specify the face color:

Wolfram Language code: Table[Graphics[{c, ASATriangle[Pi / 6, 1, Pi / 3]}], {c, {Red, Green, Blue, Yellow}}]

FaceForm and EdgeForm can be used to specify the styles of the interior and boundary:

Wolfram Language code: Graphics[{FaceForm[Pink], EdgeForm[Directive[Thick, Dashed, Blue]], ASATriangle[Pi / 6, 1, Pi / 3]}]

Regions  (10)

Embedding dimension is the dimension of the space in which the triangle lives:

Wolfram Language code: ℛ = ASATriangle[Pi / 4, Sqrt[2], Pi / 2];
Wolfram Language code: RegionEmbeddingDimension[ℛ]

Geometric dimension is the dimension of the triangle itself:

Wolfram Language code: RegionDimension[ℛ]

Membership testing:

Wolfram Language code: ℛ = ASATriangle[Pi / 4, Sqrt[2], Pi / 2];
Wolfram Language code: {RegionMember[ℛ, {1, 1}], RegionMember[ℛ, {2, 1}]}

Get conditions for membership:

Wolfram Language code: RegionMember[ℛ, {x, y}]

Area:

Wolfram Language code: ℛ = ASATriangle[Pi / 4, Sqrt[2], Pi / 2];
Wolfram Language code: {Area[ℛ], RegionMeasure[ℛ]}

Centroid:

Wolfram Language code: c = RegionCentroid[ℛ]
Wolfram Language code: Graphics[{{Pink, ℛ}, {Black, Point[c]}}]

Distance from a point to an ASATriangle:

Wolfram Language code: ℛ = ASATriangle[Pi / 4, Sqrt[2], Pi / 2];
Wolfram Language code: RegionDistance[ℛ, {2, 1}]
Wolfram Language code: {Plot3D[Evaluate@RegionDistance[ℛ, {x, y}], {x, -1, 3}, {y, -1, 2}, MeshFunctions -> {#3&}, Mesh -> 5], ContourPlot[Evaluate@RegionDistance[ℛ, {x, y}], {x, -2, 4}, {y, -2, 3}, Contours -> {{0.5, Red}, {1, Green}, {1.5, Blue}}]}

Signed distance from a point:

Wolfram Language code: ℛ = ASATriangle[Pi / 4, Sqrt[2], Pi / 2];
Wolfram Language code: SignedRegionDistance[ℛ, {1, 1 / 2}]

Now plot it:

Wolfram Language code: Plot3D[SignedRegionDistance[ℛ, {x, y}], {x, -1, 3}, {y, -1, 2}, MeshFunctions -> {#3&}, Mesh -> {{0}}, MeshShading -> {Red, Green}]

Nearest point:

Wolfram Language code: ℛ = ASATriangle[Pi / 4, Sqrt[2], Pi / 2];
Wolfram Language code: RegionNearest[ℛ, {2, 1}]

Visualize it:

Wolfram Language code: pts = Table[RegionCentroid[ℛ] + 2{Cos[k 2 π / 16], Sin[k 2 π / 16]}, {k, 0., 15}]; nst = RegionNearest[ℛ, #]& /@ pts;
Wolfram Language code: Legended[Graphics[{{Thick, Gray, ℛ}, {Thin, Gray, Line[Transpose[{pts, nst}]]}, {Red, Point[pts]}, {Blue, Point[nst]}}], PointLegend[{Red, Blue}, {"start", "nearest"}]]

A triangle is bounded:

Wolfram Language code: ℛ = ASATriangle[Pi / 4, Sqrt[2], Pi / 2];
Wolfram Language code: BoundedRegionQ[ℛ]

Find its range:

Wolfram Language code: rr = RegionBounds[ℛ]
Wolfram Language code: Graphics[{ℛ, {EdgeForm[{Dashed, Red}], Opacity[0.2, Yellow], Cuboid@@Transpose[rr]}}]

Integrate over an ASATriangle:

Wolfram Language code: ℛ = ASATriangle[Pi / 4, Sqrt[2], Pi / 2];
Wolfram Language code: Integrate[1, {x, y}∈ℛ]
Wolfram Language code: Integrate[x y, {x, y}∈ℛ]

Optimize over it:

Wolfram Language code: ℛ = ASATriangle[Pi / 4, Sqrt[2], Pi / 2];
Wolfram Language code: Minimize[{(x - 1)^2(y - 1)^2 + 1, {x, y}∈ℛ}, {x, y}]

Solve equations over an ASATriangle:

Wolfram Language code: ℛ = ASATriangle[Pi / 4, Sqrt[2], Pi / 2];
Wolfram Language code: Reduce[x^2 + y^2 == 1 && {x, y}∈ℛ, {x, y}]

Applications  (2)

A triangle with two equal angles is an isosceles triangle:

Wolfram Language code: IsoscelesTriangle[α_, s_] := ASATriangle[α, s, α]
Wolfram Language code: t = IsoscelesTriangle[3π / 8, 1]

Visualize it:

Wolfram Language code: Region[t]

Find its area:

Wolfram Language code: Area@IsoscelesTriangle[α, s]

The circumcircle of an ASATriangle can be found using Circumsphere:

Wolfram Language code: tri = ASATriangle[Pi / 3, 1., Pi / 3]

The circumcircle passes through the three corner points:

Wolfram Language code: circ = Circumsphere[First@tri];
Wolfram Language code: Graphics[{{LightGray, circ}, {LightBlue, tri}, {Black, Point[First@tri]}}]

Find the midpoints for each edge of the triangle:

Wolfram Language code: midpts = RegionCentroid[Line[#]]& /@ Subsets[First@tri, {2}]
Wolfram Language code: Graphics[{{LightBlue, tri}, Point[midpts]}]

The perpendicular bisectors are lines from the circumcenter to the midpoints:

Wolfram Language code: center = First[circ]; bisectors = Line[{center, #}]& /@ midpts;
Wolfram Language code: Graphics[{{LightBlue, tri}, {Red, Point[center]}, {Red, Point[midpts]}, {Red, Dashed, bisectors}}]

Properties & Relations  (2)

ASATriangle is a specialized case of Triangle:

Wolfram Language code: ASATriangle[α, c, β]

Any ASATriangle can be represented by a Polygon:

Wolfram Language code: Subscript[ℛ, 1] = ASATriangle[Pi / 4, Sqrt[2], Pi / 2]; Subscript[ℛ, 2] = Polygon[{{0, 0}, {Sqrt[2], 0}, {Sqrt[2], Sqrt[2]}}];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

Neat Examples  (1)

Varying two angles together:

Wolfram Language code: Graphics[{Opacity[0.2], Table[{ColorData["Rainbow"][Rescale[β, {0.1, 0.9}]], ASATriangle[1 - β, 1, 1 + β]}, {β, 0.1, 0.9, 0.04}]}]
Wolfram Research (2014), ASATriangle, Wolfram Language function, https://reference.wolfram.com/language/ref/ASATriangle.html.

Text

Wolfram Research (2014), ASATriangle, Wolfram Language function, https://reference.wolfram.com/language/ref/ASATriangle.html.

CMS

Wolfram Language. 2014. "ASATriangle." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/ASATriangle.html.

APA

Wolfram Language. (2014). ASATriangle. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ASATriangle.html

BibTeX

@misc{reference.wolfram_2026_asatriangle, author="Wolfram Research", title="{ASATriangle}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/ASATriangle.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_asatriangle, organization={Wolfram Research}, title={ASATriangle}, year={2014}, url={https://reference.wolfram.com/language/ref/ASATriangle.html}, note=[Accessed: 12-June-2026]}