WOLFRAM

Wolfram Language & System Documentation Center

s1~~s2~~… or StringExpression[s1,s2,…]

represents a sequence of strings and symbolic string objects si.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Applications  
Properties & Relations  
See Also
Tech Notes
Related Guides
Related Links
History
Cite this Page

StringExpression

s1~~s2~~… or StringExpression[s1,s2,…]

represents a sequence of strings and symbolic string objects si.

Details

  • "str1"~~"str2"~~… yields an ordinary string obtained by concatenating the characters in the "stri".
  • The following objects can appear in StringExpression:
  • "string"a literal string of characters
    _any single character
    __any substring of one or more characters
    ___any substring of zero or more characters
    x_, x__, x___ substrings given the name x
    x:patternpattern given the name x
    pattern..pattern repeated one or more times
    pattern...pattern repeated zero or more times
    {patt1,patt2,…} or patt1|patt2|…a pattern matching at least one of the patti
    AnyOrder[patt1, patt2, …]a pattern matching all of the patti in any order
    FixedOrder[patt1, patt2, …]a pattern matching the concatenation of the patti
    patt/;conda pattern for which cond evaluates to True
    pattern?testa pattern for which test yields True for each character
    Whitespacea sequence of whitespace characters
    NumberStringthe characters of a number
    DatePattern[spec]the characters of a date
    charobjan object representing a character class (see below)
    RegularExpression["regexp"]substring matching a regular expression
    StringExpression[…]an arbitrary string expression
  • The following represent classes of characters:
  • {c1,c2,…}any of the "ci"
    Characters["c1c2…"]any of the "ci"
    CharacterRange["c1","c2"]any character in the range "c1" to "c2"
    HexadecimalCharacterhexadecimal digit 0-9, a-f, A-F
    DigitCharacterdigit 0–9
    LetterCharacterletter
    WhitespaceCharacterspace, newline, tab, or other whitespace character
    WordCharacterletter or digit
    Except[p]any character except ones matching p
  • The following represent positions in strings:
  • StartOfStringstart of the whole string
    EndOfStringend of the whole string
    StartOfLinestart of a line
    EndOfLineend of a line
    WordBoundaryboundary between word characters and others
    Except[WordBoundary]anywhere except a word boundary
  • When constructs like __ or .. are present, there may be several different ways in which a given StringExpression can match a particular string.
  • By default, the Wolfram Language will use the one that makes pattern elements that appear earlier in the StringExpression match the longest possible substrings.
  • The following determine which match will be used if there are several possibilities:
  • Shortest[p]the shortest consistent match for p
    Longest[p]the longest consistent match for p (default)
  • In matching ordinary expressions instead of strings, the shortest instead of the longest consistent match is used.
  • StringExpression objects can be used in many string manipulation functions, including StringReplace, StringCases, StringSplit, and StringMatchQ.
  • StringExpression has attributes Flat and OneIdentity.

Examples

open all close all

Basic Examples  (2)

A string expression representing the string "ab" followed by any single character:

Wolfram Language code: "ab" ~~ _

This makes a replacement for each occurrence of the string pattern "ab"~~__:

Wolfram Language code: StringReplace["abc abcb abdc", "ab" ~~ _ -> "X"]

Give all pairs of identical characters in the string:

Wolfram Language code: StringCases["abbcbccaabbabccaa", x_ ~~ x_]

Scope  (5)

A single blank (_) stands for any single character:

Wolfram Language code: StringReplace[{"ab", "abc", "abcd"}, "b" ~~ _ -> "X"]

Double blank (__) stands for any sequence of one or more characters:

Wolfram Language code: StringReplace[{"ab", "abc", "abcd"}, "b" ~~ __ -> "X"]

Triple blank (___) stands for any sequence of zero or more characters:

Wolfram Language code: StringReplace[{"ab", "abc", "abcd"}, "b" ~~ ___ -> "X"]

Use AnyOrder to match patterns in any order:

Wolfram Language code: StringMatchQ["4321", AnyOrder["1", "2", "3", "4"]]

Assigning a matching AnyOrder to a variable preserves the order in the string:

Wolfram Language code: StringCases["1342 1432", a : AnyOrder["1", "2", "3", "4"] :> a]

Applications  (1)

Find the primes with four identical digits:

Wolfram Language code: FromDigits /@ Select[IntegerDigits /@ Array[Prime, 1000, 1000000], MatchQ[#, {___, x_, ___, x_, ___, x_, ___, x_, ___}]&]//Timing

By converting to strings, you can use StringMatchQ:

Wolfram Language code: FromDigits /@ Select[IntegerDigits /@ Array[Prime, 1000, 1000000], StringMatchQ[FromCharacterCode[48 + #], StringExpression[___, x_, ___, x_, ___, x_, ___, x_, ___]]&]//Timing

Properties & Relations  (1)

StringExpression objects can be used in many string manipulation functions:

Wolfram Language code: StringMatchQ["apppbb", "a" ~~ ___ ~~ "b"]
Wolfram Language code: StringFreeQ["bcde", "c" ~~ __ ~~ "t"]
Wolfram Language code: StringCount["abcadcadcbaac", "a" ~~ _ ~~ "c"]
Wolfram Language code: StringCases["a10b6a77a3a#", "a" ~~ DigitCharacter..]
Wolfram Language code: StringReplace["aa abcd", WordBoundary ~~ "aa" ~~ WordBoundary -> "XX"]
Wolfram Language code: StringReplaceList["abxxabxxabxxabxxab", _ ~~ "ab" ~~ _ -> "X"]
Wolfram Language code: StringPosition["abxxabxxabxxabxxab", _ ~~ "ab" ~~ _]
Wolfram Language code: StringReplacePart["abxxabxxabxxabxxab", "X", %]
Wolfram Research (2004), StringExpression, Wolfram Language function, https://reference.wolfram.com/language/ref/StringExpression.html (updated 2014).

Text

Wolfram Research (2004), StringExpression, Wolfram Language function, https://reference.wolfram.com/language/ref/StringExpression.html (updated 2014).

CMS

Wolfram Language. 2004. "StringExpression." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2014. https://reference.wolfram.com/language/ref/StringExpression.html.

APA

Wolfram Language. (2004). StringExpression. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/StringExpression.html

BibTeX

@misc{reference.wolfram_2026_stringexpression, author="Wolfram Research", title="{StringExpression}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/StringExpression.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_stringexpression, organization={Wolfram Research}, title={StringExpression}, year={2014}, url={https://reference.wolfram.com/language/ref/StringExpression.html}, note=[Accessed: 12-June-2026]}