WOLFRAM

Wolfram Language & System Documentation Center

DayRange[date1,date2]

gives the dates in the range from date1 to date2.

DayRange[date1,date2,daytype]

gives the dates in the range from date1 to date2 that are of the specified daytype.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Options  
CalendarType  
HolidayCalendar  
"IncludeEndPoints"  
Applications  
Properties & Relations  
Possible Issues  
See Also
Related Guides
Related Links
History
Cite this Page

DayRange

DayRange[date1,date2]

gives the dates in the range from date1 to date2.

DayRange[date1,date2,daytype]

gives the dates in the range from date1 to date2 that are of the specified daytype.

Details and Options

  • DayRange returns a list of DateObject elements.
  • A date can be specified in the following forms:
  • DateObject[…]date object
    {y,m,d}year, month, day
    {y,m}the first day of the specified month
    {y}January 1 of the year y
    "string"date as a string ("Jan. 1, 2000")
    {y,m,d,h,m,s}precise time
    timeabsolute time specification
  • Possible day types are:
  • Allany calendar date (default)
    "Weekday"date considered a weekday
    "Weekend"date considered a weekend
    "Holiday" holiday according to HolidayCalendar
    "NonHoliday"date that is not a holiday
    "BusinessDay"non-holiday weekday
    "NonBusinessDay"holiday or weekend
    "WeekdayHoliday"holiday on a weekday
    "WeekendHoliday"holiday on a weekend
    "WeekendNonHoliday"non-holiday weekend
    Monday, Tuesday, …a specific day of the week
    "EndOfMonth"final day of a given month
    "BeginningOfMonth"first day of a given month
  • In the Jewish calendar, the weekdays are Sunday through Thursday.
  • DayRange takes the following options:
  • CalendarTypeAutomaticcalendar in which the dates have been specified
    HolidayCalendar{"UnitedStates","Default"}holiday schedule and subspecification for the business day and holiday computations
    "IncludeEndPoints"{True,True}whether date1 and date2 are to be included in the range

Examples

open all close all

Basic Examples  (4)

Print all the dates in a date range:

Wolfram Language code: DayRange[Yesterday, Tomorrow]

Print all dates that fall on a given day of the week:

Wolfram Language code: With[{first = Take[DateList[], 2]}, DayRange[first, DatePlus[first, {{1, "Month"}, {-1, "Day"}}], Sunday]]

Print all business days in the date range:

Wolfram Language code: DayRange[DateObject[{2022, 1, 1}], DateObject[{2022, 1, 31}], "BusinessDay"]

Print all holidays in the current year, subject to the default holiday schedule:

Wolfram Language code: With[{firstday = DayRound[CurrentDate["Year"]]}, DayRange[firstday, DatePlus[firstday, {{1, "Year"}, {-1, "Day"}}], "Holiday"]]

Scope  (1)

Determine the last days of the month:

Wolfram Language code: With[{first = Take[DateList[], 1]}, DayRange[first, DatePlus[first, {{1, "Year"}, {-1, "Day"}}], "EndOfMonth"]]

Options  (4)

CalendarType  (1)

List all US holidays that will occur in the current Islamic calendar year:

Wolfram Language code: With[{first = {Nest[First, DateObject[CalendarType -> "Islamic"], 2]}}, DayRange[first, DatePlus[first, {{1, "Year"}, {-1, "Day"}}], "Holiday", CalendarType -> "Islamic"]]

HolidayCalendar  (2)

List holidays in India:

Wolfram Language code: DayRange[{2012}, {2012, 12, 31}, "Holiday", HolidayCalendar -> "India"]

Different markets within a country may have different holiday schedules:

Wolfram Language code: CalendarData["UnitedStates"]
Wolfram Language code: With[{first = {2012, 4}}, DayRange[first, DatePlus[first, {{1, "Month"}}], "Holiday", HolidayCalendar -> {"UnitedStates", "NYSE"}]]
Wolfram Language code: With[{first = {2012, 4}}, DayRange[first, DatePlus[first, {{1, "Month"}}], "Holiday"]]

"IncludeEndPoints"  (1)

Include the start but not the end date in the range:

Wolfram Language code: With[{first = Take[DateList[], 2]}, DayRange[first, DatePlus[first, {{1, "Week"}}], "IncludeEndPoints" -> {True, False}]]

Applications  (1)

Compute the number of days until the next US presidential election (first Tuesday after the first Monday in November of leap years):

Wolfram Language code: nextelection[date_] := Module[{year = 4Ceiling[date[[1]] / 4], nearest}, nearest = DatePlus[DayRange[{year, 11, 1}, {year, 11, 30}, Monday][[1]], 1]; If[QuantityMagnitude[DateDifference[date, nearest]] > 0, DayCount[date, nearest], DayCount[date, DatePlus[DayRange[{year + 4, 11, 1}, {year + 4, 11, 30}, Monday][[1]], 1]]]//Floor]; nextelection[DateList[]]

Properties & Relations  (3)

DayCount is equivalent to the length of the list output by DayRange for the same set of inputs:

Wolfram Language code: With[{first = Take[DateList[], 2]}, Length[DayRange[first, DatePlus[first, {{1, "Month"}, {-1, "Day"}}], "BusinessDay", "IncludeEndPoints" -> {False, True}]] == DayCount[first, DatePlus[first, {{1, "Month"}, {-1, "Day"}}], "BusinessDay"]]

DayRange with a day type specification other than All is equivalent to a Select statement:

Wolfram Language code: DayRange[{2022}, {2023}, "Weekend"] == Select[DayRange[{2022}, {2023}], DayMatchQ[#, "Weekend"]&]

Weekends, non-weekend holidays, and business days form three non-overlapping sets:

Wolfram Language code: With[{sets = {DayRange[{2022}, {2023}, "Holiday"], DayRange[{2022}, {2023}, "Weekend"], DayRange[{2022}, {2023}, "BusinessDay"]}}, Union@@sets == ((Join@@sets)//Sort)]

Possible Issues  (1)

A date may only be a holiday if it is not a weekend:

Wolfram Language code: With[{first = {2012, 7}}, DayRange[first, DatePlus[first, {{1, "Month"}, {-1, "Day"}}], "Weekend"]]
Wolfram Language code: With[{first = {2012, 7}}, DayRange[first, DatePlus[first, {{1, "Month"}, {-1, "Day"}}], "Holiday", HolidayCalendar -> {"Gregorian" -> {{True&, # == 7&, 1 ≤ # ≤ 31&}}}]]
Wolfram Research (2012), DayRange, Wolfram Language function, https://reference.wolfram.com/language/ref/DayRange.html (updated 2025).

Text

Wolfram Research (2012), DayRange, Wolfram Language function, https://reference.wolfram.com/language/ref/DayRange.html (updated 2025).

CMS

Wolfram Language. 2012. "DayRange." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2025. https://reference.wolfram.com/language/ref/DayRange.html.

APA

Wolfram Language. (2012). DayRange. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/DayRange.html

BibTeX

@misc{reference.wolfram_2026_dayrange, author="Wolfram Research", title="{DayRange}", year="2025", howpublished="\url{https://reference.wolfram.com/language/ref/DayRange.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_dayrange, organization={Wolfram Research}, title={DayRange}, year={2025}, url={https://reference.wolfram.com/language/ref/DayRange.html}, note=[Accessed: 13-June-2026]}