Wolfram Language & System Documentation Center

InfinitePlane

InfinitePlane[{p₁,p₂,p₃}]

represents the plane passing through the points p₁, p₂, and p₃.

InfinitePlane[p,{v₁,v₂}]

represents the plane passing through the point p in the directions v₁ and v₂.

Details

InfinitePlane is also known as plane or hyperplane.
InfinitePlane can be used as a geometric region and graphics primitive.

InfinitePlane represents a plane or .
Hyperplane[n,p] is an alternative representation using a normal n in 3D.
InfinitePlane can be used in Graphics and Graphics3D.
InfinitePlane will be clipped by PlotRange when rendering.
In graphics, the points p, p_i and vector v can be Dynamic expressions.
Graphics rendering is affected by directives such as FaceForm, Opacity, and color.
FaceForm[front,back] can be used to specify different styles for the front and back in 3D. The front is defined by the right-hand rule and the direction of the points p_i or the vectors v_i.
InfinitePlane can be used with functions such as RegionMeasure, RegionCentroid, etc.

Examples

open all close all

Basic Examples (3)

An InfinitePlane in 3D:

Wolfram Language code: Graphics3D[InfinitePlane[{{1, 0, 0}, {1, 1, 1}, {0, 0, 1}}]]

Different styles applied to an infinite plane:

Wolfram Language code: ℛ = InfinitePlane[{{1, 0, 0}, {1, 1, 1}, {0, 0, 1}}];

Wolfram Language code:

{Graphics3D[{Pink, ℛ}], Graphics3D[{EdgeForm[Thick], Pink, ℛ}], Graphics3D[{EdgeForm[Dashed], Pink, ℛ}], Graphics3D[{EdgeForm[Directive[Thick, Dashed, Blue]], Pink, ℛ}]}

Determine if points belong to a given infinite plane:

Wolfram Language code: ℛ = InfinitePlane[{{1, 0, 0}, {1, 0, 1}, {1, 1, 0}}];

Wolfram Language code: {RegionMember[ℛ, {1, 2, 3}], RegionMember[ℛ, {0, 2, 3}]}

Scope (17)

Graphics (7)

Specification (2)

Define an infinite plane in 3D using three points:

Wolfram Language code: ill = Graphics3D[{PointSize[Medium], Point[{{1, 0, 0}, {1, 1, 1}, {0, 0, 1}}]}, PlotRange -> 2, Axes -> True];

Wolfram Language code: Show[ill, Graphics3D[InfinitePlane[{{1, 0, 0}, {1, 1, 1}, {0, 0, 1}}]]]

Define the same plane using a single point and two tangent vectors:

Wolfram Language code:

ill = Graphics3D[{PointSize[Medium], Point[{{1, 0, 0}}], Arrowheads[Medium], Thick, Arrow[{{1, 0, 0}, {1, 1, 1}}], Arrow[{{1, 0, 0}, {0, 0, 1}}]}, PlotRange -> 2, Axes -> True];

Wolfram Language code: Show[ill, Graphics3D[InfinitePlane[{1, 0, 0}, {{0, 1, 1}, {-1, 0, 1}}]]]

An infinite plane varying in direction:

Wolfram Language code:

Table[Graphics3D[InfinitePlane[{0, 0, 0}, {{1, 0, 0}, {1, Cos[θ], Sin[θ]}}], ImageSize -> Tiny, PlotLabel -> θ], {θ, 0, π, π / 4}]

Styling (2)

Color directives specify the color of the infinite plane:

Wolfram Language code: Table[Graphics3D[{c, InfinitePlane[{1, 0, 0}, {{0, 1, 1}, {-1, 0, 1}}]}], {c, {Red, Green, Yellow, Blue}}]

FaceForm and EdgeForm can be used to specify the styles of the faces and edges:

Wolfram Language code:

Graphics3D[{FaceForm[Pink], EdgeForm[Directive[Dashed, Thick, Blue]], InfinitePlane[{1, 0, 0}, {{0, 1, 1}, {-1, 0, 1}}]}]

Coordinates (3)

Specify coordinates by fractions of the plot range:

Wolfram Language code:

Graphics3D[InfinitePlane[{Scaled[{0.5, 0, 0}], Scaled[{0, 0.5, 0}], Scaled[{0.5, 0.5, 0.5}]}], PlotRange -> {{0, 10}, {0, 10}, {0, 10}}, Axes -> True]

Specify scaled offsets from the ordinary coordinates:

Wolfram Language code:

Graphics3D[InfinitePlane[{Scaled[{0, 0, 0.5}, {1, 0, 0}], Scaled[{0, 0, 0.5}, {0, 1, 0}], Scaled[{0, 0, 0.5}, {1, 1, 1}]}], PlotRange -> {{0, 2}, {0, 2}, {0, 2}}, Axes -> True]

Points and vectors can be Dynamic:

Wolfram Language code:

DynamicModule[{θ = 0}, {Slider[Dynamic[θ], {0, Pi}], Graphics3D[InfinitePlane[{0, 0, 0}, {{1, 0, 0}, Dynamic[{1, Cos[θ], Sin[θ]}]}]]}]

Regions (10)

Embedding dimension is the dimension of the coordinates:

Wolfram Language code:

RegionEmbeddingDimension[InfinitePlane[{{Subscript[x, 0], Subscript[y, 0]}, {Subscript[x, 1], Subscript[y, 1]}, {Subscript[x, 2], Subscript[y, 2]}}]]

Wolfram Language code:

RegionEmbeddingDimension[InfinitePlane[{Subscript[x, 0], Subscript[y, 0], Subscript[z, 0]}, {{Subscript[vx, 1], Subscript[vy, 1], Subscript[vz, 1]}, {Subscript[vx, 2], Subscript[vy, 2], Subscript[vz, 2]}}]]

Geometric dimension is the dimension of the region itself:

Wolfram Language code:

RegionEmbeddingDimension[InfinitePlane[{{Subscript[x, 0], Subscript[y, 0]}, {Subscript[x, 1], Subscript[y, 1]}, {Subscript[x, 2], Subscript[y, 2]}}]]

Wolfram Language code:

RegionDimension[InfinitePlane[{Subscript[x, 0], Subscript[y, 0], Subscript[z, 0]}, {{Subscript[vx, 1], Subscript[vy, 1], Subscript[vz, 1]}, {Subscript[vx, 2], Subscript[vy, 2], Subscript[vz, 2]}}]]

Point membership test:

Wolfram Language code: ℛ = InfinitePlane[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}}];

Wolfram Language code: {RegionMember[ℛ, {2, 2, 0}], RegionMember[ℛ, {0, 0, 1}]}

Get the conditions for membership:

Wolfram Language code: RegionMember[ℛ, {x, y, z}]

An infinite plane has infinite measure and undefined centroid:

Wolfram Language code: ℛ = InfinitePlane[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}}];

Wolfram Language code: RegionMeasure[ℛ]

Wolfram Language code: RegionCentroid[ℛ]

Distance from a point:

Wolfram Language code: ℛ = InfinitePlane[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}}];

Wolfram Language code: RegionDistance[ℛ, {0, 0, -3}]

Signed distance from a point:

Wolfram Language code: SignedRegionDistance[ℛ, {0, 0, -3}]

Nearest point in the region:

Wolfram Language code: ℛ = InfinitePlane[{{0, 0, 0}, {1, 0, 0}, {0, 3, 1}}];

Wolfram Language code: RegionNearest[ℛ, {1, 2, 3}]

Nearest points:

Wolfram Language code:

pts = Flatten[Table[{Cos[k 2 π / 8]Cos[j π / 8], Sin[k 2 π / 8]Cos[j π / 8], Sin[j π / 8]}, {k, 0, 7}, {j, -3, 3}], 1];
nst = RegionNearest[ℛ, #]& /@ pts;

Wolfram Language code:

Legended[Graphics3D[{{Opacity[0.5], ℛ}, {Thin, Gray, Line[Transpose[{pts, nst}]]}, {Red, Point[pts]}, {Blue, Point[nst]}}, Boxed -> False], PointLegend[{Red, Blue}, {"start", "nearest"}]]

An infinite plane is unbounded:

Wolfram Language code:

ℛ = InfinitePlane[{{Subscript[x, 0], Subscript[y, 0], Subscript[z, 0]}, {Subscript[x, 1], Subscript[y, 1], Subscript[z, 1]}, {Subscript[x, 2], Subscript[y, 2], Subscript[z, 2]}}];

Wolfram Language code: BoundedRegionQ[ℛ]

Find the region range:

Wolfram Language code: RegionBounds[ℛ]

Integrate over an infinite plane:

Wolfram Language code: ℛ = InfinitePlane[{{0, 0, 0}, {1, 0, 0}, {0, 1, 1}}];

Wolfram Language code: Integrate[Exp[-x^2 - y^2], {x, y, z}∈ℛ]

Optimize over an infinite plane:

Wolfram Language code: ℛ = InfinitePlane[{0, 0, 2}, {{1, 0, 0}, {0, 1, 0}}];

Wolfram Language code: Minimize[{x^2 + y^2 + z^2 + 1, {x, y, z}∈ℛ}, {x, y, z}]

Solve equations over an infinite plane:

Wolfram Language code: ℛ = InfinitePlane[{0, 0, 0}, {{1, 2, 0}, {0, 0, 3}}];

Wolfram Language code: Reduce[x^2 + y^2 + z^2 == 1 && {x, y, z}∈ℛ, {x, y, z}]

Applications (7)

Find the plane in which a triangle is embedded:

Wolfram Language code: {Subscript[p, 1], Subscript[p, 2], Subscript[p, 3]} = {{1, 0, 0}, {1, 1, 1}, {0, 0, 1}};

InfinitePlane can use the same parametrization as Triangle:

Wolfram Language code:

Subscript[ℛ, 1] = Triangle[{Subscript[p, 1], Subscript[p, 2], Subscript[p, 3]}];
Subscript[ℛ, 2] = InfinitePlane[{Subscript[p, 1], Subscript[p, 2], Subscript[p, 3]}];

Wolfram Language code: Graphics3D[{Red, Subscript[ℛ, 1], Opacity[0.5, Yellow], Subscript[ℛ, 2]}, PlotRange -> {{-2, 2}, {-2, 2}, {-2, 2}}]

Find the plane in which a polygon is embedded:

Wolfram Language code:

p0 = {1, 1, 1};
e1 = Normalize[{2, 1, 1}];e2 = Normalize[{-1, 1, 2}];

Wolfram Language code: pl = With[{p = 5}, Table[p0 + Cos[2Pi k / p]e1 + Sin[2Pi k / p]e2, {k, p}]];

To find the plane, take the first three points (or any three points not on a line):

Wolfram Language code:

Subscript[ℛ, 1] = Polygon[pl];
Subscript[ℛ, 2] = InfinitePlane[pl[[1 ;; 3]]];

Wolfram Language code: Graphics3D[{Red, Subscript[ℛ, 1], Opacity[0.5, Yellow], Subscript[ℛ, 2]}, PlotRange -> {{-2, 2}, {-2, 2}, {-2, 2}}]

The tangent plane to a parametric surface f[u,v] is given by InfinitePlane[f[u,v],{∂_uf[u,v],∂_vf[u,v]}]. Find the tangent plane to the parametric surface :

Wolfram Language code: f1[u_, v_] := {Cos[u]Sin[v], Sin[u]Sin[v], Cos[v]};

Wolfram Language code:

s1 = ParametricPlot3D[f1[u, v], {u, 0, 2π}, {v, 0, π}];
t1 = With[{u = 3π / 4, v = π / 4}, Graphics3D[{Opacity[0.5], InfinitePlane[f1[u, v], {Derivative[1, 0][f1][u, v], Derivative[0, 1][f1][u, v]}]}]];

Wolfram Language code: Show[s1, t1, PlotRangePadding -> Scaled[0.2]]

Find the tangent plane to the surface :

Wolfram Language code: f2[u_, v_] := {4 + (3 + Cos[v]) Sin[u], 4 + (3 + Cos[v]) Cos[u], 4 + Sin[v]};

Wolfram Language code:

s2 = ParametricPlot3D[f2[u, v], {u, 0, 2π}, {v, 0, 2π}];
t2 = With[{u = 3π / 4, v = π / 4}, Graphics3D[{Opacity[0.5], InfinitePlane[f2[u, v], {Derivative[1, 0][f2][u, v], Derivative[0, 1][f2][u, v]}]}]];

Wolfram Language code: Show[s2, t2, PlotRangePadding -> Scaled[0.2]]

Find the intersection points of a sphere, a plane, and a surface defined by :

Wolfram Language code:

Subscript[ℛ, 1] = Sphere[];
Subscript[ℛ, 2] = InfinitePlane[{{0, 0, 0}, {0, 1, 0}, {1, 0, 1}}];

Wolfram Language code: pts = Solve[2 x y == z^2 && {x, y, z}∈Subscript[ℛ, 1] && {x, y, z}∈Subscript[ℛ, 2], {x, y, z}, Reals]

Visualize intersection points:

Wolfram Language code: intersections = {PointSize[Large], Red, Point[{x, y, z} /. pts]};

Wolfram Language code: r1 = {Opacity[0.5, LightBlue], Subscript[ℛ, 1]};

Wolfram Language code: r2 = {Opacity[0.5, Yellow], Subscript[ℛ, 2]};

Wolfram Language code:

r3 = ContourPlot3D[2 x y == z^2, {x, -1.2, 1.2}, {y, -1.2, 1.2}, {z, -1.2, 1.2}, Mesh -> None, ContourStyle -> Opacity[0.5]];

Wolfram Language code: Show[{Graphics3D[{r1, r2, intersections}], r3}, Boxed -> False]

Partition space in a BubbleChart:

Wolfram Language code: b = BubbleChart3D[RandomReal[1, {10, 4}]];

Wolfram Language code: p = InfinitePlane[{0, 0, 0}, {{0, 0, 1}, {1, 1, 0}}];

Combine the graphics:

Wolfram Language code: Show[b, Graphics3D[{Opacity@0.7, p}]]

Visualize a reflection plane:

Wolfram Language code:

pt = {1, 1, 1};
v1 = {3, -1, -2};
v2 = {-1, 3, -2};

Define a reflection plane:

Wolfram Language code: ip = InfinitePlane[pt, {v1, v2}];

Define a ReflectionTransform using a point on the plane and its normal vector:

Wolfram Language code: n = Cross[Normalize[v1], Normalize[v2]];

Wolfram Language code: rt = ReflectionTransform[n, pt];

Visualize the reflection of a unit cube about the plane:

Wolfram Language code: c = Cuboid[];

Wolfram Language code: Graphics3D[{Opacity[0.5], {Yellow, ip}, {Blue, c}, {Red, GeometricTransformation[c, rt]}}]

Properties & Relations (6)

InfinitePlane[{p₁,p₂,p₃}] is equivalent to InfinitePlane[p₁,{p₂-p₁,p₃-p₁}]:

Wolfram Language code: {Subscript[p, 1], Subscript[p, 2], Subscript[p, 3]} = {{1, 0, 0}, {1, 1, 1}, {0, 0, 1}};

Wolfram Language code:

Subscript[ℛ, 1] = InfinitePlane[{Subscript[p, 1], Subscript[p, 2], Subscript[p, 3]}];
Subscript[ℛ, 2] = InfinitePlane[Subscript[p, 1], {Subscript[p, 2] - Subscript[p, 1], Subscript[p, 3] - Subscript[p, 1]}];

Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

InfinitePlane[p,{v₁,v₂}] is equivalent to Hyperplane[Cross[v₁,v₂],p] in 3D:

Wolfram Language code: Subscript[ℛ, 1] = InfinitePlane[{1, 2, 3}, {{1, 1, 0}, {0, 1, 1}}];

Wolfram Language code: Subscript[ℛ, 2] = Hyperplane[Cross[{1, 1, 0}, {0, 1, 1}], {1, 2, 3}];

Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

ParametricRegion can represent any InfinitePlane:

Wolfram Language code: Subscript[ℛ, 1] = InfinitePlane[{1, 2, 3}, {{4, 5, 6}, {7, 8, 9}}];

Wolfram Language code: Subscript[ℛ, 2] = ParametricRegion[{1, 2, 3} + u{4, 5, 6} + v{7, 8, 9}, {{u, -∞, ∞}, {v, -∞, ∞}}];

Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

ImplicitRegion can represent any InfinitePlane:

Wolfram Language code: Subscript[ℛ, 1] = ImplicitRegion[-9 (-1 + x) - 3 (-2 + y) + 4 (-3 + z) == 0, {x, y, z}];

Wolfram Language code: Subscript[ℛ, 2] = InfinitePlane[{{1, 2, 3}, {-4, 5, -6}, {7, -8, 9}}];

Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

InfinitePlane is a special case of ConicHullRegion:

Wolfram Language code: pts = {{1, 2, 3}, {-4, 5, -6}, {7, -8, 9}};

Wolfram Language code: RegionEqual[ConicHullRegion[pts], InfinitePlane[pts]]

Any InfinitePlane can be represented as a union of two HalfPlane regions:

Wolfram Language code: {Subscript[p, 1], Subscript[v, 1], Subscript[v, 2]} = {{0, 1, 3}, {1, -1, -2}, {1, 1, 0}};

Wolfram Language code: Subscript[ℛ, 1] = InfinitePlane[Subscript[p, 1], {Subscript[v, 1], Subscript[v, 2]}];

Wolfram Language code:

Subscript[ℛ, 2] = RegionUnion[HalfPlane[Subscript[p, 1], Subscript[v, 1], Subscript[v, 2]], HalfPlane[Subscript[p, 1], Subscript[v, 1], -Subscript[v, 2]]];

Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

Neat Examples (2)

A random collection of planes:

Wolfram Language code:

Graphics3D[Table[{Hue[RandomReal[]], InfinitePlane[RandomReal[1, {3, 3}]]}, {25}], Lighting -> "Neutral", PlotRange -> 1]

Sweep an infinite plane around an axis:

Wolfram Language code:

Table[Graphics3D[{Opacity[0.3], ColorData["Rainbow"][Rescale[θ, {0, π / 2}]], InfinitePlane[{0, 0, 0}, {{1, 0, 0}, {1, Cos[θ], Sin[θ]}}]}], {θ, 0, π, π / 12}]//Show

Top

More Learning

Tech Support

Wolfram Solutions

Wolfram Solutions For Education

Get Started

Grow Your Skills

Work with Us

Educational Programs for Adults

Educational Programs for Youth

Read

InfinitePlane

Details

Examples

Basic Examples (3)

Scope (17)

Graphics (7)

Specification (2)

Styling (2)

Coordinates (3)

Regions (10)

Applications (7)

Properties & Relations (6)

Neat Examples (2)

Text

CMS

APA

BibTeX

BibLaTeX

InfinitePlane

Details

Examples

Basic Examples (3)

Scope (17)

Graphics (7)

Specification (2)

Styling (2)

Coordinates (3)

Regions (10)

Applications (7)

Properties & Relations (6)

Neat Examples (2)

See Also

Related Guides

History

Text

CMS

APA

BibTeX

BibLaTeX