WOLFRAM

Wolfram Language & System Documentation Center

CheckAbort[expr,failexpr]

evaluates expr, returning failexpr if an abort occurs.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Options  
PropagateAborts  
Properties & Relations  
See Also
Tech Notes
Related Guides
History
Cite this Page

CheckAbort

CheckAbort[expr,failexpr]

evaluates expr, returning failexpr if an abort occurs.

Details and Options

Examples

open all close all

Basic Examples  (1)

Catch an abort in a part of a computation allowing the rest of it to continue:

Wolfram Language code: CheckAbort[Abort[];1, 2] + x

Scope  (3)

Use CheckAbort inside AbortProtect to detect aborts:

Wolfram Language code: AbortProtect[Abort[];CheckAbort[Echo["no abort"], Echo["yes abort"]];Echo["end of AbortProtect"]]

The return value may depend on the function that generated the abort:

Wolfram Language code: TimeConstrained[AbortProtect[Pause[1];CheckAbort[Echo["no abort"], Echo["yes abort"]];Echo["end of AbortProtect"]], .5, "Timed out"]

Use PropagateAborts to control whether aborts continue or terminate after CheckAbort:

Wolfram Language code: AbortProtect[Abort[];CheckAbort[Echo["A1"], Echo["A2"], PropagateAborts -> True]; CheckAbort[Echo["B1"], Echo["B2"], PropagateAborts -> False];CheckAbort[Echo["C1"], Echo["c2"], PropagateAborts -> False];Echo["finished AbortProtect"]]

Use CheckAbort inside TimeConstrained to select which parts are skipped if the limit is reached:

Wolfram Language code: TimeConstrained[CheckAbort[Pause[1];Echo["first"], Echo["second"], PropagateAborts -> False];Echo["finished CheckAbort"], .1]

This can also be done with MemoryConstrained:

Wolfram Language code: MemoryConstrained[CheckAbort[Range[10 ^ 6];Echo["first"], Echo["second"], PropagateAborts -> False];Echo["finished CheckAbort"], 10 ^ 4]

Options  (2)

PropagateAborts  (2)

The default setting, Automatic, does not propagate user-initiated aborts outside of CheckAbort:

Wolfram Language code: CheckAbort[Abort[], Echo["check"], PropagateAborts -> Automatic];Echo["past CheckAbort"]

Use the setting PropagateAbortsTrue to force the abort to persist past the CheckAbort:

Wolfram Language code: CheckAbort[Abort[], Echo["check"], PropagateAborts -> True];Echo["past CheckAbort"]

Aborts created by TimeConstrained are by default propagated:

Wolfram Language code: TimeConstrained[ CheckAbort[Pause[1], Echo["check"], PropagateAborts -> Automatic];Echo["past CheckAbort"], .1]

Use the setting PropagateAbortsFalse to prevent the abort from persisting:

Wolfram Language code: TimeConstrained[ CheckAbort[Pause[1], Echo["check"], PropagateAborts -> False];Echo["past CheckAbort"], .1]

Aborts created by MemoryConstrained are similar:

Wolfram Language code: MemoryConstrained[ CheckAbort[Range[10 ^ 6], Echo["check"], PropagateAborts -> Automatic];Echo["past CheckAbort"], 10 ^ 4]

Properties & Relations  (5)

The evaluation of the second argument cannot be interrupted once begun:

Wolfram Language code: AbsoluteTiming[TimeConstrained[CheckAbort[Abort[], Pause[3];Echo["check"]], 0.1, Echo["constraint"]]]

The argument is effectively wrapped in AbortProtect:

Wolfram Language code: AbsoluteTiming[TimeConstrained[CheckAbort[Abort[], AbortProtect[Pause[3];Echo["check"]]], 0.1, Echo["constraint"]]]

CheckAbort enables and detects aborts even if enclosed within AbortProtect:

Wolfram Language code: AbortProtect[ CheckAbort[Echo["before"];Abort[];Echo["after"], Echo["check"]]]

While the computation inside the CheckAbort is terminated, AbortProtect runs to completion:

Wolfram Language code: AbortProtect[ CheckAbort[Echo["before"];Abort[];Echo["after"], Echo["check"]];Echo["passed CheckAbort"]]

A nested AbortProtect will delay an abort but not prevent it from being detected by CheckAbort:

Wolfram Language code: CheckAbort[ AbortProtect[Echo["before"];Abort[];Echo["after"]], Echo["check"]]

If an abort is already active when CheckAbort begins, the first argument will not be evaluated:

Wolfram Language code: TimeConstrained[AbortProtect[Pause[1];CheckAbort[Echo["first"], Echo["second"]];Echo["finished AbortProtect"]], .1]

CheckAbort can be used to perform cleanup if a computation is interrupted:

Wolfram Language code: f[x_] := Module[{y}, CheckAbort[$myFlag = True;If[EvenQ[x], y = 2x, Abort[]];$myFlag = False;y, $myFlag = False;$Aborted ] ]

$myFlag is set to False even for inputs that produce an abort:

Wolfram Language code: f[3]
Wolfram Language code: $myFlag

WithCleanup accomplishes this same goal with significantly less code:

Wolfram Language code: g[x_] := WithCleanup[$myFlag = True, If[EvenQ[x], 2x, Abort[]], $myFlag = False]
Wolfram Language code: g[3]
Wolfram Language code: $myFlag
Wolfram Research (1991), CheckAbort, Wolfram Language function, https://reference.wolfram.com/language/ref/CheckAbort.html (updated 2022).

Text

Wolfram Research (1991), CheckAbort, Wolfram Language function, https://reference.wolfram.com/language/ref/CheckAbort.html (updated 2022).

CMS

Wolfram Language. 1991. "CheckAbort." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2022. https://reference.wolfram.com/language/ref/CheckAbort.html.

APA

Wolfram Language. (1991). CheckAbort. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/CheckAbort.html

BibTeX

@misc{reference.wolfram_2026_checkabort, author="Wolfram Research", title="{CheckAbort}", year="2022", howpublished="\url{https://reference.wolfram.com/language/ref/CheckAbort.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_checkabort, organization={Wolfram Research}, title={CheckAbort}, year={2022}, url={https://reference.wolfram.com/language/ref/CheckAbort.html}, note=[Accessed: 12-June-2026]}