WOLFRAM

Wolfram Language & System Documentation Center

Band[{i,j}]

represents the sequence of positions on the diagonal band that starts with {i,j} in a sparse array.

Band[{imin,jmin,…},{imax,jmax,…}]

represents the positions between {imin,jmin,…} and {imax,jmax,…}.

Band[{imin,jmin,…},{imax,jmax,…},{di,dj,…}]

represents positions starting with {imin,jmin,…} and then moving with step {di,dj,…}.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Generalizations & Extensions  
Applications  
Properties & Relations  
See Also
Tech Notes
Related Guides
History
Cite this Page

Band

Band[{i,j}]

represents the sequence of positions on the diagonal band that starts with {i,j} in a sparse array.

Band[{imin,jmin,…},{imax,jmax,…}]

represents the positions between {imin,jmin,…} and {imax,jmax,…}.

Band[{imin,jmin,…},{imax,jmax,…},{di,dj,…}]

represents positions starting with {imin,jmin,…} and then moving with step {di,dj,…}.

Details

  • Band[pos]->v represents values v that repeat along the diagonal band starting at pos.
  • Band[pos]->{v1,v2,…} represents a sequence of values vn along the diagonal band starting at pos.
  • With an array a of the same rank as the whole sparse array, Band[start]->a by default inserts a at the position specified by start.
  • With arrays an of the same rank as the whole sparse array, Band[pos]->{a1,a2,…} represents a sequence of non-overlapping subarrays.
  • Band[start] is effectively equivalent to Band[start,{-1,-1,…}].
  • For scalar values, Band[start,end] is equivalent to Band[start,end,{1,1,…}].
  • Band[start,end,step] stops when any coordinate first exceeds its value in end.
  • Band[start,end]->{v1,v2,…} takes the values vn to repeat cyclically until end is reached.
  • Band[start,Automatic,step]->a continues until the edge of the array is reached.
  • Band[start,Automatic,step]->{v1,v2,…} continues until the vi are exhausted.

Examples

open all close all

Basic Examples  (1)

Create a band diagonal matrix:

Wolfram Language code: SparseArray[{Band[{1, 1}] -> x, Band[{2, 1}] -> y}, {5, 5}]//MatrixForm

Convert to normal lists:

Wolfram Language code: Normal[%]

Scope  (11)

Mix Band with other SparseArray element specifications:

Wolfram Language code: SparseArray[{Band[{1, 1}] -> x, {3, 5} -> b}, {5, 5}]//MatrixForm

Give explicit values to fill in on the band:

Wolfram Language code: SparseArray[Band[{1, 1}] -> {x, y, z}, {5, 5}]//MatrixForm

Repeat the values cyclically:

Wolfram Language code: SparseArray[Band[{1, 1}, {5, 5}] -> {x, y, z}, {5, 5}]//MatrixForm

Start the band at any position in the matrix:

Wolfram Language code: SparseArray[Band[{3, 2}] -> x, {5, 5}]//MatrixForm

Specify any start and end locations:

Wolfram Language code: SparseArray[Band[{1, 2}, {3, 4}] -> x, {5, 5}]//MatrixForm

Step by 2 between elements on the band:

Wolfram Language code: SparseArray[Band[{1, 1}, {5, 5}, 2] -> x, {5, 5}]//MatrixForm

Any step can be used:

Wolfram Language code: SparseArray[Band[{1, 1}, {5, 5}, {1, 2}] -> x, {5, 5}]//MatrixForm

Automatically continue the band to the edge of the array:

Wolfram Language code: SparseArray[Band[{1, 1}, Automatic, {1, 2}] -> x, {5, 5}]//MatrixForm

Specify a band that is part of a row:

Wolfram Language code: SparseArray[Band[{3, 3}, Automatic, {0, 1}] -> x, {5, 5}]//MatrixForm

Specify an anti-diagonal matrix:

Wolfram Language code: SparseArray[Band[{1, 5}, Automatic, {1, -1}] -> x, {5, 5}]//MatrixForm

Insert a submatrix beginning at position 3, 3:

Wolfram Language code: SparseArray[Band[{3, 3}] -> {{a, b}, {c, d}}, {5, 5}]//MatrixForm

Cyclically repeat the submatrix:

Wolfram Language code: SparseArray[Band[{1, 1}, {5, 5}] -> {{{a, b}, {c, d}}}, {5, 5}]//MatrixForm

Alternate the submatrix with a single element:

Wolfram Language code: SparseArray[Band[{1, 1}, {5, 5}] -> {{{a, b}, {c, d}}, {{x}}}, {5, 5}]//MatrixForm

Generalizations & Extensions  (2)

Band works in sparse arrays of any rank:

Wolfram Language code: Graphics3D[Cuboid /@ Position[Normal[SparseArray[Band[{1, 1, 1}] -> x, {10, 10, 10}]], x]]
Wolfram Language code: Graphics3D[Cuboid /@ Position[Normal[SparseArray[Band[{1, 1, 1}, Automatic, {1, 2, 3}] -> x, {30, 30, 30}]], x]]

Fill in a plane of values into a 3D sparse array:

Wolfram Language code: Graphics3D[Cuboid /@ Position[Normal[SparseArray[Band[{1, 1, 1}] -> Table[x, {10}, {10}]]], x]]

Applications  (2)

Make a tridiagonal matrix:

Wolfram Language code: SparseArray[{Band[{2, 1}] -> a, Band[{1, 1}] -> b, Band[{1, 2}] -> c}, 5]//MatrixForm

Build a tridiagonal linear system:

Wolfram Language code: SparseArray[{Band[{2, 1}] -> a, Band[{1, 1}] -> b, Band[{1, 2}] -> c}, 5].Array[x, 5]

Properties & Relations  (2)

Band works in SparseArray; use Normal to convert to normal lists:

Wolfram Language code: SparseArray[{Band[{1, 1}] -> x, Band[{2, 1}] -> y}, {5, 5}]
Wolfram Language code: Normal[%]

The simplest case of Band is equivalent to DiagonalMatrix:

Wolfram Language code: DiagonalMatrix[{a, b, c, d, e}]//MatrixForm
Wolfram Language code: SparseArray[Band[{1, 1}] -> {a, b, c, d, e}]//MatrixForm
Wolfram Research (2007), Band, Wolfram Language function, https://reference.wolfram.com/language/ref/Band.html.

Text

Wolfram Research (2007), Band, Wolfram Language function, https://reference.wolfram.com/language/ref/Band.html.

CMS

Wolfram Language. 2007. "Band." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/Band.html.

APA

Wolfram Language. (2007). Band. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Band.html

BibTeX

@misc{reference.wolfram_2026_band, author="Wolfram Research", title="{Band}", year="2007", howpublished="\url{https://reference.wolfram.com/language/ref/Band.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_band, organization={Wolfram Research}, title={Band}, year={2007}, url={https://reference.wolfram.com/language/ref/Band.html}, note=[Accessed: 12-June-2026]}