Activate
Examples
open all close allBasic Examples (2)
Activate an Inactive expression:
Activate[Inactive[Length][{a, b, c}]]Activate different parts of an inactive expression:
expr = Inactivate[2 + 2 + 3 ^ 2]Activate[expr, Plus]Activate[expr, Power]Activate[expr]Scope (7)
Define an inactive expression:
expr = Inactive[Sin][π / 2]Evaluate the expression using Activate:
Activate[expr]Create an inactive expression using Inactivate:
expr = Inactivate[Sin[Pi / 2], Sin]Activate[expr]Inactivate[f[g[h[x]], y, g[z]], g]Activate[%]Inactivate[f[g[h[x]], y, g[z]], g | h]Activate[%, h]Activate an inactive expression:
expr = Inactive[Cos][π] + Inactive[Integrate][x, x];Activate[expr]Activate all symbols except Integrate:
Activate[expr, Except[Integrate]]Prevent numeric functions from being activated:
Activate[expr, Except[_ ? (MemberQ[Attributes[#], NumericFunction]&)]]Formally differentiating a Laplace transform:
Inactive[LaplaceTransform][a t ^ 2, t, s]D[%, s]Activate[%]D[LaplaceTransform[a t ^ 2, t, s], s]Similarly differentiating wrt t and a:
D[Inactive[LaplaceTransform][a t ^ 2, t, s], t]D[Inactive[LaplaceTransform][a t ^ 2, t, s], a]Inactive special function expression:
expr = Inactivate[Hypergeometric2F1[3, 1, 2, x], Hypergeometric2F1]Expression after automatic simplification:
Activate[expr]Hypergeometric2F1[3, 1, 2, x]Options (1)
Heads (1)
An inactive Derivative expression:
inactive = Inactivate[Derivative[1][Cos][x]]Activate[inactive]Use the option setting Heads->False to avoid activating Derivative:
Activate[inactive, Heads -> False]Applications (5)
Define a trigonometric expression with two inactive terms:
expr = Inactivate[Sin[π / 3] + Cos[π / 3] + Tan[π / 3], Sin | Cos]Activate different parts of the expression:
Activate[expr, Sin]Activate[expr, Cos]Activate[expr]Define 
, leaving both the derivative and integral inactive:
inactive = Inactivate[D[Integrate[(t + x) ^ 2, {t, 0, x}], x], D | Integrate]Differentiate the integral without evaluating the integral:
Activate[inactive, D]Activate the integral to compute the final result:
di = Activate[%]Integrate without performing the differentiation:
Activate[inactive, Integrate]Activate the differentiation to compute the final result:
id = Activate[%]The results are mathematically the same:
Simplify[di - id]Solution for the three-dimensional Laplace equation in inactive integral form:
V[x_, y_, z_] = Inactivate[Integrate[f[z + I x Cos[u] + I y Sin[u], u], {u, -Pi, Pi}],
Integrate]Obtain a particular solution by specifying the function f:
f[a_, b_] := 3a ^ 5 + 7b ^ 4V[x, y, z]sol = Activate[%]//SimplifyRow[Table[Plot3D[sol /. {z -> j}, {x, -3, 3}, {y, -3, 3}, Ticks -> {Automatic, Automatic, None}], {j, -2, 2}]]Laplacian[sol, {x, y, z}]//SimplifyFormula for summation by parts:
sumparts = Inactivate[Sum[f[k]g[k], k] == g[k]Sum[f[k], k] -
Sum[DifferenceDelta[g[k], k]DiscreteShift[Sum[f[k], k], k], k],
Sum | DifferenceDelta | DiscreteShift]Verify the formula in a special case:
f[k_] := kg[k_] := HarmonicNumber[k]Activate[sumparts]Inactive[Sum][k HarmonicNumber[k], k] == Sum[k HarmonicNumber[k], k]divcurl = Inactivate[Div[Curl[{f[x, y, z], g[x, y, z], h[x, y, z]}, {x, y, z}],
{x, y, z}], Div | Curl]Activating Curl is not very interesting:
Activate[divcurl, Curl]Activating Div demonstrates the relation ![TemplateBox[{{(, TemplateBox[{v, }, Curl], )}, }, Div]=0](Files/Activate.en/1.png "TemplateBox[{{(, TemplateBox[{v, }, Curl], )}, }, Div]=0"){kind=small}
:
Activate[divcurl, Div]Properties & Relations (4)
Inactive expressions can be evaluated using Activate:
f[x_] := x ^ 2expr = Inactive[f][3]Activate[expr]Activate is the inverse of Inactivate:
Inactivate[f[x], f]Activate[%]Activate replaces all instances of inactive symbols in an expression:
Inactivate[f[x] + g[x] + h[x], f | g]Activate[%]Activate evaluates inactive expressions and allows parts of expressions to be inactive:
isin = Inactivate[Sin[ArcTan[1]]]Activate[isin, Sin]Activate[%]ReleaseHold evaluates expressions held in unevaluated form, and all parts are evaluated:
esin = Hold[Sin[ArcTan[1]]]ReleaseHold[%]Neat Examples (1)
Create a gallery of infinite products:
infiniteproducts = Inactivate[{Underoverscript[∏, k = 1, n]((k + 1)^3 (k + 5)/k^2), Underoverscript[∏, k = 0, n]k!, Underoverscript[∏, k = 1, ∞](1 + (1/k^2)), Underoverscript[∏, k, ∞](1 - (4/3) Sin[(x/3^k)]^2), Underoverscript[∏, k, ∞](1 + (1/Prime[k]^s)), Underoverscript[∏, k = 1, n]((k + 3/k + 1))^k, Underoverscript[∏, k = 1, n](Sin[3 k + 5]/Cos[3 k + 1])}, Product];FormulaGallery[forms_List] := Grid[ParallelMap[{# == Simplify@Activate[#]}&, forms], IconizedObject[«Grid options»]];FormulaGallery[infiniteproducts]//TraditionalFormText
Wolfram Research (2014), Activate, Wolfram Language function, https://reference.wolfram.com/language/ref/Activate.html.
CMS
Wolfram Language. 2014. "Activate." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/Activate.html.
APA
Wolfram Language. (2014). Activate. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Activate.html