WOLFRAM

Wolfram Language & System Documentation Center

LowerTriangularize[m]

gives a matrix in which all but the lower triangular elements of m are replaced with zeros.

LowerTriangularize[m,k]

replaces with zeros only the elements above the k^(th) subdiagonal of m.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Basic Uses  
Special Matrices  
Options  
TargetStructure  
Applications  
Properties & Relations  
See Also
Related Guides
History
Cite this Page

LowerTriangularize

LowerTriangularize[m]

gives a matrix in which all but the lower triangular elements of m are replaced with zeros.

LowerTriangularize[m,k]

replaces with zeros only the elements above the k^(th) subdiagonal of m.

Details and Options

Examples

open all close all

Basic Examples  (3)

Get the lower triangular part of a matrix:

Wolfram Language code: MatrixForm[LowerTriangularize[{{1, 2, 3}, {4, 5, 6}, {7, 8, 9}}]]

Get the strictly lower triangular part of a matrix:

Wolfram Language code: MatrixForm[LowerTriangularize[{{1, 2, 3}, {4, 5, 6}, {7, 8, 9}}, -1]]

Get the lower triangular part of a matrix plus the diagonal above the main diagonal:

Wolfram Language code: MatrixForm[LowerTriangularize[{{1, 2, 3}, {4, 5, 6}, {7, 8, 9}}, 1]]

Scope  (12)

Basic Uses  (8)

Get the lower triangular part of nonsquare matrices:

Wolfram Language code: MatrixForm[LowerTriangularize[{{1, 2, 3, 4}, {5, 6, 7, 8}, {9, 10, 11, 12}}]]
Wolfram Language code: MatrixForm[LowerTriangularize[{{1, 2, 3}, {4, 5, 6}, {7, 8, 9}, {10, 11, 12}}]]

Find the lower triangular part of a machine-precision matrix:

Wolfram Language code: LowerTriangularize[{{1.25, 3.2, 3.2}, {7.9, -1.4, 5.1}, {1., -1.5, 3.2}}]//MatrixForm

Lower triangular part of a complex matrix:

Wolfram Language code: LowerTriangularize[{{1. + I, 2, 3 - 2 I}, {0, 4, 5I}, {1 + I, 6, 3 + 3I}}]//MatrixForm

Lower triangular part of an exact matrix:

Wolfram Language code: LowerTriangularize[{{2, 3}, {3, 1}, {2, 4}, {2, 3}}]//MatrixForm

Lower triangular part of an arbitrary-precision matrix:

Wolfram Language code: LowerTriangularize[RandomReal[4, {2, 2}, WorkingPrecision -> 20]]//MatrixForm

Compute the lower triangular part of a symbolic matrix:

Wolfram Language code: LowerTriangularize[{{a, b, c, d}, {e, f, g, h}}]//MatrixForm

Large matrices are handled efficiently:

Wolfram Language code: mat = RandomReal[{0, 10}, {800, 800}];
Wolfram Language code: LowerTriangularize[mat]; //Timing

The number of rows or columns limits the meaningful values of the parameter k:

Wolfram Language code: Table[MatrixForm[LowerTriangularize[{{1, 2, 3, 4}, {5, 6, 7, 8}, {9, 10, 11, 12}, {13, 14, 15, 16}}, k]], {k, -4, 3}]

Special Matrices  (4)

The lower triangular part of a sparse matrix is returned as a sparse matrix:

Wolfram Language code: SparseArray[{{1, 3} -> 1, {2, 2} -> 2, {3, 1} -> 3}, {3, 4}]
Wolfram Language code: LowerTriangularize[%]

Format the result:

Wolfram Language code: %//MatrixForm

The lower triangular part of structured matrices:

Wolfram Language code: SymmetrizedArray[{{1, 1} -> 3, {2, 2} -> 1, {3, 1} -> -5}, {3, 3}, Symmetric[All]]
Wolfram Language code: LowerTriangularize[%]
Wolfram Language code: QuantityArray[{{1, 2}, {3, 4}, {5, 6}}, {"Meters", "Seconds"}]
Wolfram Language code: LowerTriangularize[%, -1]

The lower triangular part of an identity matrix is the matrix itself:

Wolfram Language code: LowerTriangularize[IdentityMatrix[3]]

This is true of any diagonal matrix:

Wolfram Language code: LowerTriangularize[DiagonalMatrix[{1, 2, 3}]]//MatrixForm

Compute the lower triangular part, including the superdiagonal, for HilbertMatrix:

Wolfram Language code: LowerTriangularize[HilbertMatrix[{3, 4}], 1]//MatrixForm

Options  (2)

TargetStructure  (2)

A matrix:

Wolfram Language code: m = {{1, 2, 3}, {4, 5, 6}, {7, 8, 9}};

Return the result as a dense matrix:

Wolfram Language code: LowerTriangularize[m, TargetStructure -> "Dense"]

Return the result as a sparse matrix:

Wolfram Language code: LowerTriangularize[m, TargetStructure -> "Sparse"]

Return the result as a LowerTriangularMatrix:

Wolfram Language code: LowerTriangularize[m, TargetStructure -> "Structured"]

A sparse array:

Wolfram Language code: sa = SparseArray[{{1, 3} -> 1, {2, 2} -> 2, {3, 1} -> 3}, {3, 3}]

The setting TargetStructureAutomatic gives a sparse result:

Wolfram Language code: LowerTriangularize[sa, TargetStructure -> Automatic]

Convert the sparse array to a dense matrix:

Wolfram Language code: dsa = Normal[sa, SparseArray]

The setting TargetStructureAutomatic gives a dense result:

Wolfram Language code: LowerTriangularize[dsa, TargetStructure -> Automatic]

Applications  (1)

JordanDecomposition relates any matrix to an upper triangular matrix via a similarity transformation m=s.j.TemplateBox[{s}, Inverse]:

Wolfram Language code: m = {{1, 0, 0, 0}, {0, 1, 0, 0}, {1, -1, 1, 0}, {1, -1, 1, 1}}; {s, j} = JordanDecomposition[m];

Visualize the three matrices:

Wolfram Language code: MatrixForm /@ {m, j, s}

Verify that the Jordan matrix is upper triangular and similar to the original matrix:

Wolfram Language code: {UpperTriangularMatrixQ[j], m == s.j.Inverse[s]}

The matrix is diagonalizable iff its Jordan matrix is also lower triangular:

Wolfram Language code: {LowerTriangularize[j] == j, DiagonalizableMatrixQ[m]}

Properties & Relations  (6)

Matrices returned by LowerTriangularize satisfy LowerTriangularMatrixQ:

Wolfram Language code: LowerTriangularMatrixQ[LowerTriangularize[{{a, b}, {c, d}}]]
Wolfram Language code: LowerTriangularMatrixQ[LowerTriangularize[{{a, b}, {c, d}}, 1], 1]

The inverse of a lower triangular matrix is lower triangular:

Wolfram Language code: mat = LowerTriangularize[RandomInteger[{1, 10}, {5, 5}]];
Wolfram Language code: LowerTriangularMatrixQ[Inverse[mat]]

This extends to arbitrary powers and functions:

Wolfram Language code: LowerTriangularMatrixQ[MatrixPower[mat, n]]
Wolfram Language code: LowerTriangularMatrixQ[MatrixFunction[f, mat]]

The product of two (or more) lower triangular matrices is lower triangular:

Wolfram Language code: m1 = LowerTriangularize[RandomReal[1., {5, 5}]]; m2 = LowerTriangularize[RandomReal[1., {5, 5}]];
Wolfram Language code: LowerTriangularMatrixQ[m1.m2]

The determinant of a triangular matrix equals the product of the diagonal entries:

Wolfram Language code: m = LowerTriangularize[RandomReal[1., {5, 5}]];
Wolfram Language code: Det[m] == Apply[Times, Diagonal[m]]

Eigenvalues of a triangular matrix equal its diagonal elements:

Wolfram Language code: m = LowerTriangularize[RandomReal[1., {5, 5}]];
Wolfram Language code: Eigenvalues[m] == Reverse@Sort@Diagonal[m]

LowerTriangularize[m,k] is equivalent to Transpose[UpperTriangularize[Transpose[m], -k]]:

Wolfram Language code: m = RandomReal[1, {3, 5}]; k = RandomInteger[{-2, 4}]; {MatrixForm[l = LowerTriangularize[m, k]], l === Transpose[UpperTriangularize[Transpose[m], -k]]}
Wolfram Research (2008), LowerTriangularize, Wolfram Language function, https://reference.wolfram.com/language/ref/LowerTriangularize.html (updated 2023).

Text

Wolfram Research (2008), LowerTriangularize, Wolfram Language function, https://reference.wolfram.com/language/ref/LowerTriangularize.html (updated 2023).

CMS

Wolfram Language. 2008. "LowerTriangularize." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2023. https://reference.wolfram.com/language/ref/LowerTriangularize.html.

APA

Wolfram Language. (2008). LowerTriangularize. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/LowerTriangularize.html

BibTeX

@misc{reference.wolfram_2026_lowertriangularize, author="Wolfram Research", title="{LowerTriangularize}", year="2023", howpublished="\url{https://reference.wolfram.com/language/ref/LowerTriangularize.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_lowertriangularize, organization={Wolfram Research}, title={LowerTriangularize}, year={2023}, url={https://reference.wolfram.com/language/ref/LowerTriangularize.html}, note=[Accessed: 13-June-2026]}