WOLFRAM

Wolfram Language & System Documentation Center

DayNightTerminator[]

is a one-dimensional GeoGraphics primitive that represents the separation line between the halves of the Earth currently in daytime and nighttime.

DayNightTerminator[datespec]

represents the separation line between day and night for the specified date.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Options  
ReferenceAltitude  
Properties & Relations  
See Also
Tech Notes
Related Guides
History
Cite this Page

DayNightTerminator

DayNightTerminator[]

is a one-dimensional GeoGraphics primitive that represents the separation line between the halves of the Earth currently in daytime and nighttime.

DayNightTerminator[datespec]

represents the separation line between day and night for the specified date.

Details and Options

  • datespec can be specified as a DateObject or a string that resolves to a date.
  • A date without explicit time zone is assumed to use $TimeZone.
  • The DayNightTerminator[…] primitive can be used in maps of solar system bodies other than Earth, such as planets and many of their moons.
  • The option ReferenceAltitude specifies how to define the terminator line. Possible values include:
  • Automaticupper limb of the Sun crosses zero altitude
    altcenter of the Sun crosses numeric altitude alt
    {alt,limb}the given limb of the Sun crosses numeric altitude alt
    "Civil"the center of the Sun has altitude –6 degrees
    "Nautical"the center of the Sun has altitude –12 degrees
    "Astronomical"the center of the Sun has altitude –18 degrees
  • The reference altitude angle alt can be given as a Quantity angle or as a numeric expression interpreted in angular degrees.
  • Possible values for the limb of the Sun include:
  • "UpperLimb"upper limb of the Sun
    "Center"central point of the Sun
    "LowerLimb"lower limb of the Sun
    limbnumeric value between –1 (lower limb) and 1 (upper limb)

Examples

open all close all

Basic Examples  (2)

Display the current terminator as a line:

Wolfram Language code: GeoGraphics[{Blue, DayNightTerminator[]}, GeoRange -> "World"]

Show the terminator line on the summer solstice using red lines to denote the Arctic and Antarctic Circles:

Wolfram Language code: GeoGraphics[{Red, GeoPath["ArcticCircle"], GeoPath["AntarcticCircle"], Blue, DayNightTerminator[DateObject[{2017, 6, 21}]]}, GeoRange -> "World"]

Use a different projection:

Wolfram Language code: GeoGraphics[{Red, GeoPath["ArcticCircle"], GeoPath["AntarcticCircle"], Blue, DayNightTerminator[DateObject[{2017, 6, 21}]]}, GeoRange -> "World", GeoProjection -> "Albers"]

Scope  (3)

DayNightTerminator[] gives a plot for the current date and time:

Wolfram Language code: GeoGraphics[DayNightTerminator[]]

Using Now explicitly gives the same result:

Wolfram Language code: GeoGraphics[DayNightTerminator[Now]]

Illustrate changes in the terminator at monthly intervals:

Wolfram Language code: GeoGraphics[Table[{Hue[month / 12], DayNightTerminator[DateObject[{2014, month, 1}]]}, {month, 1, 12}]]

Specify dates in other formats:

Wolfram Language code: GeoGraphics[DayNightTerminator["23 Sept 2018"]]
Wolfram Language code: GeoGraphics[DayNightTerminator[Tomorrow]]

Options  (1)

ReferenceAltitude  (1)

By default, DayNightTerminator corresponds to the points that observe the Sun on the horizon:

Wolfram Language code: GeoGraphics[DayNightTerminator[]]

Show the terminators for civil, nautical and astronomical twilight:

Wolfram Language code: terminators = { DayNightTerminator[], DayNightTerminator[ReferenceAltitude -> "Civil"], DayNightTerminator[ReferenceAltitude -> "Nautical"], DayNightTerminator[ReferenceAltitude -> "Astronomical"] };
Wolfram Language code: GeoGraphics[terminators]

Their meaning is clearer in a world map using the "Orthographic" projection:

Wolfram Language code: Manipulate[GeoGraphics[terminators, GeoProjection -> "Orthographic", GeoCenter -> {lat, lon}], {{lat, 0}, -90, 90}, {{lon, 0}, -180, 180}, SaveDefinitions -> True]

Properties & Relations  (2)

The terminator line separates the day and night hemispheres:

Wolfram Language code: GeoGraphics[{GeoStyling[Opacity[0.5], Yellow], DayHemisphere[], GeoStyling[Opacity[0.5], Black], NightHemisphere[], Red, DayNightTerminator[]}]

For a spherical model of the Earth, the terminator line is approximately a geo circle:

Wolfram Language code: sun = GeoPosition[Reverse[SunPosition[CelestialSystem -> "Equatorial"]] - {0, SiderealTime[GeoPosition[{0, 0}]]}]
Wolfram Language code: d = GeoDistance[sun, GeoAntipode[sun]] / 2
Wolfram Language code: GeoGraphics[{DayNightTerminator[], Red, GeoCircle[sun, d]}, GeoRange -> "World"]

The true terminator and approximate terminator geo circle differ slightly when using an ellipsoidal model of the Earth:

Wolfram Language code: GeoGraphics[{DayNightTerminator[], Red, GeoCircle[sun, d]}, GeoCenter -> GeoDestination[sun, {d, 90}], GeoRange -> Quantity[20, "Miles"], Frame -> True]
Wolfram Research (2014), DayNightTerminator, Wolfram Language function, https://reference.wolfram.com/language/ref/DayNightTerminator.html (updated 2026).

Text

Wolfram Research (2014), DayNightTerminator, Wolfram Language function, https://reference.wolfram.com/language/ref/DayNightTerminator.html (updated 2026).

CMS

Wolfram Language. 2014. "DayNightTerminator." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2026. https://reference.wolfram.com/language/ref/DayNightTerminator.html.

APA

Wolfram Language. (2014). DayNightTerminator. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/DayNightTerminator.html

BibTeX

@misc{reference.wolfram_2026_daynightterminator, author="Wolfram Research", title="{DayNightTerminator}", year="2026", howpublished="\url{https://reference.wolfram.com/language/ref/DayNightTerminator.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_daynightterminator, organization={Wolfram Research}, title={DayNightTerminator}, year={2026}, url={https://reference.wolfram.com/language/ref/DayNightTerminator.html}, note=[Accessed: 12-June-2026]}