WOLFRAM

Wolfram Language & System Documentation Center

AnyTrue[{e1,e2,…},test]

yields True if test[ei] is True for any of the ei.

AnyTrue[expr,test,level]

tests parts of expr at level level.

AnyTrue[test]

represents an operator form of AnyTrue that can be applied to an expression.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Properties & Relations  
Possible Issues  
See Also
Related Guides
History
Cite this Page

AnyTrue

AnyTrue[{e1,e2,…},test]

yields True if test[ei] is True for any of the ei.

AnyTrue[expr,test,level]

tests parts of expr at level level.

AnyTrue[test]

represents an operator form of AnyTrue that can be applied to an expression.

Details

  • AnyTrue[expr,test] and AnyTrue[expr,test,level] only evaluate as many test[ei] as are necessary to determine the result.
  • AnyTrue[list,test] is equivalent to AnyTrue[list,test,1].
  • AnyTrue[test][list] is equivalent to AnyTrue[list,test].

Examples

open all close all

Basic Examples  (4)

Check if any element of a list satisfies a condition:

Wolfram Language code: AnyTrue[{1, 2, 3, 4, 5, 6}, EvenQ]
Wolfram Language code: AnyTrue[{1, 3, 5, 7, 9}, EvenQ]

Check if any element of a matrix satisfies a condition:

Wolfram Language code: AnyTrue[{{1, 2, 3}, {4, 5, 6}}, EvenQ, 2]
Wolfram Language code: AnyTrue[{{1, 3, 5}, {7, 9, 11}}, EvenQ, 2]

Check if any value of an association satisfies a condition:

Wolfram Language code: AnyTrue[<|"a" -> 2, "b" -> 3, "c" -> 6|>, OddQ]

A symbolic result may be returned:

Wolfram Language code: AnyTrue[{12, 16, x, 14, y}, # < 10&]
Wolfram Language code: % /. {x -> 3, y -> 7}

TrueQ may be used to avoid getting a symbolic result:

Wolfram Language code: AnyTrue[{12, 16, x, 14, y}, TrueQ[# < 10]&]

Scope  (3)

AnyTrue may be applied to expressions with any head:

Wolfram Language code: AnyTrue[f[2, 7, 6], OddQ]
Wolfram Language code: AnyTrue[f[x, y, z], # < 10&]

AnyTrue can operate on ragged expressions:

Wolfram Language code: AnyTrue[{{1, 2, 3}, {4, 5}}, EvenQ, 2]
Wolfram Language code: AnyTrue[f[{1, 2, 3}, {4, 5}], EvenQ, 2]

By default, AnyTrue operates at level 1:

Wolfram Language code: AnyTrue[4, EvenQ]
Wolfram Language code: AnyTrue[{}, EvenQ]
Wolfram Language code: AnyTrue[4, EvenQ, 0]

Properties & Relations  (4)

Compose the predicate with TrueQ to make the predicate stronger:

Wolfram Language code: AnyTrue[{x, y, z}, Composition[TrueQ, f]]

AnyTrue[list,f] is equivalent to !NoneTrue[list,f]:

Wolfram Language code: LogicalExpand /@ {AnyTrue[{x, y, z}, f], !NoneTrue[{x, y, z}, f]}

AnyTrue[list,f] works efficiently on sparse vectors:

Wolfram Language code: AnyTrue[SparseArray[{1000 -> 3}, {1000000000000}], OddQ]

AnyTrue[list,test] checks the parts of list in order, stopping as soon as test returns True:

Wolfram Language code: AnyTrue[{1, 2, 3, 4, 5}, (Print[#];EvenQ[#])&]

Possible Issues  (1)

A symbolic result may be returned:

Wolfram Language code: AnyTrue[{x, y, z}, f]
Wolfram Research (2014), AnyTrue, Wolfram Language function, https://reference.wolfram.com/language/ref/AnyTrue.html (updated 2015).

Text

Wolfram Research (2014), AnyTrue, Wolfram Language function, https://reference.wolfram.com/language/ref/AnyTrue.html (updated 2015).

CMS

Wolfram Language. 2014. "AnyTrue." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2015. https://reference.wolfram.com/language/ref/AnyTrue.html.

APA

Wolfram Language. (2014). AnyTrue. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/AnyTrue.html

BibTeX

@misc{reference.wolfram_2026_anytrue, author="Wolfram Research", title="{AnyTrue}", year="2015", howpublished="\url{https://reference.wolfram.com/language/ref/AnyTrue.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_anytrue, organization={Wolfram Research}, title={AnyTrue}, year={2015}, url={https://reference.wolfram.com/language/ref/AnyTrue.html}, note=[Accessed: 12-June-2026]}