WOLFRAM

Wolfram Language & System Documentation Center

CarlsonRD[x,y,z]

gives the Carlson's elliptic integral TemplateBox[{x, y, z}, CarlsonRD].

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Numerical Evaluation  
Specific Values  
Differentiation and Integration  
Function Representations  
Function Identities and Simplifications  
Applications  
Properties & Relations  
See Also
Related Guides
History
Cite this Page

CarlsonRD

CarlsonRD[x,y,z]

gives the Carlson's elliptic integral TemplateBox[{x, y, z}, CarlsonRD].

Details

  • Mathematical function, suitable for both symbolic and numerical manipulation.
  • For non-negative arguments, TemplateBox[{x, y, z}, CarlsonRD]=3/2int_0^infty(t+x)^(-1/2)(t+y)^(-1/2)(t+z)^(-3/2)dt.
  • CarlsonRD[x,y,z] has a branch cut discontinuity at .
  • For certain arguments, CarlsonRD automatically evaluates to exact values.
  • CarlsonRD can be evaluated to arbitrary precision.
  • CarlsonRD automatically threads over lists.
  • CarlsonRD can be used with Interval and CenteredInterval objects. »

Examples

open all close all

Basic Examples  (3)

Evaluate numerically:

Wolfram Language code: CarlsonRD[2., 3., 5.]

Plot CarlsonRD:

Wolfram Language code: Plot[Table[CarlsonRD[3, y, z], {y, {1 / 2, 2, 5}}]//Evaluate, {z, 0, 10}, PlotLegends -> "Expressions"]

CarlsonRD is related to a combination of Legendre elliptic integrals restricted to :

Wolfram Language code: (m/3)Sin[ϕ]^3CarlsonRD[Cos[ϕ]^2, 1 - m Sin[ϕ]^2, 1] /. {ϕ -> Pi / 3, m -> 0.43}
Wolfram Language code: EllipticF[ϕ, m] - EllipticE[ϕ, m] /. {ϕ -> Pi / 3, m -> 0.43}

Scope  (15)

Numerical Evaluation  (6)

Evaluate CarlsonRD numerically:

Wolfram Language code: CarlsonRD[3 / 5, 11, 22 / 7.]

Evaluate to high precision:

Wolfram Language code: N[CarlsonRD[1, 7, 11], 50]

The precision of the output tracks the precision of the input:

Wolfram Language code: CarlsonRD[1, 7, 11.2345678901234567890123]
Wolfram Language code: CarlsonRD[1, 7, 11.234567890123456789012345678901234567]

Evaluate for complex arguments:

Wolfram Language code: CarlsonRD[1 + I, 1 - 2I, 5.]

Evaluate efficiently at high precision:

Wolfram Language code: Timing[CarlsonRD[11, 1, 34`500]]
Wolfram Language code: Timing[Precision[CarlsonRD[11, 1, 34`100000]]]

CarlsonRD threads elementwise over lists:

Wolfram Language code: CarlsonRD[{1, 2, 3, 4, 5}, 3, 4.]

CarlsonRD can be used with Interval and CenteredInterval objects:

Wolfram Language code: CarlsonRD[Interval[{1.23, 1.24}], Interval[{2.34, 2.35}], Interval[{3.45, 3.46}]]
Wolfram Language code: CarlsonRD[CenteredInterval[3 / 2, 1 / 100], CenteredInterval[5 / 4, 1 / 100], CenteredInterval[7 / 6, 1 / 100]]

Specific Values  (2)

Simple exact values are generated automatically:

Wolfram Language code: CarlsonRD[x, x, x]
Wolfram Language code: CarlsonRD[x, x, y]
Wolfram Language code: CarlsonRD[x, y, y]

When one argument of CarlsonRD is zero, CarlsonRD can be expressed in terms of the complete elliptic integrals CarlsonRE and CarlsonRK:

Wolfram Language code: CarlsonRD[0, x, y]

Differentiation and Integration  (2)

Derivative of TemplateBox[{x, y, z}, CarlsonRD] with respect to :

Wolfram Language code: D[CarlsonRD[x, y, z], x]

Derivative of TemplateBox[{x, y, z}, CarlsonRD] with respect to :

Wolfram Language code: D[CarlsonRD[x, y, z], z]

Indefinite integral of TemplateBox[{x, y, z}, CarlsonRD] with respect to :

Wolfram Language code: Integrate[CarlsonRD[x, y, z], x]

Indefinite integral of TemplateBox[{x, y, z}, CarlsonRD] with respect to :

Wolfram Language code: Integrate[CarlsonRD[x, y, z], z]

Function Representations  (1)

TraditionalForm formatting:

Wolfram Language code: CarlsonRD[x, y, z]//TraditionalForm

Function Identities and Simplifications  (4)

An equation relating CarlsonRD, CarlsonRF and CarlsonRG:

Wolfram Language code: 2CarlsonRG[x, y, z] == z CarlsonRF[x, y, z] + (Sqrt[x]Sqrt[y]/Sqrt[z]) - (1/3)(z - x)(z - y)CarlsonRD[x, y, z]//FullSimplify

Some cyclic permutation identities for CarlsonRD:

Wolfram Language code: CarlsonRD[x, y, z] + CarlsonRD[y, z, x] + CarlsonRD[z, x, y] == (3/Sqrt[x]Sqrt[y]Sqrt[z])//FullSimplify
Wolfram Language code: z CarlsonRD[x, y, z] + x CarlsonRD[y, z, x] + y CarlsonRD[z, x, y] == 3CarlsonRF[x, y, z]//FullSimplify
Wolfram Language code: z(x + y)CarlsonRD[x, y, z] + x(y + z)CarlsonRD[y, z, x] + y(z + x)CarlsonRD[z, x, y] == 6CarlsonRG[x, y, z]//FunctionExpand//FullSimplify

CarlsonRD satisfies the Euler–Poisson partial differential equation:

Wolfram Language code: (x - y)Subscript[∂, x, y]CarlsonRD[x, y, z] + (1/2)(Subscript[∂, y]CarlsonRD[x, y, z] - Subscript[∂, x]CarlsonRD[x, y, z]) == 0//FunctionExpand//FullSimplify
Wolfram Language code: (x - z)Subscript[∂, x, z]CarlsonRD[x, y, z] + (1/2)(Subscript[∂, z]CarlsonRD[x, y, z] - 3Subscript[∂, x]CarlsonRD[x, y, z]) == 0//FunctionExpand//FullSimplify

CarlsonRD satisfies Euler's homogeneity relation:

Wolfram Language code: xSubscript[∂, x]CarlsonRD[x, y, z] + ySubscript[∂, y]CarlsonRD[x, y, z] + zSubscript[∂, z]CarlsonRD[x, y, z] == -(3/2)CarlsonRD[x, y, z]//FunctionExpand//FullSimplify

Applications  (2)

Distance along a meridian of the Earth:

Wolfram Language code: With[{a = UnitConvert[GeodesyData["ITRF00", "SemimajorAxis"], $UnitSystem], e = GeodesyData["ITRF00", "Eccentricity"], ϕ = 29°}, a(1 - e^2)(Sin[ϕ]CarlsonRF[Cos[ϕ]^2, 1 - e^2Sin[ϕ]^2, 1] + (e^2/3)Sin[ϕ]^3CarlsonRD[Cos[ϕ]^2, 1 - e^2Sin[ϕ]^2, 1])]

Compare with the result of GeoDistance:

Wolfram Language code: GeoDistance[GeoPosition[{0, 0}], GeoPosition[{29, 0}]]

Parametrization of a Mylar balloon (two flat sheets of plastic sewn together at their circumference and then inflated):

Wolfram Language code: With[{kk = N[π CarlsonRK[2, 4]]}, ParametricPlot3D[{JacobiCN[u, (1/2)]Cos[v], JacobiCN[u, (1/2)]Sin[v], (1/Sqrt[2])(u - (1/3)JacobiSN[u, (1/2)]^3CarlsonRD[JacobiCN[u, (1/2)]^2, JacobiDN[u, (1/2)]^2, 1])}, {u, -kk, kk}, {v, -π, π}, Exclusions -> None, PlotRange -> All]]

Properties & Relations  (1)

CarlsonRD is symmetric with respect to its first two arguments:

Wolfram Language code: CarlsonRD[x, y, z] == CarlsonRD[y, x, z]
Wolfram Research (2021), CarlsonRD, Wolfram Language function, https://reference.wolfram.com/language/ref/CarlsonRD.html (updated 2023).

Text

Wolfram Research (2021), CarlsonRD, Wolfram Language function, https://reference.wolfram.com/language/ref/CarlsonRD.html (updated 2023).

CMS

Wolfram Language. 2021. "CarlsonRD." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2023. https://reference.wolfram.com/language/ref/CarlsonRD.html.

APA

Wolfram Language. (2021). CarlsonRD. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/CarlsonRD.html

BibTeX

@misc{reference.wolfram_2026_carlsonrd, author="Wolfram Research", title="{CarlsonRD}", year="2023", howpublished="\url{https://reference.wolfram.com/language/ref/CarlsonRD.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_carlsonrd, organization={Wolfram Research}, title={CarlsonRD}, year={2023}, url={https://reference.wolfram.com/language/ref/CarlsonRD.html}, note=[Accessed: 12-June-2026]}