WOLFRAM

Wolfram Language & System Documentation Center

ConfirmBy[expr,f]

confirms that f[expr] returns True, otherwise throwing an error to the nearest surrounding Enclose.

ConfirmBy[expr,f,info]

evaluates info and includes its value in the thrown error if expr is not confirmed.

ConfirmBy[expr,f,info,tag]

uses the specified tag for any thrown errors.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Applications  
Properties & Relations  
Possible Issues  
See Also
Related Guides
History
Cite this Page

ConfirmBy

ConfirmBy[expr,f]

confirms that f[expr] returns True, otherwise throwing an error to the nearest surrounding Enclose.

ConfirmBy[expr,f,info]

evaluates info and includes its value in the thrown error if expr is not confirmed.

ConfirmBy[expr,f,info,tag]

uses the specified tag for any thrown errors.

Details

  • ConfirmBy[expr,…] returns expr if expr is successfully confirmed.
  • ConfirmBy is dynamically scoped when given a tag. Otherwise, it is lexically scoped. »
  • The default value of info is Null.
  • Failure objects generated by ConfirmBy include the following fields:
  • "Information"info from ConfirmBy[expr,f,info,…]
    "Expression"expr from ConfirmBy[expr,…]
    "Function"f from ConfirmBy[expr,f,…]
  • Values of these fields can be extracted using failure["prop"] or directly through Enclose[expr,"prop"].

Examples

open all close all

Basic Examples  (2)

ConfirmBy[expr,f] gives expr if f[expr] evaluates to True:

Wolfram Language code: Enclose[f[1, ConfirmBy[2, NumberQ], 3]]

Since "foo" is not a number, ConfirmBy stops evaluation and throws an error to the surrounding Enclose:

Wolfram Language code: Enclose[f[1, ConfirmBy["foo", NumberQ], 3]]

Create a function that checks its arguments:

Wolfram Language code: world[x_] := Enclose[ConfirmBy[x, StringQ] <> ", World!"]
Wolfram Language code: world["Hello"]
Wolfram Language code: world[4]

Scope  (3)

ConfirmBy stops evaluation and returns to the matching Enclose when it throws an error:

Wolfram Language code: Enclose[Echo[1];ConfirmBy[10, LessThan[5]];Echo[2]]

info is only evaluated when expr cannot be confirmed:

Wolfram Language code: Enclose[ConfirmBy[2, NumberQ, Echo["info was evaluated"]]]
Wolfram Language code: Enclose[ConfirmBy["NaN", NumberQ, Echo["info was evaluated"]]]

Create a function that calls ConfirmBy with a tag so that it can be caught dynamically:

Wolfram Language code: f[x_] := g[StringReverse[ConfirmBy[x, StringQ, Null, "fooTag"]]]
Wolfram Language code: h[y_] := Enclose[f[y], Identity, "fooTag"]
Wolfram Language code: h["reverseme"]
Wolfram Language code: h[42]

If no tag is given, ConfirmBy is lexically scoped:

Wolfram Language code: f2[x_] := g[StringReverse[ConfirmBy[x, StringQ]]]
Wolfram Language code: h2[y_] := Enclose[f2[y]]
Wolfram Language code: h2[2]

Applications  (1)

Print a message when a failure is detected:

Wolfram Language code: reverseRoman::nan = "`` is not an integer.";
Wolfram Language code: reverseRoman[n_] := Enclose[ StringReverse[RomanNumeral[ ConfirmBy[n, IntegerQ, Message[reverseRoman::nan, n]] ]], $Failed&]
Wolfram Language code: reverseRoman[21]
Wolfram Language code: reverseRoman["veni, vidi, vici"]

Properties & Relations  (1)

ConfirmBy can be emulated with ConfirmMatch:

Wolfram Language code: Enclose[f[ConfirmBy["foo", NumberQ]]]
Wolfram Language code: Enclose[f[ConfirmMatch["foo", _ ? NumberQ]]]

Possible Issues  (3)

ConfirmBy must be given a tag or be within a lexical Enclose:

Wolfram Language code: ConfirmBy[5, NumberQ]

Untagged ConfirmBy works by replacing instances of the symbol ConfirmBy with a tagged variant:

Wolfram Language code: Enclose[Hold[ConfirmBy]]

Tagged ConfirmBy requires an Enclose with a matching tag:

Wolfram Language code: Enclose[ConfirmBy["hello", NumberQ, Null, "foo"], Identity, "bar"]
Wolfram Research (2020), ConfirmBy, Wolfram Language function, https://reference.wolfram.com/language/ref/ConfirmBy.html.

Text

Wolfram Research (2020), ConfirmBy, Wolfram Language function, https://reference.wolfram.com/language/ref/ConfirmBy.html.

CMS

Wolfram Language. 2020. "ConfirmBy." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/ConfirmBy.html.

APA

Wolfram Language. (2020). ConfirmBy. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ConfirmBy.html

BibTeX

@misc{reference.wolfram_2026_confirmby, author="Wolfram Research", title="{ConfirmBy}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/ConfirmBy.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_confirmby, organization={Wolfram Research}, title={ConfirmBy}, year={2020}, url={https://reference.wolfram.com/language/ref/ConfirmBy.html}, note=[Accessed: 12-June-2026]}