WOLFRAM

Wolfram Language & System Documentation Center

CoefficientArrays[polys,vars]

gives the arrays of coefficients of the variables vars in the polynomials polys.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Options  
"Symmetric"  
Applications  
Properties & Relations  
See Also
Tech Notes
Related Guides
History
Cite this Page

CoefficientArrays

CoefficientArrays[polys,vars]

gives the arrays of coefficients of the variables vars in the polynomials polys.

Details and Options

  • CoefficientArrays gives a list containing SparseArray objects, which can be converted to ordinary arrays using Normal.
  • If CoefficientArrays[polys,vars] gives {m0,m1,m2,…}, then polys can be reconstructed as m0+m1.vars+m2.vars.vars+…. »
  • Any element of polys of the form lhs==rhs is taken to correspond to the polynomial lhs-rhs. »
  • CoefficientArrays[polys,{form1,form2,…}] takes all expressions in polys that match any of the formi to be variables.
  • CoefficientArrays[polys] is equivalent to CoefficientArrays[polys,Variables[polys]].
  • The length of the list CoefficientArrays[polys,vars] is one more than the total degree of polys.
  • The mi are sparse arrays with ranks .
  • The first element m0 has the same length as the list polys.
  • If polys is a single polynomial rather than a list, m0 is also not a list.
  • For linear equations, the solution to Thread[polys==0] is given by LinearSolve[m1,-m0].
  • For nonlinear equations, the mi are not unique. CoefficientArrays by default assigns nonzero coefficients only to monomials where the variables appear in the same order as vars.
  • CoefficientArrays[polys,vars,"Symmetric"->True] makes all the mi symmetric in all their indices. The resulting arrays will generally be less sparse.

Examples

open all close all

Basic Examples  (1)

Wolfram Language code: CoefficientArrays[{a + x - y - z == 0, b + x + 2y + z == 0}, {x, y, z}]
Wolfram Language code: Normal[%]

Scope  (4)

Linear polynomial:

Wolfram Language code: CoefficientArrays[2x + 3y + 4z + 5, {x, y, z}]
Wolfram Language code: Normal[%]

List of linear polynomials:

Wolfram Language code: CoefficientArrays[{2x + 3y + 4z + 5, 6x + 7y + 8z + 9}, {x, y, z}]
Wolfram Language code: Normal[%]

Nonlinear polynomials:

Wolfram Language code: CoefficientArrays[{(x + y + 1) ^ 2, (x - y - 2) ^ 3}, {x, y}]
Wolfram Language code: Normal[%]

Polynomial equations:

Wolfram Language code: CoefficientArrays[{c + x ^ 2 - z == 0, x ^ 2 + 2y + z ^ 2 == 0}, {x, y, z}]
Wolfram Language code: Normal[%]

Options  (1)

"Symmetric"  (1)

The default coefficient of a quadratic form corresponding to y x is zero:

Wolfram Language code: CoefficientArrays[a x ^ 2 + b x y + c y ^ 2 + d x + e y + f, {x, y}]//Normal

With "Symmetric"->True, CoefficientArrays gives symmetric arrays:

Wolfram Language code: CoefficientArrays[a x ^ 2 + b x y + c y ^ 2 + d x + e y + f, {x, y}, "Symmetric" -> True]//Normal

Applications  (1)

Convert linear equations to arrays suitable for LinearSolve:

Wolfram Language code: eqns = {2x + 3y + 4z == 5, 9x + 8y + 7z == 6, x + 9y + 2z == 8};
Wolfram Language code: {b, m} = CoefficientArrays[eqns, {x, y, z}]
Wolfram Language code: LinearSolve[m, -b]
Wolfram Language code: {x, y, z} /. Solve[eqns, {x, y, z}]

Properties & Relations  (3)

The polynomial can be reconstructed by using Dot (.):

Wolfram Language code: v = {x, y};
Wolfram Language code: f = Expand[(2x + 3y) ^ 2 + y ^ 3]
Wolfram Language code: c = CoefficientArrays[f, v]
Wolfram Language code: c[[1]] + c[[2]].v + c[[3]].v.v + c[[4]].v.v.v//Expand

The symmetric coefficient arrays correspond to vector derivatives at the origin:

Wolfram Language code: f = Expand[(2x + 3y) ^ 2 + y ^ 3]
Wolfram Language code: CoefficientArrays[f, {x, y}, "Symmetric" -> True]//Normal
Wolfram Language code: Table[D[f, {{x, y}, n}] / n!, {n, 0, 3}] /. {x -> 0, y -> 0}

CoefficientArrays gives a list of arrays of polynomial coefficients ordered by total degrees:

Wolfram Language code: f = (3x + 5y) ^ 4;
Wolfram Language code: ca = CoefficientArrays[f, {x, y}]

CoefficientList gives a tensor of the coefficients:

Wolfram Language code: cl = CoefficientList[f, {x, y}]

Use Coefficient to find the coefficient of :

Wolfram Language code: Coefficient[f, x y ^ 3]

In ca the position of this coefficient is a+b+1 followed by a 1s and b 2s (1 and 2 indicate the first and second variables):

Wolfram Language code: ca[[5, 1, 2, 2, 2]]

In cl the coefficient of x^a y^b is the element at position {a+1,b+1}:

Wolfram Language code: cl[[1 + 1, 1 + 3]]
Wolfram Research (2003), CoefficientArrays, Wolfram Language function, https://reference.wolfram.com/language/ref/CoefficientArrays.html.

Text

Wolfram Research (2003), CoefficientArrays, Wolfram Language function, https://reference.wolfram.com/language/ref/CoefficientArrays.html.

CMS

Wolfram Language. 2003. "CoefficientArrays." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/CoefficientArrays.html.

APA

Wolfram Language. (2003). CoefficientArrays. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/CoefficientArrays.html

BibTeX

@misc{reference.wolfram_2026_coefficientarrays, author="Wolfram Research", title="{CoefficientArrays}", year="2003", howpublished="\url{https://reference.wolfram.com/language/ref/CoefficientArrays.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_coefficientarrays, organization={Wolfram Research}, title={CoefficientArrays}, year={2003}, url={https://reference.wolfram.com/language/ref/CoefficientArrays.html}, note=[Accessed: 13-June-2026]}