WOLFRAM

Wolfram Language & System Documentation Center

ContainsExactly[list1,list2]

yields True if list1 contains exactly the same elements as list2.

ContainsExactly[list2]

is an operator form that yields True when the object to which it is applied contains exactly the same elements as list2.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Options  
SameTest  
Applications  
Properties & Relations  
See Also
Related Guides
History
Cite this Page

ContainsExactly

ContainsExactly[list1,list2]

yields True if list1 contains exactly the same elements as list2.

ContainsExactly[list2]

is an operator form that yields True when the object to which it is applied contains exactly the same elements as list2.

Details and Options

Examples

open all close all

Basic Examples  (2)

Both lists contain exactly the same elements:

Wolfram Language code: ContainsExactly[{b, a, b, c}, {a, b, c}]

The lists contain different elements:

Wolfram Language code: ContainsExactly[{b, a, d, d}, {a, b, c}]

Scope  (4)

Check whether certain chemicals contain exactly certain elements:

Wolfram Language code: ContainsExactly[ChemicalData[Entity["Chemical", "Sucrose"], "ElementTypes"], {"C", "H", "O"}]
Wolfram Language code: ContainsExactly[ChemicalData[Entity["Chemical", "6Mercaptopurine9BetaDRibofuranoside"], "ElementTypes"], {"C", "H", "O"}]

Use ContainsExactly in operator form:

Wolfram Language code: fullweekend = ContainsExactly[{Saturday, Sunday}]
Wolfram Language code: fullweekend[{Sunday, Saturday, Friday}]
Wolfram Language code: fullweekend[{Sunday, Saturday, Sunday}]

Find music works composed in 1982 by Bernie Taupin and Elton John:

Wolfram Language code: EntityList[EntityClass["MusicWork", {"FirstReleaseDate" -> DateObject[{1982}], "Composers" -> ContainsExactly[{Entity["Person", "BernieTaupin::g5988"], Entity["Person", "EltonJohn::8fg2d"]}]}]]

ContainsExactly works with associations:

Wolfram Language code: ContainsExactly[<|a -> x, b -> y, c -> x|>, {x, y}]
Wolfram Language code: ContainsExactly[<|a -> x, b -> y, c -> x|>, <|1 -> x, 2 -> y|>]

Options  (2)

SameTest  (2)

By default, ContainsExactly considers elements to be the same if they are identical:

Wolfram Language code: list = Subdivide[Quantity[0, "Meters"], Quantity[1, "Meters"], 2]
Wolfram Language code: ContainsExactly[list, {Quantity[0, "Meters"], Quantity[1/2, "Meters"], Quantity[1, "Meters"]}]

Changes of units are taken into account, as long as they represent the exact same quantity:

Wolfram Language code: ContainsExactly[list, {Quantity[0, "Centimeters"], Quantity[50, "Centimeters"], Quantity[100, "Centimeters"]}]

Numerical approximations are not considered as the same object:

Wolfram Language code: ContainsExactly[list, {Quantity[0., "Centimeters"], Quantity[50., "Centimeters"], Quantity[100., "Centimeters"]}]

Use Equal as the comparison function to have numerical tolerance:

Wolfram Language code: ContainsExactly[list, {Quantity[0., "Centimeters"], Quantity[50., "Centimeters"], Quantity[100., "Centimeters"]}, SameTest -> Equal]

String comparisons are case sensitive by default:

Wolfram Language code: ContainsExactly[{"A", "B", "C"}, {"a", "b", "c"}]

Convert to lower case before comparing:

Wolfram Language code: ContainsExactly[{"A", "B", "C"}, {"a", "b", "c"}, SameTest -> (SameQ[ToLowerCase[#1], ToLowerCase[#2]]&)]

Applications  (1)

Two anagram words or phrases contain the same letters:

Wolfram Language code: letters[string_] := DeleteCases[Characters[string], " "]
Wolfram Language code: anagramQ[string1_, string2_] := ContainsExactly[letters[string1], letters[string2]]

The word "parsley" is an anagram of the word "replays":

Wolfram Language code: anagramQ["parsley", "replays"]

These two phrases contain the same letters:

Wolfram Language code: anagramQ["eleven plus two", "twelve plus one"]

Properties & Relations  (3)

ContainsExactly[list1,list2] is equivalent to testing for equality as sets:

Wolfram Language code: list1 = {2, 0, 0, 4, 3, 2, 4, 3, 2, 4};
Wolfram Language code: list2 = {3, 3, 1, 2, 0, 4, 1, 1, 3, 5};
Wolfram Language code: {ContainsExactly[list1, list2], SameQ[Union[list1], Union[list2]]}

ContainsExactly is a symmetric function of its arguments. That is, ContainsExactly[list1,list2]==ContainsExactly[list2,list1]:

Wolfram Language code: list1 = {2, 0, 0, 5, 0, 4, 0, 4, 4, 4};
Wolfram Language code: list2 = {0, 3, 3, 4, 2, 0, 5, 0, 1, 1};
Wolfram Language code: {ContainsExactly[list1, list2], ContainsExactly[list2, list1]}

ContainsExactly[list1,list2] is equivalent to And[ContainsAll[list1,list2],ContainsOnly[list1,list2]]:

Wolfram Language code: list1 = {5, 1, 4, 4, 4, 2, 2, 0, 2, 3};
Wolfram Language code: list2 = {5, 4, 4, 3, 1, 0, 3, 0, 2, 2};
Wolfram Language code: {ContainsExactly[list1, list2], And[ContainsAll[list1, list2], ContainsOnly[list1, list2]]}
Wolfram Research (2015), ContainsExactly, Wolfram Language function, https://reference.wolfram.com/language/ref/ContainsExactly.html.

Text

Wolfram Research (2015), ContainsExactly, Wolfram Language function, https://reference.wolfram.com/language/ref/ContainsExactly.html.

CMS

Wolfram Language. 2015. "ContainsExactly." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/ContainsExactly.html.

APA

Wolfram Language. (2015). ContainsExactly. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ContainsExactly.html

BibTeX

@misc{reference.wolfram_2026_containsexactly, author="Wolfram Research", title="{ContainsExactly}", year="2015", howpublished="\url{https://reference.wolfram.com/language/ref/ContainsExactly.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_containsexactly, organization={Wolfram Research}, title={ContainsExactly}, year={2015}, url={https://reference.wolfram.com/language/ref/ContainsExactly.html}, note=[Accessed: 12-June-2026]}