WOLFRAM

Wolfram Language & System Documentation Center

NoneTrue[{e1,e2,…},test]

yields True if test[ei] is False for all of the ei.

NoneTrue[expr,test,level]

tests parts of expr at level level.

NoneTrue[test]

represents an operator form of NoneTrue that can be applied to an expression.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Properties & Relations  
Possible Issues  
See Also
Related Guides
History
Cite this Page

NoneTrue

NoneTrue[{e1,e2,…},test]

yields True if test[ei] is False for all of the ei.

NoneTrue[expr,test,level]

tests parts of expr at level level.

NoneTrue[test]

represents an operator form of NoneTrue that can be applied to an expression.

Details

  • NoneTrue[list,test] and NoneTrue[expr,test,level] only evaluate as many test[ei] as are necessary to determine the result.
  • NoneTrue[list,test] is equivalent to NoneTrue[list,test,1].
  • NoneTrue[test][list] is equivalent to NoneTrue[list,test].

Examples

open all close all

Basic Examples  (4)

Check if no element of a list satisfies a condition:

Wolfram Language code: NoneTrue[{1, 2, 3, 4, 5, 6}, EvenQ]
Wolfram Language code: NoneTrue[{1, 3, 5, 7, 9}, EvenQ]

Check if no element of a matrix satisfies a condition:

Wolfram Language code: NoneTrue[{{1, 2, 3}, {4, 5, 6}}, EvenQ, 2]
Wolfram Language code: NoneTrue[{{1, 3, 5}, {7, 9, 11}}, EvenQ, 2]

Check if no value of an association satisfies a condition:

Wolfram Language code: NoneTrue[<|"a" -> 2, "b" -> 3, "c" -> 6|>, OddQ]

A symbolic result may be returned:

Wolfram Language code: a = NoneTrue[{12, 16, x, 14, y}, # < 10&]
Wolfram Language code: % /. {x -> 13, y -> 17}

Even when the condition applied to some elements is symbolic, a definitive result may be deduced:

Wolfram Language code: NoneTrue[{12, 16, x, 8, 14, y}, # < 10&]

TrueQ may be used to avoid getting a symbolic result:

Wolfram Language code: NoneTrue[{12, 16, x, 14, y}, TrueQ[# < 10]&]

Scope  (3)

NoneTrue may be applied to expressions with any head:

Wolfram Language code: NoneTrue[f[2, 8, 6], OddQ]
Wolfram Language code: NoneTrue[f[x, y, z], # < 10&]

NoneTrue can operate on ragged expressions:

Wolfram Language code: NoneTrue[{{1, 2, 3}, {4, 5}}, EvenQ, 2]
Wolfram Language code: NoneTrue[f[{1, 3, 5}, {7, 9}], EvenQ, 2]

By default, NoneTrue always operates at level 1:

Wolfram Language code: NoneTrue[4, EvenQ]
Wolfram Language code: NoneTrue[{}, EvenQ]
Wolfram Language code: NoneTrue[4, EvenQ, 0]

Properties & Relations  (5)

Compose the predicate with TrueQ to make the predicate stronger:

Wolfram Language code: NoneTrue[{x, y, z}, Composition[TrueQ, f]]

NoneTrue[list,f] is equivalent to AllTrue[list,Composition[Not,f]]:

Wolfram Language code: LogicalExpand /@ {NoneTrue[{x, y, z}, f], AllTrue[{x, y, z}, !f[#]&]}

NoneTrue[list,f] is equivalent to VectorQ[list,Composition[Not,f]] when f evaluates to True or False:

Wolfram Language code: {NoneTrue[Range[10], Negative], VectorQ[Range[10], Composition[Not, Negative]]}

NoneTrue[list,f] works efficiently on sparse vectors:

Wolfram Language code: NoneTrue[SparseArray[{1000 -> 2}, {1000000000000}], OddQ]

NoneTrue[list,test] checks the parts of list in order, stopping as soon as test returns True:

Wolfram Language code: NoneTrue[{1, 2, 3, 4, 5}, (Print[#];EvenQ[#])&]

Possible Issues  (1)

A symbolic result may be returned:

Wolfram Language code: NoneTrue[{x, y, z}, f]
Wolfram Research (2014), NoneTrue, Wolfram Language function, https://reference.wolfram.com/language/ref/NoneTrue.html (updated 2015).

Text

Wolfram Research (2014), NoneTrue, Wolfram Language function, https://reference.wolfram.com/language/ref/NoneTrue.html (updated 2015).

CMS

Wolfram Language. 2014. "NoneTrue." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2015. https://reference.wolfram.com/language/ref/NoneTrue.html.

APA

Wolfram Language. (2014). NoneTrue. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/NoneTrue.html

BibTeX

@misc{reference.wolfram_2026_nonetrue, author="Wolfram Research", title="{NoneTrue}", year="2015", howpublished="\url{https://reference.wolfram.com/language/ref/NoneTrue.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_nonetrue, organization={Wolfram Research}, title={NoneTrue}, year={2015}, url={https://reference.wolfram.com/language/ref/NoneTrue.html}, note=[Accessed: 13-June-2026]}