WOLFRAM

Wolfram Language & System Documentation Center

HoeffdingD[v1,v2]

gives Hoeffding's dependence measure for the vectors v1 and v2.

HoeffdingD[m]

gives Hoeffding's dependence measure for the matrix m.

HoeffdingD[m1,m2]

gives Hoeffding's dependence measure for the matrices m1 and m2.

HoeffdingD[dist]

gives Hoeffding's matrix for the multivariate symbolic distribution dist.

HoeffdingD[dist,i,j]

gives the ^(th) element of for the multivariate symbolic distribution dist.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Data  
Distributions and Processes  
Applications  
Properties & Relations  
See Also
Related Guides
History
Cite this Page

HoeffdingD

HoeffdingD[v1,v2]

gives Hoeffding's dependence measure for the vectors v1 and v2.

HoeffdingD[m]

gives Hoeffding's dependence measure for the matrix m.

HoeffdingD[m1,m2]

gives Hoeffding's dependence measure for the matrices m1 and m2.

HoeffdingD[dist]

gives Hoeffding's matrix for the multivariate symbolic distribution dist.

HoeffdingD[dist,i,j]

gives the ^(th) element of for the multivariate symbolic distribution dist.

Details

  • HoeffdingD[v1,v2] gives Hoeffding's dependence measure between v1 and v2.
  • Hoeffding's is a measure of dependence based on the relative order of elements in the two lists.
  • Hoeffding's between v1 and v2 is given by 30 (-2 (n-2) R+(n-3) (n-2) S+Q)/TemplateBox[{{n, -, 4}, 5}, Pochhammer], where is the number of observations in v1, , , , for , is the rank of v1i, is the rank of v2i, and is equal to Boole[a<b].
  • The arguments v1 and v2 can be any real‐valued vectors of equal length greater than 5.
  • For a matrix m with columns, HoeffdingD[m] is a × matrix of the dependence measures between columns of m.
  • For an × matrix m1 and an × matrix m2, HoeffdingD[m1,m2] is a × matrix of the dependence measures between columns of m1 and columns of m2.
  • HoeffdingD[dist,i,j] is given by 30 Expectation[(F[x,y]-G[x]H[y])^2,{x,y}disti,j], where F[x,y], G[x], and H[y] are the CDFs of the ^(th), ^(th), and ^(th) marginals of dist respectively.
  • HoeffdingD[dist] gives a matrix where the ^(th) entry is given by HoeffdingD[dist,i,j].

Examples

open all close all

Basic Examples  (4)

Hoeffding's for two vectors:

Wolfram Language code: v1 = {3, -4, 1, 4, 22, 17, -2, 2, 13, -11}; v2 = {-20, -24, 0, 4, 24, 36, -12, -12, 56, -14};
Wolfram Language code: HoeffdingD[v1, v2]

Hoeffding's for a matrix:

Wolfram Language code: m = RandomVariate[BinormalDistribution[.6], 10^3];
Wolfram Language code: HoeffdingD[m]//MatrixForm

Hoeffding's for two matrices:

Wolfram Language code: m1 = RandomReal[1, {10^3, 4}];
Wolfram Language code: m2 = RandomReal[1, {10^3, 3}];
Wolfram Language code: HoeffdingD[m1, m2]//MatrixForm

Compute Hoeffding's for a bivariate distribution:

Wolfram Language code: 𝒟 = BinormalDistribution[.5];
Wolfram Language code: HoeffdingD[𝒟]//MatrixForm

Compare to a simulated value:

Wolfram Language code: HoeffdingD[RandomVariate[𝒟, 10^4]]//MatrixForm

Scope  (7)

Data  (4)

Exact input yields exact output:

Wolfram Language code: HoeffdingD[{1, 2, 3, 1, 4, 6}, {2, 1, 8, 7, 2, 1}]

Approximate input yields approximate output:

Wolfram Language code: HoeffdingD[{1.1, 2, 3, 1, 4, 6}, {2, 1, 8, 7, 2, 1}]
Wolfram Language code: HoeffdingD[N[{1, 2, 3, 1, 4, 6}, 30], N[{2, 1, 8, 7, 2, 1}, 30]]

Works with large arrays:

Wolfram Language code: HoeffdingD[RandomReal[1, 10 ^ 4], RandomReal[1, 10 ^ 4]]

SparseArray data can be used:

Wolfram Language code: HoeffdingD[SparseArray[{{2, 2} -> 1, {5, 3} -> 2, {10, 1} -> 3}]]//MatrixForm

Distributions and Processes  (3)

Hoeffding's matrix for a continuous multivariate distribution:

Wolfram Language code: HoeffdingD[BinormalDistribution[.5]]//MatrixForm
Wolfram Language code: HoeffdingD[BinormalDistribution[0.3], 2, 1]

Hoeffding's matrix for derived distributions:

Wolfram Language code: HoeffdingD[ProductDistribution[ExponentialDistribution[1], NormalDistribution[3, 5]]]//MatrixForm
Wolfram Language code: 𝒟 = CopulaDistribution[{"FGM", 2 / 3}, {UniformDistribution[{0, 1}], UniformDistribution[{0, 1}]}];
Wolfram Language code: HoeffdingD[𝒟]//MatrixForm

Data distribution:

Wolfram Language code: 𝒟 = HistogramDistribution[RandomVariate[BinormalDistribution[.75], 10 ^ 2]];
Wolfram Language code: HoeffdingD[𝒟]//MatrixForm
Wolfram Language code: HoeffdingD[BinormalDistribution[.75]]//MatrixForm

Hoeffding's matrix for a random process at times and :

Wolfram Language code: HoeffdingD[WienerProcess[][{0.2, 0.3}]]//MatrixForm

Applications  (3)

Hoeffding's is typically used to detect non-monotonic dependency structures:

Wolfram Language code: x = RandomVariate[UniformDistribution[{-1, 1}], 100]; y = x^2 + RandomReal[{-.05, .05}, 100]; y2 = RandomVariate[UniformDistribution[{-1, 1}], 100];
Wolfram Language code: ListPlot[{Transpose[{x, y}], Transpose[{x, y2}]}]

Hoeffding's tends to be larger for dependent vectors:

Wolfram Language code: HoeffdingD[x, y]

The value tends to 0 for independent vectors:

Wolfram Language code: HoeffdingD[x, y2]

Hoeffding's can detect linear dependence:

Wolfram Language code: data = BlockRandom[SeedRandom[1];Table[RandomVariate[BinormalDistribution[i], 1000], {i, {-.99, -.75, -.25, -.5, 0., .25, .5, .75, .99}}]];
Wolfram Language code: Grid[Partition[Table[ListPlot[i, PlotStyle -> Directive[PointSize[Tiny]], FrameTicks -> None, Frame -> True, Axes -> None, PlotLabel -> Row[{"𝒟 : ", HoeffdingD[i][[1, 2]]}]], {i, data}], 3]]

SpearmanRho and KendallTau are more sensitive to linear dependence:

Wolfram Language code: Grid[Join[{{"𝒟", "τ", "ρ"}}, Round[Table[{HoeffdingD[i][[1, 2]], KendallTau[i][[1, 2]], SpearmanRho[i][[1, 2]]}, {i, data}], .01]], Alignment -> Right]

Hoeffding's can also detect many types of nonlinear dependence:

Wolfram Language code: uni = RandomReal[{-3, 3}, 1000];
Wolfram Language code: f[x_] := {{x, -Sqrt[Abs[x]] + RandomReal[.5]}, {x, .25x^2 + RandomReal[.5]}, {x, -Sinc[x] + RandomReal[.5]}, {Cos[x], Sin[x] + RandomReal[.5]}}
Wolfram Language code: data = f /@ uni;
Wolfram Language code: Table[ListPlot[data[[All, i]], Frame -> True, Axes -> None, PlotLabel -> Row[{"𝒟 : ", HoeffdingD[data[[All, i]]][[1, 2]]}], PlotStyle -> Directive[PointSize[Tiny]], FrameTicks -> None], {i, 4}]

Use HoeffdingDTest to determine if the value is statistically significant:

Wolfram Language code: Table[HoeffdingDTest[Sequence@@Transpose[data[[All, i]]], "TestDataTable"], {i, 4}]

Properties & Relations  (4)

Larger values of Hoeffding's indicate increasing dependence:

Wolfram Language code: dep = Range[-.999, .999, .005];
Wolfram Language code: data = BlockRandom[SeedRandom[1];Table[RandomVariate[BinormalDistribution[i], 500], {i, dep}]];
Wolfram Language code: ListPlot[Transpose[{dep, HoeffdingD[#][[1, 2]]& /@ data}], AxesLabel -> {"ρ", "𝒟"}]

Hoeffding's matrix is symmetric:

Wolfram Language code: hfd = HoeffdingD[RandomVariate[BinormalDistribution[1 / 3], 10 ^ 3]];
Wolfram Language code: SymmetricMatrixQ[hfd]

The diagonal elements of Hoeffding's matrix are 1:

Wolfram Language code: data = RandomInteger[{-3, 3}, {100, 15}];
Wolfram Language code: Diagonal[HoeffdingD[data]]

Hoeffding's for a continuous bivariate distribution:

Wolfram Language code: 𝒟 = CopulaDistribution[{"AMH", 2 / 3}, {UniformDistribution[{0, 1}], UniformDistribution[{0, 1}]}];
Wolfram Language code: HoeffdingD[𝒟, 1, 2]
Wolfram Language code: 30 Expectation[(CDF[𝒟, {x, y}] - CDF[ProductDistribution[Sequence@@Table[MarginalDistribution[𝒟, i], {i, 2}]], {x, y}])^2, {x, y}𝒟]
Wolfram Language code: % - %%//FullSimplify
Wolfram Research (2012), HoeffdingD, Wolfram Language function, https://reference.wolfram.com/language/ref/HoeffdingD.html.

Text

Wolfram Research (2012), HoeffdingD, Wolfram Language function, https://reference.wolfram.com/language/ref/HoeffdingD.html.

CMS

Wolfram Language. 2012. "HoeffdingD." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/HoeffdingD.html.

APA

Wolfram Language. (2012). HoeffdingD. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/HoeffdingD.html

BibTeX

@misc{reference.wolfram_2026_hoeffdingd, author="Wolfram Research", title="{HoeffdingD}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/HoeffdingD.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_hoeffdingd, organization={Wolfram Research}, title={HoeffdingD}, year={2012}, url={https://reference.wolfram.com/language/ref/HoeffdingD.html}, note=[Accessed: 12-June-2026]}