WOLFRAM

Wolfram Language & System Documentation Center

BesselJZero[n,k]

represents the k^(th) zero of the Bessel function .

BesselJZero[n,k,x0]

represents the k^(th) zero greater than x0.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Numerical Evaluation  
Specific Values  
Visualization  
Differentiation and Series Expansions  
Applications  
Properties & Relations  
See Also
Tech Notes
Related Guides
History
Cite this Page

BesselJZero

BesselJZero[n,k]

represents the k^(th) zero of the Bessel function .

BesselJZero[n,k,x0]

represents the k^(th) zero greater than x0.

Details

  • Mathematical function, suitable for both symbolic and numerical manipulation.
  • N[BesselJZero[n,k]] gives a numerical approximation so long as the specified zero exists.
  • BesselJZero[n,k] represents the k^(th) zero greater than 0.
  • BesselJZero can be evaluated to arbitrary numerical precision.
  • BesselJZero automatically threads over lists. »

Examples

open all close all

Basic Examples  (5)

Evaluate numerically:

Wolfram Language code: N[BesselJZero[0, 1]]

Evaluate symbolically:

Wolfram Language code: BesselJ[0, BesselJZero[0, 1]]

Display zeros of the BesselJ function over a subset of the reals:

Wolfram Language code: Plot[BesselJ[1, z], {z, 0, 15}, Epilog -> {PointSize[0.03], Red, Point[Table[{BesselJZero[1, k], 0}, {k, 4}]]}]

Series expansion at the origin:

Wolfram Language code: Series[BesselJZero[n, x], {x, 0, 1}]

TraditionalForm formatting:

Wolfram Language code: BesselJZero[ν, k]//TraditionalForm

Scope  (18)

Numerical Evaluation  (7)

Evaluate numerically:

Wolfram Language code: BesselJZero[0., 2]

Find the first zero of greater than 40:

Wolfram Language code: N[BesselJZero[0, 1, 40]]

Evaluate to high precision:

Wolfram Language code: N[BesselJZero[1, 20, 40], 50]

Evaluate efficiently at high precision:

Wolfram Language code: N[BesselJZero[0, 1, 40`100]]//Timing
Wolfram Language code: N[BesselJZero[0, 2, 50`1000]];//Timing

Evaluate at a non-integer second argument:

Wolfram Language code: N[BesselJZero[0, 1 - 2 / 3], 20]

For BesselJZero[ν,k-α/π], the result is a zero of :

Wolfram Language code: BesselJ[0, %]Cos[2Pi / 3] - BesselY[0, %]Sin[2Pi / 3]

Compute average-case statistical intervals using Around:

Wolfram Language code: BesselJZero[ 1, Around[2, 0.01]]

Compute the elementwise values of an array using automatic threading:

Wolfram Language code: BesselJZero[1 / 2, {{2, 1}, {1, 3}}]//N

Or compute the matrix BesselJZero function using MatrixFunction:

Wolfram Language code: MatrixFunction[BesselJZero[1 / 2, #]&, {{2, 1}, {1, 3}}]//N

Specific Values  (3)

Limiting value at infinity:

Wolfram Language code: Limit[BesselJZero[2, x], x -> Infinity]

The first three zeros:

Wolfram Language code: {BesselJZero[0, 1], BesselJZero[0, 2], BesselJZero[0, 3]}//N

Find the first zero of BesselJ[1,x] using Solve:

Wolfram Language code: xzero = x /. Solve[BesselJ[1, x] == 0 && 2 < x < 6, x][[1]]
Wolfram Language code: Plot[BesselJ[1, x], {x, 0, 10}, Epilog -> Style[Point[{xzero, BesselJ[1, xzero]}], PointSize[Large], Red]]

Visualization  (3)

Visualize the zeroes of BesselJ as a step function:

Wolfram Language code: Plot[BesselJZero[0, 1, x], {x, 1, 10}]

Display zeros of the BesselJ function:

Wolfram Language code: Plot[BesselJ[1, z], {z, 0, 20}, Epilog -> {PointSize[0.03], Point[Table[{BesselJZero[1, k], 0}, {k, 6}]]}]

Show the first zero greater than 6:

Wolfram Language code: Plot[BesselJ[1, z], {z, 0, 10}, Epilog -> {PointSize[0.03], Red, Point[{BesselJZero[1, 1, 6], 0}]}]

Differentiation and Series Expansions  (5)

Find the derivative of Bessel zero with respect to k:

Wolfram Language code: D[BesselJZero[ν, k], k]

Second derivative:

Wolfram Language code: D[BesselJZero[2, x], {x, 2}]// Simplify

Find the Taylor expansion using Series:

Wolfram Language code: Series[BesselJZero[n, x], {x, 0, 2}]//Normal//Simplify

Find the series expansion at Infinity:

Wolfram Language code: Series[BesselJZero[n, x], {x, Infinity, 1}]

Taylor expansion at a generic point:

Wolfram Language code: Series[BesselJZero[n, x], {x, x0, 1}]

Applications  (3)

Find the first 10 eigenmodes of a circular drum with Dirichlet boundary conditions:

Wolfram Language code: modes = N[BesselJZero[0, Range[10]]]

Construct an amplitude comprising a certain mixture of modes:

Wolfram Language code: ampl[r_] = Sin[modes].BesselJ[0, r modes];

Circular density plot:

Wolfram Language code: ParametricPlot[{Cos[ϕ] r, Sin[ϕ] r}, {ϕ, 0, 2Pi}, {r, 0, 1}, ColorFunction -> Function[{x, y, ϕ, r}, GrayLevel[ampl[r]]], Mesh -> False, Axes -> False, BoundaryStyle -> None]

Radial drum displacement profile:

Wolfram Language code: Plot[ampl[r], {r, 0, 1}]

Find the coefficient in the Rayleigh criterion for diffraction-limited optics:

Wolfram Language code: BesselJZero[1, 1] / π //N

Analytically compute the eigenvalues of a Laplacian in Cartesian coordinates over a Disk:

Wolfram Language code: DEigenvalues[{-Laplacian[u[x, y], {x, y}], DirichletCondition[u[x, y] == 0, True]}, u[x, y], {x, y}∈Disk[], 3]

Properties & Relations  (1)

Asymptotic behavior of BesselJZero[ν,k] for large k:

Wolfram Language code: Series[BesselJZero[ν, k], {k, Infinity, 3}]
Wolfram Research (2007), BesselJZero, Wolfram Language function, https://reference.wolfram.com/language/ref/BesselJZero.html.

Text

Wolfram Research (2007), BesselJZero, Wolfram Language function, https://reference.wolfram.com/language/ref/BesselJZero.html.

CMS

Wolfram Language. 2007. "BesselJZero." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/BesselJZero.html.

APA

Wolfram Language. (2007). BesselJZero. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/BesselJZero.html

BibTeX

@misc{reference.wolfram_2026_besseljzero, author="Wolfram Research", title="{BesselJZero}", year="2007", howpublished="\url{https://reference.wolfram.com/language/ref/BesselJZero.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_besseljzero, organization={Wolfram Research}, title={BesselJZero}, year={2007}, url={https://reference.wolfram.com/language/ref/BesselJZero.html}, note=[Accessed: 12-June-2026]}