WOLFRAM

Wolfram Language & System Documentation Center

Characters["string"]

gives a list of the characters in a string.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Applications  
Properties & Relations  
Possible Issues  
See Also
Tech Notes
Related Guides
Related Links
History
Cite this Page

Characters

Characters["string"]

gives a list of the characters in a string.

Details

  • Each character is given as a length one string.
  • Characters handles both ordinary and special characters.
  • Characters has attribute Listable.

Examples

open all close all

Basic Examples  (1)

Break a string into a list of characters:

Wolfram Language code: Characters["A string."]

Show in InputForm:

Wolfram Language code: InputForm[%]

Reassemble the string:

Wolfram Language code: StringJoin[%]

Scope  (2)

Characters handles special characters just like ordinary ones:

Wolfram Language code: Characters["◆αβγ⟷𝒜ℬ𝒞↵🙂😠"]

Characters threads itself element-wise over lists:

Wolfram Language code: Characters[{"ABC", "DEF", "XYZ"}]

Applications  (4)

Break a string into overlapping trigrams:

Wolfram Language code: Partition[Characters["this is a string"], 3, 1]

Reassemble into strings:

Wolfram Language code: StringJoin /@ %

Sort the characters in a string:

Wolfram Language code: Sort[Characters["this is a string"]]

Find their frequencies:

Wolfram Language code: Length /@ Split[%]

Rotate the characters in a string:

Wolfram Language code: StringJoin[RotateLeft[Characters["ABCDEFG"]]]

Make an array out of a list of strings:

Wolfram Language code: data = NestList[StringReplace[#, {"A" -> "BA", "B" -> "A"}]&, "A", 5]
Wolfram Language code: Characters[data]
Wolfram Language code: Grid[PadLeft[%]]
Wolfram Language code: ArrayPlot[Characters[data], ColorRules -> {"A" -> Yellow, "B" -> Blue}, Mesh -> True]

Properties & Relations  (2)

Characters gives a list of strings of length 1:

Wolfram Language code: Characters["A string."]
Wolfram Language code: InputForm[%]

Characters splits characters composed of multiple codes into their individual codes:

Wolfram Language code: Characters["हि"]

Also, some emoji characters will break apart into their constituent parts:

Wolfram Language code: Characters["👨‍🔧"]

Possible Issues  (3)

A string form of an expression must be created before it can be broken into characters:

Wolfram Language code: Characters[x + y]
Wolfram Language code: Characters[ToString[x + y]]

Characters operates on the explicit character form of strings:

Wolfram Language code: Characters["red"]

Characters normally treats special characters just like other characters:

Wolfram Language code: Characters["αβγ"]

Use ToString and FullForm to get the characters in the full names of special characters:

Wolfram Language code: Characters[ToString[FullForm["αβγ"]]]
Wolfram Research (1988), Characters, Wolfram Language function, https://reference.wolfram.com/language/ref/Characters.html (updated 1996).

Text

Wolfram Research (1988), Characters, Wolfram Language function, https://reference.wolfram.com/language/ref/Characters.html (updated 1996).

CMS

Wolfram Language. 1988. "Characters." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 1996. https://reference.wolfram.com/language/ref/Characters.html.

APA

Wolfram Language. (1988). Characters. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Characters.html

BibTeX

@misc{reference.wolfram_2026_characters, author="Wolfram Research", title="{Characters}", year="1996", howpublished="\url{https://reference.wolfram.com/language/ref/Characters.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_characters, organization={Wolfram Research}, title={Characters}, year={1996}, url={https://reference.wolfram.com/language/ref/Characters.html}, note=[Accessed: 13-June-2026]}