WOLFRAM

Wolfram Language & System Documentation Center

Confirm[expr]

confirms that expr is not considered a failure, otherwise throwing an error to the nearest surrounding Enclose.

Confirm[expr,info]

evaluates info and includes its value in the thrown error if expr is not confirmed.

Confirm[expr,info,tag]

uses the specified tag for any thrown errors.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Applications  
Properties & Relations  
Possible Issues  
See Also
Related Guides
History
Cite this Page

Confirm

Confirm[expr]

confirms that expr is not considered a failure, otherwise throwing an error to the nearest surrounding Enclose.

Confirm[expr,info]

evaluates info and includes its value in the thrown error if expr is not confirmed.

Confirm[expr,info,tag]

uses the specified tag for any thrown errors.

Details

  • Confirm[expr,…] returns expr if expr is successfully confirmed.
  • Confirm[expr,…] considers expr a failure and throws an error if expr has any of the following forms:
  • Failure[…]
    Missing[…]
    $Failed
    $Canceled
    $Aborted
  • Confirm is dynamically scoped when given a tag. Otherwise, it is lexically scoped. »
  • The default value of info is Null.
  • expr is wrapped in a Failure before it is thrown unless info is Null and expr is a Failure from a previous confirmation function. »
  • Failure objects generated by Confirm include the following fields:
  • "Information"info from Confirm[expr,info,…]
    "Expression"expr from Confirm[expr,…]
  • Values of these fields can be extracted using failure["prop"] or directly through Enclose[expr,"prop"].

Examples

open all close all

Basic Examples  (2)

Confirm[expr] gives expr if expr is not considered a failure:

Wolfram Language code: Enclose[f[x, Confirm[y], z]]

If Confirm encounters a failure, it stops evaluation and throws an error to the surrounding Enclose:

Wolfram Language code: Enclose[f[x, Confirm[$Failed], z]]

Define a function that propagates failures in its arguments:

Wolfram Language code: addtwo[x_] := Enclose[Confirm[x] + 2]
Wolfram Language code: addtwo[4]
Wolfram Language code: addtwo[Missing[]]

Scope  (4)

Confirm stops evaluation and returns to the matching Enclose when it throws an error:

Wolfram Language code: Enclose[Echo[1];Confirm[$Failed];Echo[2]]

info is only evaluated when expr cannot be confirmed:

Wolfram Language code: Enclose[Confirm[2, Echo["info was evaluated"]]]
Wolfram Language code: Enclose[Confirm[$Failed, Echo["info was evaluated"]]]

Create a function that calls Confirm with a tag so that it can be caught dynamically:

Wolfram Language code: f[x_] := g[3 + Confirm[x, Null, "fooTag"]]
Wolfram Language code: h[y_] := Enclose[f[y], Identity, "fooTag"]
Wolfram Language code: h[2]
Wolfram Language code: h[$Canceled]

If no tag is given, Confirm is lexically scoped:

Wolfram Language code: f2[x_] := g[3 + Confirm[x]]
Wolfram Language code: h2[y_] := Enclose[f2[y]]
Wolfram Language code: h2[2]

Failures are wrapped in a Failure before they are thrown, unless they were thrown from another confirmation function:

Wolfram Language code: Enclose[Confirm[Missing[]]]
Wolfram Language code: Enclose[Confirm[%]]

This behavior is overruled when info is not Null:

Wolfram Language code: Enclose[Confirm[%, "foo"]]

Applications  (1)

Print a message when a failure is detected:

Wolfram Language code: mountainElevation::inv = "Could not interpret `` as a mountain.";
Wolfram Language code: mountainElevation[name_] := Enclose[ Confirm[Interpreter["Mountain"][name], Message[mountainElevation::inv, name]]["Elevation"], $Failed&]
Wolfram Language code: mountainElevation["k2"]
Wolfram Language code: mountainElevation[π]

Properties & Relations  (1)

Confirm can be emulated with ConfirmBy:

Wolfram Language code: Enclose[f[Confirm[Missing[]]]]
Wolfram Language code: Enclose[f[ConfirmBy[Missing[], # =!= $Canceled && !FailureQ[#] && !MissingQ[#]&]]]

Possible Issues  (3)

Confirm must be given a tag or be within a lexical Enclose:

Wolfram Language code: Confirm[2]

Untagged Confirm works by replacing instances of the symbol Confirm with a tagged variant:

Wolfram Language code: Enclose[Hold[Confirm]]

Tagged Confirm requires an Enclose with a matching tag:

Wolfram Language code: Enclose[Confirm[$Failed, Null, "foo"], Identity, "bar"]
Wolfram Research (2020), Confirm, Wolfram Language function, https://reference.wolfram.com/language/ref/Confirm.html.

Text

Wolfram Research (2020), Confirm, Wolfram Language function, https://reference.wolfram.com/language/ref/Confirm.html.

CMS

Wolfram Language. 2020. "Confirm." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/Confirm.html.

APA

Wolfram Language. (2020). Confirm. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Confirm.html

BibTeX

@misc{reference.wolfram_2026_confirm, author="Wolfram Research", title="{Confirm}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/Confirm.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_confirm, organization={Wolfram Research}, title={Confirm}, year={2020}, url={https://reference.wolfram.com/language/ref/Confirm.html}, note=[Accessed: 13-June-2026]}