WOLFRAM

Wolfram Language & System Documentation Center

AbsoluteDashing[{d1,d2,…}]

is a graphics directive which specifies that lines which follow are to be drawn dashed, with successive segments having absolute lengths d1, d2, … (repeated cyclically).

AbsoluteDashing[d]

is equivalent to AbsoluteDashing[{d,d}].

AbsoluteDashing[{d1,d2,…},offset]

offsets the dashes by offset.

AbsoluteDashing[{d1,d2,…},offset,capform]

sets the CapForm for individual dashes to capform.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Dashing Specifications  
Properties & Relations  
Possible Issues  
Neat Examples  
See Also
Tech Notes
Related Guides
History
Cite this Page

AbsoluteDashing

AbsoluteDashing[{d1,d2,…}]

is a graphics directive which specifies that lines which follow are to be drawn dashed, with successive segments having absolute lengths d1, d2, … (repeated cyclically).

AbsoluteDashing[d]

is equivalent to AbsoluteDashing[{d,d}].

AbsoluteDashing[{d1,d2,…},offset]

offsets the dashes by offset.

AbsoluteDashing[{d1,d2,…},offset,capform]

sets the CapForm for individual dashes to capform.

Details

  • Dash and offset lengths are measured in units of printer's points, equal before magnification to of an inch.
  • AbsoluteDashing[{}] specifies that lines should be solid. »
  • AbsoluteDashing can be used in both two- and three-dimensional graphics, as well as in Style specifications.
  • The following symbolic forms for d can be used: Tiny, Small, Medium, and Large. »
  • If a segment has a length di specified as 0, it is drawn as a dot whose diameter is the thickness of the line.
  • offset is specified in printer's points, and it may be positive or negative. If offset is not specified, it is 0.
  • capform can take any of the legal form values in CapForm[form]. If not specified, all segments will be drawn with the "Butt" cap form.

Examples

open all close all

Basic Examples  (2)

Specify the dashing of lines as successive segments with lengths in printer's points:

Wolfram Language code: Table[Graphics[{AbsoluteDashing[{d, 15 - d}], Line[{{0, 0}, {2, 1}}]}], {d, {2, 5, 8, 12}}]
Wolfram Language code: Table[Graphics3D[{AbsoluteDashing[{d, 15 - d}], Line[{{0, 0, 0}, {2, 1, 1}}]}], {d, {2, 5, 8, 12}}]

Use Dashed, Dotted, and DotDashed to specify predefined absolute dashings:

Wolfram Language code: {Graphics[{Dashed, Line[{{0, 0}, {2, 1}}]}], Graphics[{Dotted, Line[{{0, 0}, {2, 1}}]}], Graphics[{DotDashed, Line[{{0, 0}, {2, 1}}]}]}

Scope  (4)

Dashing Specifications  (4)

No dashing:

Wolfram Language code: Graphics[{AbsoluteDashing[{}], Line[{{0, 0}, {2, 1}}]}]

AbsoluteDashing[d] is equivalent to AbsoluteDashing[{d,d}]:

Wolfram Language code: Table[Graphics[{AbsoluteDashing[d], Line[{{0, 0}, {2, 1}}]}], {d, {2, 5, 8, 12}}]

Symbolic values for predefined absolute dashings:

Wolfram Language code: Table[Graphics[{AbsoluteDashing[d], Line[{{0, 0}, {2, 1}}]}], {d, {Tiny, Small, Medium, Large}}]

Specify offset to dashed segments:

Wolfram Language code: Table[Graphics[{Line[{{0, 0}, {2, 1}}], AbsoluteDashing[{10, 5}, o], Red, Opacity[.5], AbsoluteThickness[5], Line[{{0, 0}, {2, 1}}]}], {o, {-5, 0, 5}}]

Specify caps to dashed segments:

Wolfram Language code: Table[Graphics[{Line[{{0, 0}, {2, 1}}], AbsoluteDashing[{10, 10}, 0, CapForm[c]], Red, Opacity[.5], AbsoluteThickness[5], Line[{{0, 0}, {2, 1}}]}], {c, {"Round", "Butt", "Square"}}]

Properties & Relations  (3)

AbsoluteDashing defines the length of a segment in units of printer's points:

Wolfram Language code: Graphics[{Thickness[.02], AbsoluteDashing[{15}], Line[{{0, 0}, {1, 0}}], Text[Style["15 points", FontSize -> 15], {0.5, 0.1}]}]

AbsoluteDashing is independent of the image size:

Wolfram Language code: Table[Graphics[{AbsoluteDashing[10], Line[{{0, 0}, {2, 1}}]}, ImageSize -> s], {s, {50, 100, 150}}]

Dashing defines the length of a segment as a fraction of the total width of the graphic:

Wolfram Language code: Graphics[{Thick, Dashing[{0.05, 0.1}], Line[{{-1, 0}, {1, 0}}]}, Frame -> True]

Dashing depends on the image size:

Wolfram Language code: Table[Graphics[{Dashing[.05], Line[{{0, 0}, {2, 1}}]}, ImageSize -> s], {s, {50, 100, 150}}]

AbsoluteDashing overrides the CapForm directive:

Wolfram Language code: Graphics[{AbsoluteDashing[{20, 15}], CapForm["Round"], AbsoluteThickness[10], Line[{{0, 0}, {1, 1}}]}]

Specify the third argument to Dashing to set a cap form for all dashes:

Wolfram Language code: Graphics[{AbsoluteDashing[{20, 15}, 0, "Round"], AbsoluteThickness[10], Line[{{0, 0}, {1, 1}}]}]

Possible Issues  (1)

Line caps add to the length of individual dashes and may cause closely spaced dashes to overlap:

Wolfram Language code: Table[Graphics[{AbsoluteDashing[{20, 8}, 0, cap], AbsoluteThickness[10], Line[{{1, 0}, {0, 1}}]}], {cap, {None, "Round"}}]

Neat Examples  (1)

Vary the offset for dashed rays out of the origin:

Wolfram Language code: Animate[Graphics[{AbsoluteDashing[{20, 10}, a], Table[Line[{{0, 0}, {Cos[b], Sin[b]}}], {b, 0, 2 π, π / 20}]}], {a, 90, 0}]
Wolfram Research (1991), AbsoluteDashing, Wolfram Language function, https://reference.wolfram.com/language/ref/AbsoluteDashing.html (updated 2021).

Text

Wolfram Research (1991), AbsoluteDashing, Wolfram Language function, https://reference.wolfram.com/language/ref/AbsoluteDashing.html (updated 2021).

CMS

Wolfram Language. 1991. "AbsoluteDashing." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2021. https://reference.wolfram.com/language/ref/AbsoluteDashing.html.

APA

Wolfram Language. (1991). AbsoluteDashing. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/AbsoluteDashing.html

BibTeX

@misc{reference.wolfram_2026_absolutedashing, author="Wolfram Research", title="{AbsoluteDashing}", year="2021", howpublished="\url{https://reference.wolfram.com/language/ref/AbsoluteDashing.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_absolutedashing, organization={Wolfram Research}, title={AbsoluteDashing}, year={2021}, url={https://reference.wolfram.com/language/ref/AbsoluteDashing.html}, note=[Accessed: 12-June-2026]}