BlomqvistBeta[dist,i,j]
gives the (i,j)
medial correlation coefficient for the multivariate symbolic distribution dist.
BlomqvistBeta
BlomqvistBeta[v1,v2]
gives Blomqvist's medial correlation coefficient β for the vectors v1 and v2.
gives Blomqvist's medial correlation coefficient β for the matrix m.
BlomqvistBeta[m1,m2]
gives Blomqvist's medial correlation coefficient β for the matrices m1 and m2.
BlomqvistBeta[dist]
gives the medial correlation coefficient matrix for the multivariate symbolic distribution dist.
BlomqvistBeta[dist,i,j]
gives the (i,j)
medial correlation coefficient for the multivariate symbolic distribution dist.
Details
- BlomqvistBeta[v1,v2] gives Blomqvist's medial correlation coefficient β between v1 and v2.
- Blomqvist's β between vectors x and y is given by Correlation[Sign[x-μx],Sign[y-μy]], where μx and μy are the medians of x and y, respectively.
- The arguments v1 and v2 can be any real‐valued vectors of equal length.
- For a matrix m with
columns BlomqvistBeta[m] is a 
×
matrix of the β's between columns of m. - For an
×
matrix m1 and an 
×
matrix m2 BlomqvistBeta[m1,m2] is a 
×
matrix of the β's between columns of m1 and columns of m2. - BlomqvistBeta[dist,i,j] is Probability[(x-μx)(y-μy)>0,{x,y}disti,j]-Probability[(x-μx)(y-μy)<0,{x,y}disti,j] where disti,j is the
marginal of dist. - BlomqvistBeta is not well defined for discrete distributions or in the presence of ties.
- BlomqvistBeta[dist] gives a matrix β where the
entry is given by BlomqvistBeta[dist,i,j].
Examples
open all close allBasic Examples (4)
Blomqvist's β for two vectors:
v1 = {3, -4, 1, 4, 22, 17, -2, 2, 13, -11};
v2 = {-20, -24, 0, 4, 24, 36, -12, -12, 56, -14};BlomqvistBeta[v1, v2]m = RandomVariate[BinormalDistribution[.6], 10^3];BlomqvistBeta[m]//MatrixFormBlomqvist's β for two matrices:
m1 = RandomReal[1, {10^3, 4}];m2 = RandomReal[1, {10^3, 3}];BlomqvistBeta[m1, m2]//MatrixFormCompute Blomqvist's β matrix for a bivariate distribution:
𝒟 = BinormalDistribution[.5];BlomqvistBeta[𝒟]//MatrixFormBlomqvistBeta[RandomVariate[𝒟, 10^6]]//MatrixFormScope (7)
Data (4)
Exact input yields exact output:
BlomqvistBeta[{-20, -21, 1, 7, 24, 36, -10, -12, 56, -14}, {3, -4, 1, 4, 22, 17, -2, 2, 13, -11}]Approximate input yields approximate output:
BlomqvistBeta[{1.5, 3, 5, 10}, {2, 1.25, 15, 8}]BlomqvistBeta[N[{1, 3, 5, 6, 9}, 30], N[{2, -1, 3, 11, 4}, 30]]BlomqvistBeta[RandomReal[1, 10 ^ 5], RandomReal[1, 10 ^ 5]]SparseArray data can be used:
BlomqvistBeta[SparseArray[{{2, 2} -> 1, {5, 3} -> 2, {10, 1} -> 3}]]//MatrixFormDistributions and Processes (3)
Blomqvist's β matrix for a continuous multivariate distribution:
BlomqvistBeta[BinormalDistribution[ρ]]//Simplify//MatrixFormBlomqvistBeta[BinormalDistribution[ρ], 2, 1]//SimplifyBlomqvist's β matrix for derived distributions:
BlomqvistBeta[ProductDistribution[ExponentialDistribution[1], NormalDistribution[3, 5]]]//MatrixForm𝒟 = CopulaDistribution[{"FGM", 2 / 3}, {UniformDistribution[{0, 1}], UniformDistribution[{0, 1}]}];BlomqvistBeta[𝒟]//MatrixForm𝒟 = HistogramDistribution[RandomVariate[BinormalDistribution[.75], 10 ^ 4]];BlomqvistBeta[𝒟]//MatrixFormBlomqvistBeta[BinormalDistribution[.75]]//MatrixFormBlomqvist's β matrix for a random process at times 
and 
:
BlomqvistBeta[WienerProcess[][{0.2, 0.3}]]//MatrixFormApplications (3)
Blomqvist's β is typically used to detect linear dependence between two vectors:
{v11, v21} = Transpose[RandomVariate[BinormalDistribution[.99], 1000]];
{v12, v22} = Transpose[RandomVariate[BinormalDistribution[0], 1000]];The absolute magnitude of β tends to 1 given strong linear dependence:
BlomqvistBeta[v11, v21]The value tends to 0 for linearly independent vectors:
BlomqvistBeta[v12, v22]Blomqvist's β can be used to measure linear association:
data = BlockRandom[SeedRandom[1];Table[RandomVariate[BinormalDistribution[i], 1000], {i, {-.99, -.75, -.25, -.5, 0., .25, .5, .75, .99}}]];Grid[Partition[Table[ListPlot[i, PlotStyle -> Directive[PointSize[Tiny]],
FrameTicks -> None, Frame -> True, Axes -> None, PlotLabel -> Row[{"β : ", BlomqvistBeta[i][[1, 2]]}]], {i, data}],
3]]Blomqvist's β only detects monotonic dependence structures:
uni = RandomReal[{-3, 3}, 1000];f[x_] := {{x, -Sqrt[Abs[x]] + RandomReal[.5]}, {x, .25x^2 + RandomReal[.5]}, {x, -Sinc[x] + RandomReal[.5]}, {Cos[x], Sin[x] + RandomReal[.5]}}data = f /@ uni;Table[ListPlot[data[[All, i]], Frame -> True, Axes -> None, PlotLabel -> Row[{"β : ", BlomqvistBeta[data[[All, i]]][[1, 2]]}], PlotStyle -> Directive[PointSize[Tiny]], FrameTicks -> None], {i, 4}]HoeffdingD can be used for a variety of other dependence structures:
Table[HoeffdingD[data[[All, i]]][[1, 2]], {i, 4}]Properties & Relations (7)
Blomqvist's β ranges from 
to 
for high negative and high positive association, respectively:
d = RandomVariate[NormalDistribution[], 100];BlomqvistBeta[d, d]BlomqvistBeta[d, -d]Blomqvist's β matrix is symmetric:
blb = BlomqvistBeta[RandomVariate[BinormalDistribution[1 / 3], 10 ^ 3]];SymmetricMatrixQ[blb]The diagonal elements of Blomqvist's β matrix are 1:
data = RandomInteger[{-3, 3}, {100, 15}];Diagonal[BlomqvistBeta[data]]Blomqvist's 
for even sample sizes:
d = RandomVariate[BinormalDistribution[.5], 100];med = Median[d]medCentered = Transpose[Transpose[d] - med];ListPlot[medCentered, Frame -> True, AspectRatio -> 1, PlotRange -> {{-3, 3}, {-3, 3}}]Count the number of points in each quadrant:
q1 = Count[medCentered, {x_, y_} /; x > 0 && y > 0];
q2 = Count[medCentered, {x_, y_} /; x <= 0 && y > 0];
q3 = Count[medCentered, {x_, y_} /; x <= 0 && y <= 0];
q4 = Count[medCentered, {x_, y_} /; x > 0 && y <= 0];n1 = q1 + q3n2 = q2 + q4(n1 - n2/n1 + n2)//NBlomqvistBeta[d[[All, 1]], d[[All, 2]]]//NBlomqvist's β will yield 
or 
if there is perfect monotonic association:
x = Sort@RandomReal[10, 50];
y = If[# > 5, 5#, #]& /@ x;ListPlot[{Transpose[{x, y}], Transpose[{x, -y}]}, Frame -> True]BlomqvistBeta[x, y]BlomqvistBeta[x, -y]This is in contrast to Correlation, which measures the degree of linear association:
Correlation[x, y]Correlation[x, -y]BlomqvistBetaTest can be used to test the value of β:
data = RandomVariate[BinormalDistribution[-.65], 100];BlomqvistBeta[data[[All, 1]], data[[All, 2]]]BlomqvistBetaTest[data[[All, 1]], data[[All, 2]], "TestDataTable"]IndependenceTest can be used to automatically select an appropriate test:
IndependenceTest[data[[All, 1]], data[[All, 2]], "TestDataTable"]Blomqvist's β for a bivariate distribution:
𝒟 = CopulaDistribution[{"AMH", 1}, {UniformDistribution[{0, 1}], UniformDistribution[{0, 1}]}];BlomqvistBeta[𝒟, 1, 2]{μx, μy} = Table[Mean[MarginalDistribution[𝒟, i]], {i, 2}]βExpected = Probability[(x - μx)(y - μy) > 0, {x, y}𝒟] - Probability[(x - μx)(y - μy) < 0, {x, y}𝒟]data = RandomVariate[𝒟, 10 ^ 6];BlomqvistBeta[data][[1, 2]] - βExpected//NText
Wolfram Research (2012), BlomqvistBeta, Wolfram Language function, https://reference.wolfram.com/language/ref/BlomqvistBeta.html.
CMS
Wolfram Language. 2012. "BlomqvistBeta." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/BlomqvistBeta.html.
APA
Wolfram Language. (2012). BlomqvistBeta. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/BlomqvistBeta.html