WOLFRAM

Wolfram Language & System Documentation Center

Dated[obj,year]

represents the object obj associated with a particular year.

Dated[obj,date]

represents the object obj associated with a date.

Dated[obj,All]

represents the object obj for all dates where information is available about it.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Generalizations & Extensions  
Applications  
Properties & Relations  
See Also
Related Guides
History
Cite this Page

Dated

Dated[obj,year]

represents the object obj associated with a particular year.

Dated[obj,date]

represents the object obj associated with a date.

Dated[obj,All]

represents the object obj for all dates where information is available about it.

Details

  • In Dated[obj,date], obj can be an Entity object, an EntityProperty object, or a string representing an entity property.
  • In Dated[obj,year], the year can be given as an integer.
  • In Dated[obj,date], date is specified using DateObject.
  • When data is requested using Dated[obj,All], a time series is typically returned.

Examples

open all close all

Basic Examples  (3)

Represent France in 1985:

Wolfram Language code: Dated[Entity["Country", "France"], 1985]

Find the population of France in 1985:

Wolfram Language code: Dated[Entity["Country", "France"], 1985]["Population"]

Dated can also be used on EntityProperty expressions:

Wolfram Language code: Dated[EntityProperty["City", "PerCapitaIncome"], DateObject[{2010}, "Year", "Gregorian", -6.]]
Wolfram Language code: Dated[EntityProperty["City", "PerCapitaIncome"], DateObject[{2010}, "Year", "Gregorian", -6.]][Entity["City", {"Chicago", "Illinois", "UnitedStates"}]]

A string property name can also be wrapped in Dated:

Wolfram Language code: EntityValue[Entity["Planet", "Mars"], Dated["DistanceFromEarth", DateObject[{1985, 8, 4}, "Day", "Gregorian", -6.]]]

Scope  (2)

When Dated is used on an entity, properties without date qualifiers will ignore the date parameter:

Wolfram Language code: EntityValue[Dated[Entity["Planet", "Mars"], DateObject[{1986, 10, 13}, "Day", "Gregorian", -6.]], "Mass"]

When Dated is used on a property without date qualifiers, Missing[…] is returned:

Wolfram Language code: EntityValue[Entity["Planet", "Mars"], Dated["Mass", DateObject[{1986, 10, 13}, "Day", "Gregorian", -6.]]]

If Dated is used on both the entity and property, the date associated with the property is used:

Wolfram Language code: EntityValue[Dated[Entity["Star", "HIP44511"], DateObject[{2010}, "Year", "Gregorian", -6.]], Dated[EntityProperty["Star", "DistanceFromSun"], DateObject[{1990}, "Year", "Gregorian", -6.]]]

Generalizations & Extensions  (2)

Get the net income of a company for multiple dates by requesting values for multiple dated properties:

Wolfram Language code: years = DateRange[DateObject[{2017}], DateObject[{2022}], "Years"];
Wolfram Language code: Entity["Company", "Apple::5zkjq"][Dated[EntityProperty["Company", "NetIncome"], #]& /@ years]

Get the same result by requesting the net income for multiple dated entities:

Wolfram Language code: EntityValue[Dated[Entity["Company", "Apple::5zkjq"], #]& /@ years, EntityProperty["Company", "NetIncome"]]

Get the five largest countries by electricity from wind in 2010:

Wolfram Language code: wind2010 = Dated[EntityProperty["Country", "ElectricityWind"], 2010];
Wolfram Language code: EntityClass["Country", wind2010 -> TakeLargest[5]][wind2010, "Association"]

Applications  (10)

Find the planet currently closest to Earth:

Wolfram Language code: EntityList[EntityClass["Planet", "DistanceFromEarth" -> TakeSmallest[2]]]

Find the planet closest to Earth on February 2, 2023:

Wolfram Language code: EntityList[EntityClass["Planet", Dated["DistanceFromEarth", DateObject[{2023, 2, 2}, "Day"]] -> TakeSmallest[2]]]

Find Mercury's and Mars's distances from Earth between January and October 2023:

Wolfram Language code: EntityValue[{Entity["Planet", "Mercury"], Entity["Planet", "Mars"]}, Dated["DistanceFromEarth", #]& /@ DateRange[DateObject[{2023, 1}, "Month"], DateObject[{2023, 10}, "Month"], "Months"], "EntityAssociation"]
Wolfram Language code: ListPlot[%, Joined -> True]

Get US retail sales on January 1, 2022:

Wolfram Language code: Dated[Entity["Country", "UnitedStates"], DateObject[{2022, 1, 1}]]["RetailSales"]

Get the US M1 vs. M2 money supply in 2020:

Wolfram Language code: Dated[Entity["Country", "UnitedStates"], 2020][{EntityProperty["Country", "MoneySupply", {"Component" -> "M1"}], EntityProperty["Country", "MoneySupply", {"Component" -> "M2"}]}]

History plot of US real GDP annual growth rate from 1965 to 2000:

Wolfram Language code: DateListPlot[Entity["Country", "UnitedStates"][Dated[EntityProperty["Country", "GrossDomesticProduct", {"Adjustment" -> "Real", "TimeSeriesOperator" -> "AnnualizedChangeRate"}], Interval[{DateObject[{1965}, "Year"], DateObject[{2000}, "Year"]}]]]]

Make a history plot of the US national debt divided by the US GDP from 1978:

Wolfram Language code: DateListPlot[Entity["Country", "UnitedStates"][Dated[EntityProperty["Country", "GrossDomesticProduct"], Interval[{DateObject[{1978}, "Year"], Today}]]] / Entity["Country", "UnitedStates"][Dated[EntityProperty["Country", "FederalDebt"], Interval[{DateObject[{1978}, "Year"], Today}]]]]

Make a pie chart of US industrial production by sector in 1995:

Wolfram Language code: sectors = {"FinalProducts", "ConsumerGoods", "BusinessEquipment", "Manufacturing", "Materials", "Mining", "ElectricGasUtilities"}; PieChart[Dated[Entity["Country", "UnitedStates"], 1995][EntityProperty["Country", "IndustrialProduction", {"ProductionSector" -> #}]& /@ sectors], ChartLegends -> sectors]

Compare Illinois and Wisconsin unemployment rate in March 1996:

Wolfram Language code: Dated[{Entity["AdministrativeDivision", {"Illinois", "UnitedStates"}], Entity["AdministrativeDivision", {"Wisconsin", "UnitedStates"}]}, DateObject[{1996, 3}]]["CivilianUnemploymentRate", "Association"]

Make a history plot of Phoenix, St. Louis, Miami housing prices from 2010:

Wolfram Language code: With[{cities = {Entity["City", {"Phoenix", "Arizona", "UnitedStates"}], Entity["City", {"SaintLouis", "Missouri", "UnitedStates"}], Entity["City", {"Miami", "Florida", "UnitedStates"}]}}, DateListPlot[Dated[cities, Interval[{DateObject[{2010}], Today}]]["MedianHomeListingPrice"], PlotLegends -> cities]]

Make a geo region value plot of US mid-west states GDP per capita in 2020:

Wolfram Language code: GeoRegionValuePlot[EntityList@EntityClass["AdministrativeDivision", "USStatesMidwest"] -> Dated[EntityProperty["AdministrativeDivision", "GrossDomesticProduct", {"Modifier" -> "PerCapita"}], 2020]]

Properties & Relations  (1)

Get the population of a country on a given date:

Wolfram Language code: Entity["Country", "UnitedStates"][Dated["Population", DateObject[{2020}, "Year"]]]

The following is equivalent:

Wolfram Language code: Entity["Country", "UnitedStates"][EntityProperty["Country", "Population", {"Date" -> DateObject[{2020}, "Year"]}]]
Wolfram Research (2016), Dated, Wolfram Language function, https://reference.wolfram.com/language/ref/Dated.html.

Text

Wolfram Research (2016), Dated, Wolfram Language function, https://reference.wolfram.com/language/ref/Dated.html.

CMS

Wolfram Language. 2016. "Dated." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/Dated.html.

APA

Wolfram Language. (2016). Dated. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Dated.html

BibTeX

@misc{reference.wolfram_2026_dated, author="Wolfram Research", title="{Dated}", year="2016", howpublished="\url{https://reference.wolfram.com/language/ref/Dated.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_dated, organization={Wolfram Research}, title={Dated}, year={2016}, url={https://reference.wolfram.com/language/ref/Dated.html}, note=[Accessed: 12-June-2026]}