WOLFRAM

Wolfram Language & System Documentation Center

DirichletWindow[x]

represents a Dirichlet window function of x.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Applications  
Properties & Relations  
See Also
Related Guides
History
Cite this Page

DirichletWindow

DirichletWindow[x]

represents a Dirichlet window function of x.

Details

  • DirichletWindow, also known as the rectangular or boxcar window, is a window function used in signal processing applications where data needs to be processed in short segments.
  • DirichletWindow[x] is equal to  1 -1/2<=x<=1/2; 0 TemplateBox[{x}, Abs]>1/2; .
  • DirichletWindow automatically threads over lists.

Examples

open all close all

Basic Examples  (3)

Shape of a 1D Dirichlet window:

Wolfram Language code: Plot[DirichletWindow[x], {x, -1, 1}, Exclusions -> None]

Shape of a 2D Dirichlet window:

Wolfram Language code: Plot3D[DirichletWindow[x]DirichletWindow[y], {x, -1, 1}, {y, -1, 1}, PlotRange -> All, Exclusions -> None]

Extract the continuous function representing the Dirichlet window:

Wolfram Language code: FunctionExpand[DirichletWindow[x]]

Scope  (4)

Evaluate numerically:

Wolfram Language code: DirichletWindow[0.1]

Translated and dilated Dirichlet window:

Wolfram Language code: Plot[DirichletWindow[(x - 1) / 2], {x, -1, 3}, Exclusions -> None]

2D Dirichlet window with a circular support:

Wolfram Language code: Plot3D[DirichletWindow[Sqrt[x ^ 2 + y ^ 2]], {x, -1, 1}, {y, -1, 1}, PlotRange -> All, Exclusions -> None]

Discrete Dirichlet window of length 15:

Wolfram Language code: ListPlot[Array[DirichletWindow, 15, {-1 / 2, 1 / 2}], Filling -> Axis]

Discrete 15×10 2D Dirichlet window:

Wolfram Language code: ListPointPlot3D[Array[DirichletWindow[#1] DirichletWindow[#2]&, {15, 10}, {{-1, 1}}], Filling -> Axis]

Applications  (2)

Use a window specification to calculate sample PowerSpectralDensity:

Wolfram Language code: proc = ARMAProcess[1, {.5}, {.3}, 1]; data = RandomFunction[proc, {50}];

Calculate the spectrum:

Wolfram Language code: spec = PowerSpectralDensity[data, w, DirichletWindow];

Compare to spectral density calculated without a windowing function:

Wolfram Language code: sd = PowerSpectralDensity[data, w];
Wolfram Language code: sd === spec

The Dirichlet window does not change the spectral density:

Wolfram Language code: Plot[{sd, spec}, {w, -π, π}, PlotLegends -> {"no window", "with window"}]

Compare to the theoretical spectral density of the process:

Wolfram Language code: Plot[{spec, Evaluate@PowerSpectralDensity[proc, w]}, {w, -π, π}, PlotLegends -> {"data", "process"}]

Use a window specification for time series estimation:

Wolfram Language code: data = RandomFunction[ARMAProcess[1, {.3}, {.4}, 1], {300}];

Specify the window for the spectral estimator:

Wolfram Language code: EstimatedProcess[data, ARMAProcess[1, 1], ProcessEstimator -> {"SpectralEstimator", "Window" -> DirichletWindow}]

Properties & Relations  (3)

DirichletWindow is equivalent to UnitBox:

Wolfram Language code: PiecewiseExpand[DirichletWindow[x]] === PiecewiseExpand[UnitBox[x]]

Fourier transform of the Dirichlet window:

Wolfram Language code: f = FourierTransform[DirichletWindow[x], x, w]

Power spectrum of the Dirichlet window:

Wolfram Language code: LogLinearPlot[20 Log[10, Abs[f]], {w, .1, 80}]

Discrete-time Fourier transform of the discrete Dirichlet window of length 11:

Wolfram Language code: f = ListFourierSequenceTransform[Array[DirichletWindow, 11, {-1 / 2, 1 / 2}], ω, -5]//FullSimplify

Magnitude at ω=0:

Wolfram Language code: f0 = N[f /. ω -> 0]

Power spectrum:

Wolfram Language code: LogLinearPlot[20 Log[10, Abs[f] / f0], {ω, .1, π}, GridLines -> Automatic]
Wolfram Research (2012), DirichletWindow, Wolfram Language function, https://reference.wolfram.com/language/ref/DirichletWindow.html.

Text

Wolfram Research (2012), DirichletWindow, Wolfram Language function, https://reference.wolfram.com/language/ref/DirichletWindow.html.

CMS

Wolfram Language. 2012. "DirichletWindow." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/DirichletWindow.html.

APA

Wolfram Language. (2012). DirichletWindow. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/DirichletWindow.html

BibTeX

@misc{reference.wolfram_2026_dirichletwindow, author="Wolfram Research", title="{DirichletWindow}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/DirichletWindow.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_dirichletwindow, organization={Wolfram Research}, title={DirichletWindow}, year={2012}, url={https://reference.wolfram.com/language/ref/DirichletWindow.html}, note=[Accessed: 12-June-2026]}