Series
Series[f,{x,x0,n}]
generates a power series expansion for f about the point x=x0 to order (x-x0)n, where n is an explicit integer.
Series[f,xx0]
generates the leading term of a power series expansion for f about the point x=x0.
Series[f,{x,x0,nx},{y,y0,ny},…]
successively finds series expansions with respect to x, then y, etc.
Details and Options
- Series can construct standard Taylor series, as well as certain expansions involving negative powers, fractional powers, and logarithms.
- Series detects certain essential singularities. On[Series::esss] makes Series generate a message in this case.
- Series can expand about the point x=∞.
- Series[f,{x,0,n}] constructs Taylor series for any function f according to the formula
. - Series effectively evaluates partial derivatives using D. It assumes that different variables are independent.
- The result of Series is usually a SeriesData object, which you can manipulate with other functions.
- Normal[series] truncates a power series and converts it to a normal expression.
- SeriesCoefficient[series,n] finds the coefficient of the n
-order term. - The following options can be given:
-
Analytic True whether to treat unrecognized functions as analytic Assumptions $Assumptions assumptions to make about parameters SeriesTermGoal Automatic number of terms in the approximation
Examples
open all close allBasic Examples (4)
Power series for the exponential function around 
:
Series[Exp[x], {x, 0, 10}]Convert to a normal expression:
Normal[%]Power series of an arbitrary function around 
:
Series[f[x], {x, a, 3}]Series[Cos[x] / x, {x, 0, 10}]In any operation on series, only appropriate terms are kept:
1 / (1 + %) + % ^ 2Find the leading term of a power series:
Series[Gamma[Sin[x] - x] ^ 3, x -> 0]Scope (10)
Univariate Series (10)
Series can handle fractional powers and logarithms:
Series[Sqrt[Sin[x]], {x, 0, 10}]Series[x ^ x, {x, 0, 4}]Symbolic parameters can often be used:
Series[(1 + x) ^ n, {x, 0, 4}]Laurent series with negative powers can be generated:
Series[1 / Sin[x] ^ 10, {x, 0, 2}]Truncate the series to the specified negative power:
Series[1 / Sin[x] ^ 10, {x, 0, -5}]Find power series for special functions:
Series[Gamma[x], {x, 0, 1}]Series[Zeta[x], {x, 0, 2}]Series[BesselK[0, x], {x, 0, 2}]Series[BesselJ[n, x], {x, 0, 4}]Series[JacobiSN[u, m], {u, 0, 5}]Series[HermiteH[n, x], {x, 1, 2}]Find the series for a function at a branch point:
Series[ArcSin[x], {x, 1, 1}]With x assumed to be to the left of the branch point, a simpler result is given:
Series[ArcSin[x], {x, 1, 1}, Assumptions -> (x < 1)]Series[Min[x, 1 - x], {x, a, 5}]Series[Sin[1 / x], {x, Infinity, 10}]Series[ArcSin[x], {x, Infinity, 5}]Series can give asymptotic series:
Series[x!, {x, Infinity, 5}]Series[BesselJ[0, x], {x, Infinity, 5}]Normal[Series[ProductLog[x], {x, Infinity, 0}]]Series expansions of implicit solutions to equations:
Series[Root[# ^ 5 + a # + 1&, 1], {a, 0, 10}]Series expansions of unevaluated integrals:
Integrate[Sin[a Sin[x]], {x, 0, a}]Series[%, {a, 0, 15}]Generalizations & Extensions (4)
Power series in two variables:
Series[Sin[x + y], {x, 0, 3}, {y, 0, 3}]Series is threaded element-wise over lists:
Series[{Sin[x], Cos[x], Tan[x]}, {x, 0, 5}]Series generates SeriesData expressions:
InputForm[Series[Sin[x], {x, 0, 5}]]Series can work with approximate numbers:
Series[Sin[2.5 x], {x, 0, 10}]Options (4)
Analytic (1)
Series by default assumes symbolic functions to be analytic:
Series[f[x]Exp[x], {x, 0, 2}]Series[f[x] Exp[x], {x, 0, 2}, Analytic -> False]Assumptions (3)
Use Assumptions to specify regions in the complex plane where expansions should apply:
Series[ArcCos[x], {x, 1, 1}, Assumptions -> x > 1]Without assumptions, a piecewise constant factor 
appears:
Series[ArcCos[x], {x, 1, 1}]Get expansions in Stokes regions:
Series[AiryAi[x], {x, ComplexInfinity, 0}, Assumptions -> 0 < Arg[x] < Pi / 6]//SimplifySpecify assumptions on a parameter:
Series[AiryAi[a x], {x, Infinity, 0}, Assumptions -> a > 0]Without assumptions, the result is more complicated:
Series[AiryAi[a x], {x, Infinity, 0}]//FullSimplifyApplications (8)
Plot successive series approximations to 
:
Plot[Evaluate[Table[Normal[Series[Sin[x], {x, 0, n}]], {n, 20}]], {x, 0, 2Pi}]Find a series expansion for a standard combinatorial problem:
Series[(1 + 1 / n) ^ n, {n, Infinity, 5}]Find Fibonacci numbers from a generating function:
CoefficientList[Series[1 / (1 - t - t ^ 2), {t, 0, 15}], t]Find Legendre polynomials by expanding a generating function:
CoefficientList[Series[1 / Sqrt[1 - 2 t x + t ^ 2], {t, 0, 5}], t]Table[LegendreP[n, x], {n, 0, 5}]Set up a generating function to enumerate ways to make change using U.S. coins:
gf = 1 / Apply[Times, 1 - z ^ {1, 5, 10, 25, 50, 100}]Series[gf, {z, 0, 10}]The number of ways to make change for $1:
SeriesCoefficient[Series[gf, {z, 0, 100}], 100]Find the lowest-order terms in a large polynomial:
Series[(1 + 2x) ^ 1000, {x, 0, 5}]Normal[%]Find higher-order terms in Newton's approximation for a root of f[x] near 
:
InverseSeries[Series[f[x], {x, a, 3}], x]Normal[%] /. x -> 0Plot the complex zeros for a series approximation to Exp[x]:
ComplexListPlot[x /. NSolve[Normal[Series[Exp[x], {x, 0, 40}]] == 0, x]]Properties & Relations (10)
Series always only keeps terms up to the specified order:
Series[(1 + x) ^ 10, {x, 0, 5}]Operations on series keep only the appropriate terms:
Sqrt[%]Normal converts to an ordinary polynomial:
Sqrt[Normal[Series[(1 + x) ^ 10, {x, 0, 5}]]]Any mathematical function can be applied to a series:
Series[Sin[x], {x, 0, 10}]BesselJ[0, %] ^ %Adding a series of lower order causes the higher-order terms to be dropped:
Series[Exp[x], {x, 0, 10}]% + Series[Sin[x], {x, 0, 5}]D[Series[Tan[x], {x, 0, 10}], x]Solve equations for series coefficients:
Series[a Sin[x] + b Sin[2 x], {x, 0, 3}] == Series[Sinh[x], {x, 0, 3}]Solve[%, {a, b}]Find the list of coefficients in a series:
Series[Sin[x], {x, 0, 10}]CoefficientList[%, x]Use O[x] to force the construction of a series:
Sin[x] + O[x] ^ 10ComposeSeries treats a series as a function to apply to another series:
ComposeSeries[x + 2x ^ 2 + O[x] ^ 10, Series[Exp[x] - 1, {x, 0, 10}]]InverseSeries does series reversion to find the series for the inverse function of a series:
Series[Sin[x], {x, 0, 10}]InverseSeries[%, x]Series[ArcSin[x], {x, 0, 10}]Use FunctionAnalytic to test whether a function is analytic:
f = x Cos[2 ^ Sin[x ^ 2] + 2x];FunctionAnalytic[f, x]An analytic function can be expressed as a Taylor series at each point of its domain:
s = Series[f, {x, 0, 3}]The resulting polynomial approximates 
near 0:
Plot@@{{f, Normal[s]}, {x, -2, 2}}Possible Issues (7)
When there is an essential singularity, Series will attempt to factor it out:
Series[Sin[1 / x], {x, 0, 1}]Series[Sin[1 / x] Sin[x], {x, 0, 10}]Numeric values cannot be substituted directly for the expansion variable in a series:
Series[Exp[x], {x, 0, 10}]% /. x -> 1
Use Normal to get a normal expression in which the substitution can be done:
Normal[Series[Exp[x], {x, 0, 10}]] /. x -> 1Series must be converted to normal expressions before being plotted:
Plot[Evaluate[Normal[Series[Sin[x], {x, 0, 10}]]], {x, 0, 2Pi}]Power series with different expansion points cannot be combined:
Series[Exp[x], {x, 1, 3}] + Series[Exp[x], {x, 0, 3}]
Not all series are represented by expressions with head SeriesData:
Series[x ^ a Exp[x], {x, 0, 5}]InputForm[%]Some functions cannot be decomposed into series of power-like functions:
Series[Zeta[x], {x, Infinity, 10}]Series does not change expressions independent of the expansion variable:
Series[0, {x, 0, 4}]Series[Sin[y], {x, 0, 4}]Related Links
NKS|OnlineText
Wolfram Research (1988), Series, Wolfram Language function, https://reference.wolfram.com/language/ref/Series.html (updated 2020).
CMS
Wolfram Language. 1988. "Series." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2020. https://reference.wolfram.com/language/ref/Series.html.
APA
Wolfram Language. (1988). Series. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Series.html