SeriesCoefficient[series,n]
finds the coefficient of the n 
-order term in a power series in the form generated by Series.
SeriesCoefficient[f,{x,x0,n}]
finds the coefficient of 
in the expansion of f about the point 
.
SeriesCoefficient
SeriesCoefficient[series,n]
finds the coefficient of the n 
-order term in a power series in the form generated by Series.
SeriesCoefficient[f,{x,x0,n}]
finds the coefficient of 
in the expansion of f about the point 
.
SeriesCoefficient[f,{x,x0,nx},{y,y0,ny},…]
finds a coefficient in a multivariate series.
Details and Options
- In the form SeriesCoefficient[f,{x,x0,n}], the order n can be symbolic.
- The following options can be given:
-
Assumptions $Assumptions assumptions to make about parameters Method Automatic method to use - For explicit SeriesData objects, the form SeriesCoefficient[series,{nx,ny,…}] can also be used.
Examples
open all close allBasic Examples (4)
Find the coefficient for a term in a series:
Series[Exp[Sin[x]], {x, 0, 10}]SeriesCoefficient[%, 8]Find the coefficient of the general term in a series:
SeriesCoefficient[Exp[-x], {x, 0, n}]Table[%, {n, 0, 5}]Series[Exp[-x], {x, 0, 5}]Find the coefficient for a term in a multivariate series:
Series[Exp[x + y], {x, 0, 3}, {y, 0, 3}]SeriesCoefficient[%, {3, 3}]Find the coefficient for a general term in a multivariate series:
SeriesCoefficient[Exp[x + y], {x, 0, n}, {y, 0, m}]Scope (6)
SeriesCoefficient[1 / (x ^ 2 - 3 / 2x + 1), {x, 0, n}]ListPlot[Table[%, {n, 0, 30}], Filling -> Axis]SeriesCoefficient[x / (x - 5), {x, 0, n}]SeriesCoefficient[x ^ 3 / ((-3 + x) (-2 + x) (-1 + x)), {x, 0, n}]SeriesCoefficient[Exp[x] / (1 - x), {x, 0, n}]SeriesCoefficient[Cos[Sqrt[x]], {x, 0, n}]SeriesCoefficient[Log[1 / Sqrt[1 - 5x ^ 2]], {x, 0, n}]SeriesCoefficient[PolyLog[-k, x], {x, 0, n}]SeriesCoefficient[BesselI[3, 2x] / x ^ 7, {x, 0, n}]SeriesCoefficient[HypergeometricPFQ[{1, 2}, {3, 4, 5}, 6x], {x, 0, n}]In general a DifferenceRoot function may be required to express the solution:
SeriesCoefficient[BesselI[3, (1/2x + 1)], {x, 0, n}, Assumptions -> n ≥ 0]Find the coefficients in multivariate functions:
SeriesCoefficient[Exp[3x + y ^ 2], {x, 0, m}, {y, 0, n}]SeriesCoefficient[Exp[x + y ^ 2] / (x + 1), {x, 0, m}, {y, 0, n}]SeriesCoefficient[Sin[x + y ^ 2] / (x + 1), {x, 0, m}, {y, 0, n}]Options (3)
Assumptions (2)
Coefficients of the expansion of the Chebyshev polynomials:
SeriesCoefficient[ChebyshevT[k, x], {x, 0, n}]Use Assumptions to get a simpler result:
SeriesCoefficient[ChebyshevT[k, x], {x, 0, n}, Assumptions -> k∈ Integers]With no Assumptions, general results are generated:
SeriesCoefficient[Exp[x], {x, 0, n}]With Assumptions a result valid under the given assumptions is given:
SeriesCoefficient[Exp[x], {x, 0, n}, Assumptions -> (n ≥ 0)]Method (1)
This generates a DifferenceRoot object when possible:
SeriesCoefficient[Exp[x], {x, 0, n}, Method -> "Holonomic"]Applications (4)
Find the 
Fibonacci number from its generating function:
Series[1 / (1 - t - t ^ 2), {t, 0, 10}]SeriesCoefficient[%, 10]Fibonacci[11]Find a Chebyshev polynomial from its generating function:
Series[1 / (1 - 2 t x + t ^ 2), {t, 0, 4}]SeriesCoefficient[%, 4]ChebyshevU[4, x]Solve a linear difference equation:
GeneratingFunction[y[n + 1] - 5y[n] == 1, n, x]Add the initial value equation and solve the algebraic equation for the transform:
Solve[% /. y[0] -> 2, GeneratingFunction[y[n], n, x]]SeriesCoefficient[GeneratingFunction[y[n], n, x] /. First[%], {x, 0, n}]Use RSolve:
RSolve[{y[n + 1] - 5y[n] == 1, y[0] == 2}, y[n], n]Find the coefficient of the general term in the power series expansion of 1/(1+x):
s = SeriesCoefficient[1 / (1 + x), {x, 0, n}]Obtain the power series expansion in Inactive form:
Inactive[Sum][Refine[s x ^ n, n ≥ 0], {n, 0, Infinity}]Make a table of the power series expansions for different functions:
flist = {2 / (3 - x), 1 / (x + 10), 3 / (x ^ 2 - x - 2), 1 / (1 + x) ^ 2, 1 / (1 + x) ^ 3, (x ^ 2) / (1 + x) ^ 3, 10 ^ x, (1 - 3 x) ^ (-5), (E ^ x) / x};Grid[Prepend[{#, Inactive[Sum][Refine[SeriesCoefficient[#1, {x, 0, n}] x ^ n, n ≥ 0], {n, 0, Infinity}]}& /@ flist, {"Function", "Power Series"}], IconizedObject[«Grid options»]]//TraditionalFormProperties & Relations (4)
Use DiscreteAsymptotic to compute an asymptotic approximation:
DiscreteAsymptotic[Inactive[SeriesCoefficient][-(z / (-1 + z + z ^ 2)), {z, 0, n}],
n -> ∞]The coefficients of a truncated series expansion:
Table[Coefficient[Series[Log[1 / Sqrt[1 + 5x ^ 2]], {x, 0, 5}], x, n], {n, 0, 4}]The general coefficient formula:
SeriesCoefficient[Log[1 / Sqrt[1 + 5x ^ 2]], {x, 0, n}]The general formula agrees with the truncated expansion:
Table[%, {n, 0, 4}]CoefficientList finds all coefficients in a series:
s = Series[1 / (1 - t - t ^ 2), {t, 0, 10}]Table[SeriesCoefficient[s, i], {i, 0, 10}]CoefficientList[s, t]SeriesCoefficient is closely related to InverseZTransform:
SeriesCoefficient[Exp[x ^ 2], {x, 0, n}]InverseZTransform[Exp[x ^ 2] /. x -> 1 / x, x, n]Simplify[% - %%, n ≥ 0]Possible Issues (2)
Series coefficients can be functions of the expansion variable:
Series[x ^ x, {x, 0, 5}]SeriesCoefficient[%, 4]General coefficients of series may not be available:
SeriesCoefficient[EllipticK[Sin[x ^ 2]], {x, 0, n}]Series[EllipticK[Sin[x ^ 2]], {x, 0, 12}]SeriesCoefficient[%, 4]Neat Examples (2)
Series coefficient for a hypergeometric function:
SeriesCoefficient[HypergeometricPFQ[{Subscript[a, 1], Subscript[a, 2]}, {Subscript[b, 1], Subscript[b, 2], Subscript[b, 3]}, x], {x, 0, n}]Create a gallery of common series coefficients:
flist = {Exp[x], Sin[x], Cos[x], 1 / (1 + x), Log[1 + x], ArcTan[x]};Grid[Prepend[{#, SeriesCoefficient[#1, {x, 0, n}]}& /@ flist, {f[x], "Series Coefficient"}], IconizedObject[«Grid options»]]//TraditionalFormRelated Links
MathWorldText
Wolfram Research (1996), SeriesCoefficient, Wolfram Language function, https://reference.wolfram.com/language/ref/SeriesCoefficient.html (updated 2008).
CMS
Wolfram Language. 1996. "SeriesCoefficient." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2008. https://reference.wolfram.com/language/ref/SeriesCoefficient.html.
APA
Wolfram Language. (1996). SeriesCoefficient. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/SeriesCoefficient.html