WOLFRAM

Wolfram Language & System Documentation Center

ClipPlanes

is an option to Graphics3D that specifies a list of clipping planes that can cut away portions of a 3D scene from the resulting view.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Generalizations & Extensions  
Properties & Relations  
Possible Issues  
Neat Examples  
See Also
Related Guides
History
Cite this Page

ClipPlanes

ClipPlanes

is an option to Graphics3D that specifies a list of clipping planes that can cut away portions of a 3D scene from the resulting view.

Details

  • ClipPlanes->InfinitePlane[…] specifies a single plane. ClipPlanes->{InfinitePlane[…],…} cuts away portions of the scene behind the specified planes.
  • ClipPlanes can be specified separately for particular objects in Graphics3D by giving a style option Style[obj,ClipPlanes->spec]. »
  • ClipPlanesStyle can be used to specify how clipping planes should be rendered.
  • The number of clipping planes that can be implemented with ClipPlanes is limited by available graphics hardware.
  • Graphics3D[…,ClipPlanes->{{a1,b1,c1,d1},…}] specifies a list of clipping planes defined as .
  • The default value is None.

Examples

open all close all

Basic Examples  (3)

Use ClipPlanes to specify a clipping plane:

Wolfram Language code: Graphics3D[{Sphere[]}, ClipPlanes -> InfinitePlane[{{0, 0, 0}, {0, 1, 1}, {1, 1, 2}}]]

Specify clipping planes for each object:

Wolfram Language code: Graphics3D[{Sphere[{0, 0, 0}, 1 / 2], Style[Sphere[], Red, ClipPlanes -> InfinitePlane[{{0, 0, 0}, {0, 1, 1}, {1, 1, 2}}]]}]

Use ClipPlanesStyle to show the clipping planes:

Wolfram Language code: Graphics3D[{Sphere[]}, ClipPlanes -> {InfinitePlane[{{0, 0, 0}, {0, 1, 1}, {1, 0, 1}}]}, ClipPlanesStyle -> Opacity[0.3]]

Scope  (7)

Use an InfinitePlane to specify a clip plane:

Wolfram Language code: Graphics3D[{Cone[]}, ClipPlanes -> InfinitePlane[{{0, 0, 0}, {0, 0, 1}, {0, 1, 1}}]]

Use multiple planes:

Wolfram Language code: Graphics3D[{Sphere[]}, ClipPlanes -> {InfinitePlane[{{0, 0, 0}, {0, 0, 1}, {0, 1, 1}}], InfinitePlane[{{0, 0, 0}, {0, 0, -1}, {1, 0, -1}}]}]

Specify a plane using coefficients of the plane equation:

Wolfram Language code: Graphics3D[{Sphere[]}, ClipPlanes -> {1, 1, -2, 0}]

Clip a 3D image:

Wolfram Language code: Image3D[RandomReal[1, {5, 10, 10}], ClipPlanes -> InfinitePlane[{{0, 0, 0}, {1, 1, 1}, {1, 1, 0}}]]

Clip a single object:

Wolfram Language code: Graphics3D[{Cone[], Style[Sphere[], ClipPlanes -> InfinitePlane[{{1, 0, .5}, {0, 0, 1}, {1, 1, 1}}]]}]

Specify ClipPlanes as a directive:

Wolfram Language code: Graphics3D[{Sphere[{0, 0, 0}], ClipPlanes -> InfinitePlane[{{0, 0, 0}, {0, 1, 0}, {1, 1, 0}}], Sphere[{1, 0, 0}]}]

Specify a clipping plane for a list of primitives:

Wolfram Language code: Graphics3D[{Sphere[{0, 0, 0}], Sphere[{1, 1, 0}], Style[{Sphere[{0, 1, 0}], Sphere[{1, 0, 0}]}, ClipPlanes -> InfinitePlane[{{0, 0, 0.8}, {0, 1, 0.8}, {1, 1, 0.8}}]]}]

Generalizations & Extensions  (3)

A clip plane can be styled using ClipPlanesStyle:

Wolfram Language code: Graphics3D[{Cone[]}, ClipPlanes -> InfinitePlane[{{0, 0, 0}, {0, 0, 1}, {0, 1, 1}}], ClipPlanesStyle -> Directive[Opacity[0.5], Green]]

A list of styles will be applied sequentially to the specified planes:

Wolfram Language code: Graphics3D[{Sphere[]}, ClipPlanes -> {InfinitePlane[{{0, 0, 0}, {0, 1, 0}, {1, 1, 0}}], InfinitePlane[{{0, 0, 0}, {0, 1, 0}, {0, 1, 1}}]}, ClipPlanesStyle -> {Directive[Red, Opacity[0.3]], Directive[Green, Opacity[0.3]]}]

Clip planes applied using Style can be styled separately:

Wolfram Language code: Graphics3D[{Style[Sphere[{0, 0, 0}], ClipPlanes -> InfinitePlane[{{0, 0, .5}, {0, 1, .5}, {1, 0, .5}}], ClipPlanesStyle -> Directive[Blue, Opacity[0.3]]], Style[Sphere[{1, 0, 0}], ClipPlanes -> InfinitePlane[{{0, -.5, 0}, {0, -.5, 1}, {1, -.5, 0}}], ClipPlanesStyle -> Directive[Red, Opacity[0.3]]]}]

Properties & Relations  (1)

The inside of a clipped primitive can be styled with the second argument to FaceForm:

Wolfram Language code: Graphics3D[{FaceForm[Green, Pink], Cone[]}, ClipPlanes -> InfinitePlane[{{0, 0, 0}, {0, 1, 1}, {0, 1, 0}}]]

Possible Issues  (1)

Large points and primitives may behave unpredictably when rotated:

Wolfram Language code: Graphics3D[{PointSize[.5], Sphere[{.1, -.1, 0}], Point[{.1, -.1, 0}]}, ClipPlanes -> InfinitePlane[{{0, 0, 0}, {1, 1, 1}, {1, 1, 0}}]]

Neat Examples  (2)

Cut away several sections of a sphere:

Wolfram Language code: Graphics3D[{FaceForm[Red, Blue], Sphere[{0, 0, 0}, 1.85]}, ClipPlanes -> Flatten@Table[InfinitePlane[{x, y, z}, {{x y, -x ^ 2 - z ^ 2, y z}, {-z, 0, x}}], {x, {-1, 1}}, {y, {-1, 1}}, {z, {-1, 1}}], Axes -> True]
Wolfram Language code: Graphics3D[{FaceForm[Red, Blue], Sphere[{0, 0, 0}, 1.85]}, ClipPlanes -> Flatten@Table[InfinitePlane[{x, y, z}, {{x y, -x ^ 2 - z ^ 2, y z}, {-z, 0, x}}], {x, {-1, 1}}, {y, {-1, 1}}, {z, {-1, 1}}], Axes -> True, ClipPlanesStyle -> GrayLevel[0.7, 0.3]]

Apply ClipPlanes to anatomical structures:

Wolfram Language code: With[{z = 400}, AnatomyPlot3D[{Entity["AnatomicalStructure", "LeftUpperLimb"], ClipPlanes -> {InfinitePlane[{{0, -300, z}, {300, -300, z + 200}, {200, 0, z}}]}, Entity["AnatomicalStructure", "SkinOfLeftUpperLimb"]}]]
Wolfram Research (2014), ClipPlanes, Wolfram Language function, https://reference.wolfram.com/language/ref/ClipPlanes.html (updated 2016).

Text

Wolfram Research (2014), ClipPlanes, Wolfram Language function, https://reference.wolfram.com/language/ref/ClipPlanes.html (updated 2016).

CMS

Wolfram Language. 2014. "ClipPlanes." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2016. https://reference.wolfram.com/language/ref/ClipPlanes.html.

APA

Wolfram Language. (2014). ClipPlanes. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ClipPlanes.html

BibTeX

@misc{reference.wolfram_2026_clipplanes, author="Wolfram Research", title="{ClipPlanes}", year="2016", howpublished="\url{https://reference.wolfram.com/language/ref/ClipPlanes.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_clipplanes, organization={Wolfram Research}, title={ClipPlanes}, year={2016}, url={https://reference.wolfram.com/language/ref/ClipPlanes.html}, note=[Accessed: 13-June-2026]}