WOLFRAM

Wolfram Language & System Documentation Center

DayHemisphere[]

is a two-dimensional GeoGraphics primitive that represents the half of the Earth that is currently in daylight.

DayHemisphere[datespec]

represents the daylight half of the Earth for the specified date.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Options  
ReferenceAltitude  
Properties & Relations  
Neat Examples  
See Also
Tech Notes
Related Guides
History
Cite this Page

DayHemisphere

DayHemisphere[]

is a two-dimensional GeoGraphics primitive that represents the half of the Earth that is currently in daylight.

DayHemisphere[datespec]

represents the daylight half of the Earth for the specified date.

Details and Options

  • datespec can be a DateObject or a string that resolves to a date.
  • A date without explicit time zone is assumed to use $TimeZone.
  • The DayHemisphere[…] primitive can be used in maps of solar system bodies other than Earth, such as planets and many of their moons.
  • The option ReferenceAltitude specifies how to define the terminator line, separating the day and night hemispheres. Possible values include:
  • Automaticupper limb of the Sun crosses zero altitude
    altcenter of the Sun crosses numeric altitude alt
    {alt,limb}the given limb of the Sun crosses numeric altitude alt
    "Civil"the center of the Sun has altitude –6 degrees
    "Nautical"the center of the Sun has altitude –12 degrees
    "Astronomical"the center of the Sun has altitude –18 degrees
  • The reference altitude angle alt can be given as a Quantity angle or as a numeric expression interpreted in angular degrees.
  • Possible values for the limb of the Sun include:
  • "UpperLimb"upper limb of the Sun
    "Center"central point of the Sun
    "LowerLimb"lower limb of the Sun
    limbnumeric value between –1 (lower limb) and 1 (upper limb)

Examples

open all close all

Basic Examples  (2)

Color the part of the Earth currently in daylight:

Wolfram Language code: GeoGraphics[{GeoStyling[Opacity[0.5], Yellow], DayHemisphere[]}, GeoRange -> "World"]

Show the illuminated part of the Earth on the next summer solstice using red lines to denote the Arctic and Antarctic Circles:

Wolfram Language code: solstice = FindAstroEvent["JuneSolstice"]
Wolfram Language code: GeoGraphics[{GeoStyling[Opacity[0.5], Yellow], DayHemisphere[solstice], Red, GeoPath["ArcticCircle"], GeoPath["AntarcticCircle"]}, GeoRange -> "World"]

Use a different projection:

Wolfram Language code: GeoGraphics[{GeoStyling[Opacity[0.5], Yellow], DayHemisphere[solstice], Red, GeoPath["ArcticCircle"], GeoPath["AntarcticCircle"]}, GeoRange -> "World", GeoProjection -> "Bonne"]

Scope  (3)

DayHemisphere[] gives a plot for the current date and time:

Wolfram Language code: GeoGraphics[DayHemisphere[]]

Using Now explicitly gives the same result:

Wolfram Language code: GeoGraphics[DayHemisphere[Now]]

Illustrate changes in the illuminated hemisphere at different times of day and year:

Wolfram Language code: GeoGraphics[Table[{GeoStyling[Opacity[0.2], Hue[n / 12]], DayHemisphere[DateObject[{2014, n, 1, 2n, 0, 0}]]}, {n, 1, 12}]]

Specify dates in other formats:

Wolfram Language code: GeoGraphics[DayHemisphere["31 December 2000"]]
Wolfram Language code: GeoGraphics[DayHemisphere[Tomorrow]]

Options  (1)

ReferenceAltitude  (1)

By default, DayHemisphere corresponds to the part of the Earth for which the Sun is above the horizon:

Wolfram Language code: GeoGraphics[{StandardYellow, DayHemisphere[]}]

Show the parts of the Earth including the areas of civil, nautical and astronomical twilight:

Wolfram Language code: dayHemispheres = { DayHemisphere[], DayHemisphere[ReferenceAltitude -> "Civil"], DayHemisphere[ReferenceAltitude -> "Nautical"], DayHemisphere[ReferenceAltitude -> "Astronomical"] };
Wolfram Language code: GeoGraphics[{StandardYellow, dayHemispheres}]

Their meaning is clearer in a world map using the "Orthographic" projection:

Wolfram Language code: Manipulate[GeoGraphics[{StandardYellow, dayHemispheres}, GeoProjection -> "Orthographic", GeoCenter -> {lat, lon}], {{lat, 0}, -90, 90}, {{lon, 0}, -180, 180}, SaveDefinitions -> True]

Properties & Relations  (2)

The terminator line separates the day and night hemispheres:

Wolfram Language code: GeoGraphics[{GeoStyling[Opacity[0.5], Yellow], DayHemisphere[], GeoStyling[Opacity[0.5], Black], NightHemisphere[], Red, DayNightTerminator[]}]

For a spherical model of the Earth, the day hemisphere is a geo disk:

Wolfram Language code: sun = AstroSubpoint["Sun"]
Wolfram Language code: d = GeoDistance[sun, GeoAntipode[sun]] / 2
Wolfram Language code: GeoGraphics[{DayHemisphere[], GeoStyling[Opacity[0.3], Red], GeoDisk[sun, d]}, GeoRange -> "World"]

The true day hemisphere and approximate daylight geo disk differ slightly when using an ellipsoidal model of the Earth:

Wolfram Language code: GeoGraphics[{DayHemisphere[], GeoStyling[Opacity[0.3], Red], GeoDisk[sun, d]}, GeoCenter -> GeoDestination[sun, {d, 90}], GeoRange -> Quantity[20, "Miles"], Frame -> True]

Neat Examples  (1)

Use a different map style in the day and night hemispheres:

Wolfram Language code: GeoGraphics[{GeoStyling["ReliefMap"], DayHemisphere[], GeoStyling["Satellite"], NightHemisphere[]}, GeoBackground -> None, ImageSize -> Large]
Wolfram Research (2014), DayHemisphere, Wolfram Language function, https://reference.wolfram.com/language/ref/DayHemisphere.html (updated 2026).

Text

Wolfram Research (2014), DayHemisphere, Wolfram Language function, https://reference.wolfram.com/language/ref/DayHemisphere.html (updated 2026).

CMS

Wolfram Language. 2014. "DayHemisphere." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2026. https://reference.wolfram.com/language/ref/DayHemisphere.html.

APA

Wolfram Language. (2014). DayHemisphere. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/DayHemisphere.html

BibTeX

@misc{reference.wolfram_2026_dayhemisphere, author="Wolfram Research", title="{DayHemisphere}", year="2026", howpublished="\url{https://reference.wolfram.com/language/ref/DayHemisphere.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_dayhemisphere, organization={Wolfram Research}, title={DayHemisphere}, year={2026}, url={https://reference.wolfram.com/language/ref/DayHemisphere.html}, note=[Accessed: 12-June-2026]}