WOLFRAM

Wolfram Language & System Documentation Center

DifferentialRoot[lde][x]

gives the holonomic function , specified by the linear differential equation lde[h,x].

DifferentialRoot[lde]

represents a pure holonomic function .

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Numerical Evaluation  
Function Properties  
Differentiation  
Integration  
Series Expansions  
Generalizations & Extensions  
Applications  
Properties & Relations  
Possible Issues  
Neat Examples  
See Also
Tech Notes
Related Guides
History
Cite this Page

DifferentialRoot

DifferentialRoot[lde][x]

gives the holonomic function , specified by the linear differential equation lde[h,x].

DifferentialRoot[lde]

represents a pure holonomic function .

Details

  • Mathematical function, suitable for both symbolic and numerical manipulation; also known as holonomic function and D-finite function.
  • The holonomic function defined by a DifferentialRoot function satisfies a holonomic differential equation with polynomial coefficients and initial values .
  • DifferentialRoot can be used like any other mathematical function.
  • FunctionExpand will attempt to convert DifferentialRoot functions in terms of special functions.
  • The functions representable by DifferentialRoot include a large number of special functions.
  • DifferentialRootReduce can convert most special functions to DifferentialRoot functions.
  • Holonomic functions are closed under many operations, including:
  • , constant multiple, integer power
    , sums and products
    , , composition with polynomial, rational, and algebraic functions
    convolution
    , derivatives and integrals
  • DifferentialRoot is automatically generated by functions such as Integrate, DSolve, and GeneratingFunction.
  • Functions such as Integrate, D, SeriesCoefficient, and DSolve work with DifferentialRoot inputs.
  • DifferentialRoot can be evaluated to arbitrary numerical precision.
  • DifferentialRoot automatically threads over lists.
  • DifferentialRoot[lde,pred] represents a solution restricted to avoid cuts in the complex plane defined by pred[z], where pred[z] can contain equations and inequalities.

Examples

open all close all

Basic Examples  (2)

Define f to be the sin function:

Wolfram Language code: f = DifferentialRoot[Function[{y, x}, {y''[x] + y[x] == 0, y[0] == 0, y'[0] == 1}]]

Plot its result:

Wolfram Language code: Plot[f[x], {x, 0, 2Pi}]

Evaluate numerically to any precision:

Wolfram Language code: f[N[1 + I, 30]]

Compare the result with the built-in Sin function:

Wolfram Language code: Sin[N[1 + I, 30]]

Solve a differential equation:

Wolfram Language code: DSolve[y'''[x] - x^2 y'[x] - y[x] - Cos[x] == 0 && y[0] == 0 && y'[0] == 1 && y''[0] == 0, y, x]

Numerical values:

Wolfram Language code: Table[y[n] /. First[%], {n, 1, 2, 0.2}]

Scope  (23)

Numerical Evaluation  (7)

Evaluate at machine precision:

Wolfram Language code: DifferentialRoot[Function[{y, x}, {y'[x] - y[x] == 0, y[0] == 1}]][0.5]

Evaluate to high precision:

Wolfram Language code: DifferentialRoot[Function[{y, x}, {y'[x] - y[x] == 0, y[0] == 1}]][1 / 2`50]

The precision of the output tracks the precision of the input:

Wolfram Language code: DifferentialRoot[Function[{y, x}, {y'[x] - y[x] == 0, y[0] == 1}]][0.10000000000000000001]

DifferentialRoot takes complex number parameters and arguments:

Wolfram Language code: DifferentialRoot[Function[{y, x}, {x y''[x] + y'[x] - y[x] == 0, y[1 / 2] == 1, y'[1 / 2] == -3 / 4}]][1 / 2 + 1.I]
Wolfram Language code: DifferentialRoot[Function[{y, x}, {x y''[x] + I y'[x] - y[x] == 0, y[1 / 2] == 1 + 4I, y'[1 / 2] == -3 / 4}]][1 / 2 + 1.I]

DifferentialRoot takes inexact input parameters:

Wolfram Language code: DifferentialRoot[Function[{y, x}, {x y''[x] + y'[x] - y[x] == 0, y[1 / 2] == 1`20, y'[1 / 2] == -3 / 4}]][1 / 2 + 1I]
Wolfram Language code: Precision[%]

Evaluate DifferentialRoot efficiently at high precision:

Wolfram Language code: DifferentialRoot[Function[{y, x}, {x y''[x] + I y'[x] - y[x] == 0, y[1 / 2] == 1 + 4I, y'[1 / 2] == -3 / 4}]][2 / 10`100]//N//Timing

DifferentialRoot threads elementwise over lists and matrices:

Wolfram Language code: DifferentialRoot[Function[{y, x}, {x y''[x] + I y'[x] - y[x] == 0, y[1 / 2] == 1 + 4I, y'[1 / 2] == -3 / 4}]][{0.2, 1.4}]
Wolfram Language code: DifferentialRoot[Function[{y, x}, {x y''[x] + I y'[x] - y[x] == 0, y[1 / 2] == 1 + 4I, y'[1 / 2] == -3 / 4}]][(| | | | :------- | :------- | | 3.1 | 1 / 3`20 | | 4 / 5`20 | 0.4 |)]

Function Properties  (5)

DifferentialRoot objects have all the standard features of a mathematical function:

Wolfram Language code: f = DifferentialRoot[Function[{y, x}, {y'''[x] + 2x y''[x] - y[x] == 0, y[1 / 2] == 1, y'[1 / 2] == -3 / 4, y''[1 / 2] == 0}]]

Integrate the function:

Wolfram Language code: Integrate[f[x], x]

Differentiate it:

Wolfram Language code: D[f[x], x]

Find its series expansion:

Wolfram Language code: Series[f[x], {x, 1 / 2, 3}]

Plot it on the reals:

Wolfram Language code: Plot[f[x], {x, -10, 10}]

Plot it in the complex plane:

Wolfram Language code: ComplexPlot[f[z], {z, 5}, RasterSize -> 50, PlotLegends -> Automatic]

Simple exact values are generated automatically:

Wolfram Language code: DifferentialRoot[Function[{y, x}, {y''[x] + y[x] == 0, y[0] == 0, y'[0] == 1}]][Pi / 2]

Use FunctionExpand to attempt to convert a DifferentialRoot object to a built-in mathematical function:

Wolfram Language code: DifferentialRoot[Function[{y, x}, {y''[x] + y[x] == 0, y[0] == 0, y'[0] == 1}]][x]
Wolfram Language code: %//FunctionExpand

DifferentialRoot works on equations with rational coefficients:

Wolfram Language code: DifferentialRoot[Function[{y, x}, {y'''[x] / x + y[x] == 0, y[0] == 0, y'[0] == 1, y''[0] == 0}]]

Inhomogeneous holonomic equations are automatically transformed to higher-order homogeneous ones:

Wolfram Language code: DifferentialRoot[Function[{y, x}, {y'[x] - y[x] - Cos[x] == 0, y[0] == 1}]]

Differentiation  (4)

The derivative of DifferentialRoot is a DifferentialRoot function:

Wolfram Language code: f = DifferentialRoot[Function[{y, x}, {x + y[x] + y'[x] == 0, y[0] == 1}]][x]
Wolfram Language code: D[%, x]

Differentiate a DifferentialRoot object with respect to a parameter:

Wolfram Language code: f = DifferentialRoot[Function[{y, x}, {x + a y[x] + y'[x] == 0, y[0] == 1}]]
Wolfram Language code: D[f[x], a]

Compute higher-order derivatives of a DifferentialRoot object:

Wolfram Language code: f = DifferentialRoot[Function[{y, x}, {x + a y[x] + y'[x] == 0, y[0] == 1}]][x]
Wolfram Language code: D[f, {x, 2}]
Wolfram Language code: D[f, x, a]
Wolfram Language code: D[f, {a, 2}]

Differentiate a DifferentialRoot object:

Wolfram Language code: df = D[DifferentialRoot[Function[{y, x}, {4x^2 - y[x] + y'[x] == 0, y[0] == 1}]][x], x]

Specific values of :

Wolfram Language code: df /. x -> RandomReal[{-5, 5}, 5]

Plot of :

Wolfram Language code: Plot[df, {x, -5, 5}]

Integration  (4)

The integral of a DifferentialRoot object is a DifferentialRoot object:

Wolfram Language code: f = DifferentialRoot[Function[{y, x}, {x + y[x] + y'[x] == 0, y[0] == 1}]]
Wolfram Language code: Integrate[f[x], x]

Compute higher-order integrals of a DifferentialRoot object:

Wolfram Language code: f = DifferentialRoot[Function[{y, x}, {x + a y[x] + y'[x] == 0, y[0] == 1}]][x]
Wolfram Language code: Integrate[f, x, x]

Compute the definite integral of a DifferentialRoot object:

Wolfram Language code: f = DifferentialRoot[Function[{y, x}, {x^2 + y[x] + y'[x] == 0, y[0] == 1}]]
Wolfram Language code: Subsuperscript[∫, -1, 1]f[x]ⅆx

Integrate a DifferentialRoot object:

Wolfram Language code: F = Integrate[DifferentialRoot[Function[{y, x}, {x^2 + x y[x] + y'[x] == 0, y[0] == 1}]][x], x]

Specific values of :

Wolfram Language code: F /. x -> RandomReal[{-5, 5}, 5]

Plot of :

Wolfram Language code: Plot[F, {x, -5, 5}]

Series Expansions  (3)

Calculate the series expansion of a DifferentialRoot object:

Wolfram Language code: Series[DifferentialRoot[Function[{y, x}, {y''[x] + y[x] == 0, y[0] == 1, y'[0] == 1}]][x], {x, 0, 5}]

Find the ^(th) coefficient of the Taylor expansion of a DifferentialRoot object:

Wolfram Language code: SeriesCoefficient[DifferentialRoot[Function[{y, x}, {y''[x] + y[x] == 0, y[0] == 0, y'[0] == 1}]][x], {x, 0, n}]

Calculate the first 9 coefficients:

Wolfram Language code: Table[%, {n, 0, 9}]

Compare with the Sin function expansion coefficients:

Wolfram Language code: CoefficientList[Series[Sin[x], {x, 0, 10}]//Normal, {x}]

Calculate the series expansion of a DifferentialRoot object with a parameter:

Wolfram Language code: Series[DifferentialRoot[Function[{y, x}, {y''[x] + a y[x] == 0, y[0] == 1, y'[0] == 1}]][x], {x, 0, 5}]

Generalizations & Extensions  (1)

Equations with holonomic constant terms are automatically lifted to polynomial coefficients:

Wolfram Language code: DifferentialRoot[Function[{y, x}, {y'[x] - y[x] - Cos[x] == 0, y[0] == 1}]]

Applications  (4)

Generate a DifferentialRoot object from a special function:

Wolfram Language code: DifferentialRootReduce[BesselJ[2, Sqrt[x ^ 2 + 1]], x]

Integrate it:

Wolfram Language code: Integrate[%, x]

DifferentialRoot objects have all the standard features of a mathematical function:

Wolfram Language code: f = DifferentialRoot[Function[{y, x}, {y'''[x] + 2x y''[x] - y[x] == 0, y[1 / 2] == 1, y'[1 / 2] == -3 / 4, y''[1 / 2] == 0}]][x]

Find the coefficients of the series expansion of a DifferentialRoot object:

Wolfram Language code: SeriesCoefficient[f, {x, 1 / 2, n}]

Calculate the first 5 coefficients of the expansion explicitly:

Wolfram Language code: Table[%, {n, 0, 5}]

Compute arbitrary-order derivatives of a DifferentialRoot object:

Wolfram Language code: df = D[f, x]
Wolfram Language code: D[f, {x, 4}]

Integrate the DifferentialRoot object:

Wolfram Language code: F = Integrate[f, x]

Extract the differential equation and initial conditions of the function that is the integral of f:

Wolfram Language code: %[[0, 1]][y, x]

Plot the function f, its integral and derivative functions:

Wolfram Language code: Plot[{f, F, df}, {x, -10, 10}]

Use DifferentialRoot to homogenize a differential equation:

Wolfram Language code: dr = DifferentialRoot[Function[{y, x}, {y''[x] - x y[x] == Cos[x^2], y[0] == 1, y'[0] == -3 / 4 I}]]

Extract the homogenized equation:

Wolfram Language code: dr[[1]][y, x]

Generate a DifferentialRoot object that is a combination of two mathematical functions:

Wolfram Language code: DifferentialRootReduce[Sin[x] + 4 x Cos[x], x]

Extract the differential equation and initial conditions that this function obeys:

Wolfram Language code: %[[0, 1]][y, x]

Properties & Relations  (5)

DifferentialRootReduce generates DifferentialRoot objects:

Wolfram Language code: DifferentialRootReduce[Cos[x], x]

DSolve generates a DifferentialRoot object if the solution is not available in known functions:

Wolfram Language code: DSolve[y'''[x] + y'[x] + x^3y[x] == 0, y[x], x]

GeneratingFunction may generate a DifferentialRoot object:

Wolfram Language code: GeneratingFunction[DifferenceRoot[Function[{y, n}, {y[n] + (1 + n) (2 + n) y[n + 2] == 0, y[0] == 0, y[1] == 1}]][n], n, x]

Integrate returns a DifferentialRoot object for general holonomic functions:

Wolfram Language code: Integrate[DifferentialRoot[Function[{y, x}, {x + y[x] + y'[x] == 0, y[0] == 1}]][x], x]

D returns a DifferentialRoot object for general holonomic functions:

Wolfram Language code: D[DifferentialRoot[Function[{y, x}, {x + y[x] + y'[x] == 0, y[0] == 1}]][x], x]

Possible Issues  (3)

DifferentialRoot takes only linear differential equations with polynomial coefficients:

Wolfram Language code: DifferentialRoot[Function[{y, x}, {Sqrt[x]y''[x] - x y^2[x] == 0, y[0] == 1, y'[0] == -3 / 4 I}]][x]

DifferentialRoot will not evaluate if the initial values are given at a singular point:

Wolfram Language code: DifferentialRoot[Function[{y, x}, {x y''[x] + y'[x] - y[x] == 0, y[0] == 1, y'[0] == -3 / 4 I}]][x]

The branch cut structure of a built-in function may differ from the automatically computed branch cut structure:

Wolfram Language code: f = DifferentialRoot[Function[{y, x}, {x (x - 1)y''[x] + ((1 + 1 / 2 + 1 / 3)x - 1 / 4)y'[x] + 1 / 2 * 1 / 3y[x] == 0, y[1 + I] == Hypergeometric2F1[1 / 2, 1 / 3, 1 / 4, 1 + I], y'[1 + I] == (D[Hypergeometric2F1[1 / 2, 1 / 3, 1 / 4, z], z] /. z -> 1 + I)}]]

For some regions of the complex plane, the value of f differs from corresponding built-in function value:

Wolfram Language code: f[2. - I]
Wolfram Language code: Hypergeometric2F1[1 / 2, 1 / 3, 1 / 4, 2. - I]

For other regions, DifferentialRoot will give the same result:

Wolfram Language code: f[3. + 4I]
Wolfram Language code: Hypergeometric2F1[1 / 2, 1 / 3, 1 / 4, 3. + 4I]

Neat Examples  (1)

Solve a differential equation that is unsolved in known mathematical functions:

Wolfram Language code: sol = DSolveValue[{y''[x] + (x^10 - 1)y[x] == 0, y[0] == 1 / 2, y'[0] == -3 / 4}, y[x], x]

Calculate the numerical values of this solution:

Wolfram Language code: Table[sol, {x, 0., 1, 0.2}]

Plot this solution:

Wolfram Language code: Plot[sol, {x, -3, 3}]

Differentiate this solution:

Wolfram Language code: dsol = D[sol, x]
Wolfram Research (2008), DifferentialRoot, Wolfram Language function, https://reference.wolfram.com/language/ref/DifferentialRoot.html (updated 2020).

Text

Wolfram Research (2008), DifferentialRoot, Wolfram Language function, https://reference.wolfram.com/language/ref/DifferentialRoot.html (updated 2020).

CMS

Wolfram Language. 2008. "DifferentialRoot." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2020. https://reference.wolfram.com/language/ref/DifferentialRoot.html.

APA

Wolfram Language. (2008). DifferentialRoot. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/DifferentialRoot.html

BibTeX

@misc{reference.wolfram_2026_differentialroot, author="Wolfram Research", title="{DifferentialRoot}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/DifferentialRoot.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_differentialroot, organization={Wolfram Research}, title={DifferentialRoot}, year={2020}, url={https://reference.wolfram.com/language/ref/DifferentialRoot.html}, note=[Accessed: 13-June-2026]}