WOLFRAM

Wolfram Language & System Documentation Center

CarlsonRJ[x,y,z,ρ]

gives Carlson's elliptic integral TemplateBox[{x, y, z, rho}, CarlsonRJ].

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Numerical Evaluation  
Specific Values  
Differentiation and Integration  
Function Representations  
Function Identities and Simplifications  
Applications  
Properties & Relations  
See Also
Related Guides
History
Cite this Page

CarlsonRJ

CarlsonRJ[x,y,z,ρ]

gives Carlson's elliptic integral TemplateBox[{x, y, z, rho}, CarlsonRJ].

Details

  • Mathematical function, suitable for both symbolic and numerical manipulation.
  • For non-negative arguments, TemplateBox[{x, y, z, rho}, CarlsonRJ]=3/2int_0^infty(t+x)^(-1/2)(t+y)^(-1/2)(t+z)^(-1/2)(t+rho)^(-1)dt.
  • CarlsonRJ[x,y,z,ρ] has a branch cut discontinuity at .
  • CarlsonRJ[x,y,z,ρ] is understood as a Cauchy principal value integral for .
  • For certain arguments, CarlsonRJ automatically evaluates to exact values.
  • CarlsonRJ can be evaluated to arbitrary precision.
  • CarlsonRJ automatically threads over lists.
  • CarlsonRJ can be used with Interval and CenteredInterval objects. »

Examples

open all close all

Basic Examples  (3)

Evaluate numerically:

Wolfram Language code: CarlsonRJ[2., 3., 5., 7.2]

Visualize over a range of arguments:

Wolfram Language code: Plot[{CarlsonRJ[t, 3, 5, 4], CarlsonRJ[1, t, 5, 4], CarlsonRJ[1, 3, t, 4], CarlsonRJ[1, 3, 5, t]}, {t, -6, 6}, PlotLegends -> "Expressions"]

CarlsonRJ is related to the Legendre elliptic integral of the third kind TemplateBox[{n, phi, m}, EllipticPi3] for :

Wolfram Language code: (n/3)Sin[ϕ]^3CarlsonRJ[Cos[ϕ]^2, 1 - m Sin[ϕ]^2, 1, 1 - n Sin[ϕ]^2] /. {ϕ -> 0.7, m -> 0.5, n -> -3}
Wolfram Language code: EllipticPi[n, ϕ, m] - EllipticF[ϕ, m] /. {ϕ -> 0.7, m -> 0.5, n -> -3}

Scope  (14)

Numerical Evaluation  (6)

Evaluate numerically:

Wolfram Language code: CarlsonRJ[3, 5, 1, 0.2]
Wolfram Language code: CarlsonRJ[3, 5, 1., -5]

Evaluate at high precision:

Wolfram Language code: N[CarlsonRJ[1 / 3, 1 / 5, 1 / 7, 1], 50]

Precision of the output tracks the precision of the input:

Wolfram Language code: CarlsonRJ[1 / 3, 1 / 5, 1, 1.234567890123456789012345]
Wolfram Language code: CarlsonRJ[1 / 3, 1 / 5, 1, 1.2345678901234567890123456789012345]

Evaluate for complex arguments:

Wolfram Language code: CarlsonRJ[0.7 - 0.2I, 4, 2. + I / 3, 0.7 I]

Evaluate efficiently at high precision:

Wolfram Language code: Timing[CarlsonRJ[2, 4, 6, 3`500]]
Wolfram Language code: Timing[Precision@CarlsonRJ[2, 4, 6, 3`100000]]

CarlsonRJ threads elementwise over lists:

Wolfram Language code: CarlsonRJ[{1, 2, 3}, {2, 3, 1}, {3, 1, 2}, {0.1, 0.2, 0.5}]

CarlsonRJ can be used with Interval and CenteredInterval objects:

Wolfram Language code: CarlsonRJ[Interval[{1.23, 1.24}], Interval[{2.34, 2.35}], Interval[{3.45, 3.46}], Interval[{4.56, 4.57}]]
Wolfram Language code: CarlsonRJ[CenteredInterval[3 / 2, 1 / 100], CenteredInterval[5 / 4, 1 / 100], CenteredInterval[7 / 6, 1 / 100], CenteredInterval[9 / 8, 1 / 100]]

Specific Values  (3)

Simple exact values are generated automatically:

Wolfram Language code: CarlsonRJ[x, x, x, x] /. x -> EulerGamma
Wolfram Language code: CarlsonRJ[x, x, x, ρ] /. x -> Zeta[3]
Wolfram Language code: CarlsonRJ[x, y, Pi, Pi]

When one of the first three arguments of CarlsonRJ is zero, CarlsonRJ reduces to the complete elliptic integral CarlsonRM:

Wolfram Language code: CarlsonRJ[0, x, y, ρ]

When one of the first three arguments of CarlsonRJ is equal to the last argument, and they do not lie on the negative real axis, CarlsonRJ reduces to CarlsonRD:

Wolfram Language code: CarlsonRJ[x, y, 2 + 3I, 2 + 3I]

Differentiation and Integration  (2)

Derivative of TemplateBox[{x, y, z, rho}, CarlsonRJ] with respect to :

Wolfram Language code: D[CarlsonRJ[x, y, z, ρ], x]

Derivative of TemplateBox[{x, y, z, rho}, CarlsonRJ] with respect to :

Wolfram Language code: D[CarlsonRJ[x, y, z, ρ], ρ]

Indefinite integral of TemplateBox[{x, y, z, rho}, CarlsonRJ] with respect to :

Wolfram Language code: Integrate[CarlsonRJ[x, y, z, ρ], x]

Function Representations  (1)

TraditionalForm formatting:

Wolfram Language code: CarlsonRJ[Subscript[x, 1], Subscript[x, 2], Subscript[x, 3], ρ]//TraditionalForm

Function Identities and Simplifications  (2)

CarlsonRJ satisfies the Euler–Poisson partial differential equation:

Wolfram Language code: (x - y)Subscript[∂, x, y]CarlsonRJ[x, z, y, ρ] + (1/2)(Subscript[∂, y]CarlsonRJ[x, z, y, ρ] - Subscript[∂, x]CarlsonRJ[x, z, y, ρ]) == 0//FunctionExpand//FullSimplify
Wolfram Language code: (x - ρ)Subscript[∂, x, ρ]CarlsonRJ[x, z, y, ρ] + (1/2)Subscript[∂, ρ]CarlsonRJ[x, z, y, ρ] - Subscript[∂, x]CarlsonRJ[x, z, y, ρ] == 0//FunctionExpand//FullSimplify

CarlsonRJ satisfies Euler's homogeneity relation:

Wolfram Language code: xSubscript[∂, x]CarlsonRJ[x, z, y, ρ] + ySubscript[∂, y]CarlsonRJ[x, z, y, ρ] + zSubscript[∂, z]CarlsonRJ[x, z, y, ρ] + ρSubscript[∂, ρ]CarlsonRJ[x, z, y, ρ] == -(3/2)CarlsonRJ[x, z, y, ρ]//FunctionExpand//FullSimplify

Applications  (1)

Use CarlsonRJ to define a conformal map:

Wolfram Language code: f[w_] = (2 Cos[(w/2)]^2 /3 (1 + Cos[w]))(9 CarlsonRF[1, 1 - 2 Tan[(w/2)]^2, 1 - (1/3) Tan[(w/2)]^2] Tan[(w/2)] - 4 CarlsonRJ[1, 1 - 2 Tan[(w/2)]^2, 1 - (1/3) Tan[(w/2)]^2, Sec[(w/2)]^2] Tan[(w/2)]^3);

Visualize the image of lines of constant real and imaginary parts:

Wolfram Language code: ParametricPlot[{Re[f[u + I v]], Im[f[u + I v]]}, {u, -Pi / 2, Pi / 2}, {v, 1*^-4, 3}, Mesh -> 15, PlotPoints -> 100]

Properties & Relations  (2)

CarlsonRJ is invariant under a permutation of its first three arguments:

Wolfram Language code: CarlsonRJ[x, y, z, ρ] == CarlsonRJ[z, x, y, ρ]

Verify the change of parameter relation for CarlsonRJ:

Wolfram Language code: With[{q = x + ((y - x)(z - x)/p - x)}, (p - x)CarlsonRJ[x, y, z, p] + (q - x)CarlsonRJ[x, y, z, q] == 3CarlsonRF[x, y, z] - 3CarlsonRC[(y z/x), (p q/x)]] /. {{x -> 2, y -> 3, z -> 5, p -> 7.}, {x -> 2, y -> 3, z -> 5, p -> 1.}, {x -> 2, y -> 3, z -> 5, p -> -4.}}
Wolfram Research (2021), CarlsonRJ, Wolfram Language function, https://reference.wolfram.com/language/ref/CarlsonRJ.html (updated 2023).

Text

Wolfram Research (2021), CarlsonRJ, Wolfram Language function, https://reference.wolfram.com/language/ref/CarlsonRJ.html (updated 2023).

CMS

Wolfram Language. 2021. "CarlsonRJ." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2023. https://reference.wolfram.com/language/ref/CarlsonRJ.html.

APA

Wolfram Language. (2021). CarlsonRJ. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/CarlsonRJ.html

BibTeX

@misc{reference.wolfram_2026_carlsonrj, author="Wolfram Research", title="{CarlsonRJ}", year="2023", howpublished="\url{https://reference.wolfram.com/language/ref/CarlsonRJ.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_carlsonrj, organization={Wolfram Research}, title={CarlsonRJ}, year={2023}, url={https://reference.wolfram.com/language/ref/CarlsonRJ.html}, note=[Accessed: 12-June-2026]}