WOLFRAM

Wolfram Language & System Documentation Center

Catch[expr]

returns the argument of the first Throw generated in the evaluation of expr.

Catch[expr,form]

returns value from the first Throw[value,tag] for which form matches tag.

Catch[expr,form,f]

returns f[value,tag].

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Generalizations & Extensions  
Applications  
Properties & Relations  
See Also
Tech Notes
Related Guides
Related Links
History
Cite this Page

Catch

Catch[expr]

returns the argument of the first Throw generated in the evaluation of expr.

Catch[expr,form]

returns value from the first Throw[value,tag] for which form matches tag.

Catch[expr,form,f]

returns f[value,tag].

Details

  • Catch[expr,…] always returns the value of expr if no Throw was generated during the evaluation.
  • form can be any expression, and is often a pattern.
  • tag in Throw[value,tag] is re‐evaluated every time it is compared to form.

Examples

open all close all

Basic Examples  (3)

Exit to the enclosing Catch as soon as the Throw is evaluated:

Wolfram Language code: Catch[a;b;Throw[c];d;e]

Define a function that can "throw an exception":

Wolfram Language code: f[x_] := If[x > 10, Throw[overflow], x!]

The result of the Catch is just what is thrown by Throw:

Wolfram Language code: Catch[f[2] + f[11]]
Wolfram Language code: Catch[f[2] + f[3]]

Use Throw to exit a loop when a criterion is satisfied:

Wolfram Language code: Catch[Do[If[i! > 10 ^ 10, Throw[i]], {i, 100}]]

Scope  (5)

Catch can catch a Throw from inside essentially any function:

Wolfram Language code: Catch[If[# < 0, Throw[#]]& /@ {1, 2, 0, -1, 5, 6}]
Wolfram Language code: Catch[{a, Throw[b], c}]
Wolfram Language code: Catch[a ^ 2 + b ^ 2 + c ^ 2 /. b :> Throw[bbb]]

The nearest enclosing Catch catches the Throw:

Wolfram Language code: Catch[{Catch[{a, Throw[b], c}], d, e}]

Catch picks up the first Throw that is evaluated:

Wolfram Language code: Catch[{Throw[a], Throw[b], Throw[c]}]
Wolfram Language code: Catch[Throw /@ {a, b, c}]

Throw need not occur lexically inside Catch:

Wolfram Language code: f[x_] := (If[x < 0, Throw["negative"]];Sqrt[x])
Wolfram Language code: Catch[Sum[f[i], {i, 5, -5, -1}]]

A function that can throw a number of different exceptions:

Wolfram Language code: f[x_] := Which[ x < 0, Throw[x, error[negative]], x == 0, Throw[x, error[zero]], True, 1 / Sqrt[x]]

A handler for the possible exceptions:

Wolfram Language code: ff[x_] := Catch[f[x], error[_], Function[{value, tag}, tag /. {error[negative] :> Indeterminate, error[zero] :> Infinity, _ :> Throw[value, tag]}]]
Wolfram Language code: ff /@ {-1, 0, 1}

Generalizations & Extensions  (3)

Catch the Throw with tag u:

Wolfram Language code: Catch[Throw[a, u], u]

The inner Catch catches the Throw:

Wolfram Language code: Catch[f[Catch[Throw[a, u], u]], v]

The outer Catch catches the Throw:

Wolfram Language code: Catch[f[Catch[Throw[a, u], v]], u]

Keep the tag local:

Wolfram Language code: Module[{u}, Catch[Throw[a, u], u]]

Applications  (3)

Find the next prime after 1010:

Wolfram Language code: Catch[Do[If[PrimeQ[i], Throw[i]], {i, 10 ^ 10, 10 ^ 10 + 1000}]]

Find the first power of 17 equal to 1 mod 19:

Wolfram Language code: Catch[Do[If[Mod[17 ^ i, 19] == 1, Throw[i]], {i, 19}]]

Stop if an iteration gets too large:

Wolfram Language code: NestList[# ^ 2 + 1&, 2, 6]
Wolfram Language code: Catch[NestList[If[# > 1000, Throw[#], # ^ 2 + 1]&, 2, 6]]

Properties & Relations  (1)

Use Check to throw an exception if a message is generated:

Wolfram Language code: Catch[2 + Check[1 / (1 + 1 / 0), Throw[error]]]
Wolfram Language code: Catch[2 + Check[1 / (1 + 1 / 2), Throw[error]]]
Wolfram Research (1988), Catch, Wolfram Language function, https://reference.wolfram.com/language/ref/Catch.html (updated 1996).

Text

Wolfram Research (1988), Catch, Wolfram Language function, https://reference.wolfram.com/language/ref/Catch.html (updated 1996).

CMS

Wolfram Language. 1988. "Catch." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 1996. https://reference.wolfram.com/language/ref/Catch.html.

APA

Wolfram Language. (1988). Catch. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Catch.html

BibTeX

@misc{reference.wolfram_2026_catch, author="Wolfram Research", title="{Catch}", year="1996", howpublished="\url{https://reference.wolfram.com/language/ref/Catch.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_catch, organization={Wolfram Research}, title={Catch}, year={1996}, url={https://reference.wolfram.com/language/ref/Catch.html}, note=[Accessed: 13-June-2026]}