WOLFRAM

Wolfram Language & System Documentation Center

CoefficientRules[poly,{x1,x2,…}]

gives the list {{e11,e12,…}c1,{e21,…}c2,…} of exponent vectors and coefficients for the monomials in poly with respect to the xi.

CoefficientRules[poly,{x1,x2,…},order]

gives the result with the monomial ordering specified by order.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Options  
Modulus  
Properties & Relations  
Possible Issues  
Neat Examples  
See Also
Tech Notes
Related Guides
History
Cite this Page

CoefficientRules

CoefficientRules[poly,{x1,x2,…}]

gives the list {{e11,e12,…}c1,{e21,…}c2,…} of exponent vectors and coefficients for the monomials in poly with respect to the xi.

CoefficientRules[poly,{x1,x2,…},order]

gives the result with the monomial ordering specified by order.

Details and Options

Examples

open all close all

Basic Examples  (1)

Get exponents and coefficients of monomials:

Wolfram Language code: CoefficientRules[(x + y) ^ 3]

Scope  (1)

Use "DegreeReverseLexicographic" monomial ordering:

Wolfram Language code: CoefficientRules[a x y ^ 2 + b x ^ 2 z, {x, y, z}, "DegreeReverseLexicographic"]

Specify the same ordering using weight matrix:

Wolfram Language code: CoefficientRules[a x y ^ 2 + b x ^ 2 z, {x, y, z}, {{1, 1, 1}, {0, 0, -1}, {0, -1, 0}}]

Options  (1)

Modulus  (1)

Reduce the coefficients modulo 2:

Wolfram Language code: CoefficientRules[(x + 1) ^ 5, x, Modulus -> 2]

Properties & Relations  (2)

FromCoefficientRules reconstructs the original polynomial:

Wolfram Language code: CoefficientRules[a x ^ 2 + b x y + c y ^ 2, {x, y}]
Wolfram Language code: FromCoefficientRules[%, {x, y}]

MonomialList gives a different representation:

Wolfram Language code: MonomialList[a x ^ 2 + b x y + c y ^ 2, {x, y}]

For two variables "DegreeLexicographic" and "DegreeReverseLexicographic" coincide:

Wolfram Language code: poly = Sum[RandomInteger[{-10, 10}]x ^ RandomInteger[10]y ^ RandomInteger[10], {20}]
Wolfram Language code: CoefficientRules[poly, {x, y}, "DegreeLexicographic"] === CoefficientRules[poly, {x, y}, "DegreeReverseLexicographic"]

Possible Issues  (1)

The list given by Variables[poly] is not always sorted:

Wolfram Language code: Variables[y + x z]
Wolfram Language code: CoefficientRules[y + x z]
Wolfram Language code: FromCoefficientRules[%, {y, x, z}]

Neat Examples  (2)

Visualize monomial orderings in 2D:

Wolfram Language code: MonomialOrderPlot[poly_, {x1_, x2_}, ord_ : "Lexicographic", o : OptionsPattern[]] := Graphics[{Blue, Arrow /@ Partition[CoefficientRules[poly, {x1, x2}, ord][[All, 1]], 2, 1]}, Sequence@@FilterRules[{o}, Options[Graphics]]]

The standard built-in orderings:

Wolfram Language code: orders = {"Lexicographic", "DegreeLexicographic", "DegreeReverseLexicographic", "NegativeLexicographic", "NegativeDegreeLexicographic", "NegativeDegreeReverseLexicographic"};

In 2D some orderings cannot be distinguished:

Wolfram Language code: Table[MonomialOrderPlot[Sum[x ^ i y ^ j, {i, 0, 5}, {j, 0, 5}], {x, y}, o, PlotLabel -> Style[o, Small]], {o, orders}]

Visualize monomial orderings in 3D:

Wolfram Language code: MonomialOrderPlot3D[poly_, {x1_, x2_, x3_}, ord_ : "Lexicographic", o : OptionsPattern[]] := Graphics3D[{Arrowheads[.06], Arrow[Tube[#, .02]]& /@ Partition[CoefficientRules[poly, {x1, x2, x3}, ord][[All, 1]], 2, 1]}, Sequence@@FilterRules[{o}, Options[Graphics3D]]]
Wolfram Language code: orders = {"Lexicographic", "DegreeLexicographic", "DegreeReverseLexicographic", "NegativeLexicographic", "NegativeDegreeLexicographic", "NegativeDegreeReverseLexicographic"};

In 3D all orderings are distinct:

Wolfram Language code: Table[MonomialOrderPlot3D[Sum[x ^ i y ^ j z ^ k, {i, 0, 2}, {j, 0, 2}, {k, 0, 2}], {x, y, z}, o, PlotLabel -> Style[o, Small]], {o, orders}]
Wolfram Research (2008), CoefficientRules, Wolfram Language function, https://reference.wolfram.com/language/ref/CoefficientRules.html.

Text

Wolfram Research (2008), CoefficientRules, Wolfram Language function, https://reference.wolfram.com/language/ref/CoefficientRules.html.

CMS

Wolfram Language. 2008. "CoefficientRules." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/CoefficientRules.html.

APA

Wolfram Language. (2008). CoefficientRules. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/CoefficientRules.html

BibTeX

@misc{reference.wolfram_2026_coefficientrules, author="Wolfram Research", title="{CoefficientRules}", year="2008", howpublished="\url{https://reference.wolfram.com/language/ref/CoefficientRules.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_coefficientrules, organization={Wolfram Research}, title={CoefficientRules}, year={2008}, url={https://reference.wolfram.com/language/ref/CoefficientRules.html}, note=[Accessed: 12-June-2026]}