WOLFRAM

Wolfram Language & System Documentation Center

ContainsAll[list1,list2]

yields True if list1 contains all of the elements of list2.

ContainsAll[list2]

is an operator form that yields True when the object to which it is applied contains all of the elements of list2.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Options  
SameTest  
Applications  
Properties & Relations  
See Also
Related Guides
History
Cite this Page

ContainsAll

ContainsAll[list1,list2]

yields True if list1 contains all of the elements of list2.

ContainsAll[list2]

is an operator form that yields True when the object to which it is applied contains all of the elements of list2.

Details and Options

Examples

open all close all

Basic Examples  (2)

The first list contains all elements of the second list:

Wolfram Language code: ContainsAll[{b, a, b, c}, {a, b}]

The first list does not contain all elements of the second list:

Wolfram Language code: ContainsAll[{b, a, b, c}, {a, b, d}]

Scope  (4)

The English word facetious contains all five vowels:

Wolfram Language code: ContainsAll[Characters["facetious"], {"a", "e", "i", "o", "u"}]

Use ContainsAll in operator form:

Wolfram Language code: all5 = ContainsAll[{1, 2, 3, 4, 5}]
Wolfram Language code: all5[{2, 3, 1, 3}]
Wolfram Language code: all5[{4, 2, 3, 1, 6, 1, 5}]

Find the movies whose cast contains both Angelina Jolie and Brad Pitt:

Wolfram Language code: EntityList[EntityClass["Movie", "Cast" -> ContainsAll[{Entity["Person", "AngelinaJolie::8cggf"], Entity["Person", "BradPitt::6xy46"]}]]]

ContainsAll works with associations:

Wolfram Language code: ContainsAll[<|a -> x, b -> y, c -> z, d -> x|>, {x, y, z}]
Wolfram Language code: ContainsAll[<|a -> x, b -> y, c -> z, d -> x|>, <|1 -> x, 2 -> y, 3 -> z|>]

Options  (2)

SameTest  (2)

By default, ContainsAll considers elements to be the same if they are identical:

Wolfram Language code: list = Subdivide[Quantity[0, "Meters"], Quantity[1, "Meters"], 10]
Wolfram Language code: ContainsAll[list, {Quantity[1/5, "Meters"], Quantity[1/2, "Meters"]}]

Changes of units are taken into account, as long as they represent the exact same quantity:

Wolfram Language code: ContainsAll[list, {Quantity[20, "Centimeters"], Quantity[50, "Centimeters"]}]

Numerical approximations are not considered as the same object:

Wolfram Language code: ContainsAll[list, {Quantity[20., "Centimeters"], Quantity[50., "Centimeters"]}]

Use Equal as the comparison function to have numerical tolerance:

Wolfram Language code: ContainsAll[list, {Quantity[20., "Centimeters"], Quantity[50., "Centimeters"]}, SameTest -> Equal]

String comparisons are case sensitive by default:

Wolfram Language code: ContainsAll[{"A", "B", "C"}, {"a", "b"}]

Convert to lower case before comparing:

Wolfram Language code: ContainsAll[{"A", "B", "C"}, {"a", "b"}, SameTest -> (SameQ[ToLowerCase[#1], ToLowerCase[#2]]&)]

Applications  (4)

Randomly find 10 English words containing all five vowels:

Wolfram Language code: Select[RandomSample@DictionaryLookup[], ContainsAll[Characters[#], {"a", "e", "i", "o", "u"}]&, 10]

Find the shortest French word containing all five vowels:

Wolfram Language code: MinimalBy[Select[WordList[Language -> "French"], ContainsAll[Characters[#], {"a", "e", "i", "o", "u"}]&], StringLength]

Take the first character of each word of a text:

Wolfram Language code: firstchars = StringTake[#, 1]& /@ ExampleData[{"Text", "ToBeOrNotToBe"}, "Words"]

It does not contain words starting with all letters of the alphabet:

Wolfram Language code: ContainsAll[ToLowerCase[firstchars], CharacterRange["a", "z"]]
Wolfram Language code: Complement[CharacterRange["a", "z"], ToLowerCase[firstchars]]

This larger text does contain words starting with all letters of the alphabet:

Wolfram Language code: Length[firstchars = StringTake[#, 1]& /@ ExampleData[{"Text", "OriginOfSpecies"}, "Words"]]
Wolfram Language code: ContainsAll[firstchars, CharacterRange["a", "z"]]

All of them do not appear as capital first letters in the text:

Wolfram Language code: ContainsAll[firstchars, CharacterRange["A", "Z"]]

A pangrammatic lipogram is a text that uses all letters of the alphabet except one:

Wolfram Language code: pangrammaticLipogramQ[text_, letter_] := ContainsAll[Characters[text], Complement[Alphabet[], {letter}]]
Wolfram Language code: pangrammaticLipogramQ["a jovial swain should not complain of any buxom fair who mocks his pain and thinks it gain to quiz his awkward air", "e"]

Properties & Relations  (3)

ContainsAll[list1,list2] is equivalent to SubsetQ[list1,list2]:

Wolfram Language code: list1 = {5, 1, 0, 0, 0, 0, 4, 5, 0, 0};
Wolfram Language code: list2 = {1, 2, 3, 4, 5};
Wolfram Language code: {ContainsAll[list1, list2], SubsetQ[list1, list2]}

Reversing the arguments of ContainsAll is equivalent to using ContainsOnly:

Wolfram Language code: list1 = {3, 1, 0, 0, 4, 0, 3, 2, 4, 0};
Wolfram Language code: list2 = {1, 2, 3, 4, 5};
Wolfram Language code: {ContainsAll[list1, list2], ContainsOnly[list2, list1]}

ContainsAll[list,{}] always returns True:

Wolfram Language code: ContainsAll[{1, 2}, {}]
Wolfram Language code: ContainsAll[{}, {}]
Wolfram Research (2015), ContainsAll, Wolfram Language function, https://reference.wolfram.com/language/ref/ContainsAll.html.

Text

Wolfram Research (2015), ContainsAll, Wolfram Language function, https://reference.wolfram.com/language/ref/ContainsAll.html.

CMS

Wolfram Language. 2015. "ContainsAll." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/ContainsAll.html.

APA

Wolfram Language. (2015). ContainsAll. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ContainsAll.html

BibTeX

@misc{reference.wolfram_2026_containsall, author="Wolfram Research", title="{ContainsAll}", year="2015", howpublished="\url{https://reference.wolfram.com/language/ref/ContainsAll.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_containsall, organization={Wolfram Research}, title={ContainsAll}, year={2015}, url={https://reference.wolfram.com/language/ref/ContainsAll.html}, note=[Accessed: 13-June-2026]}