WOLFRAM

Wolfram Language & System Documentation Center

DownValues[f]

gives a list of transformation rules corresponding to all downvalues (values for f[…]) defined for the symbol f.

DownValues["symbol"]

gives a list of transformation rules corresponding to all downvalues defined for the symbol named "symbol" if it exists.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Applications  
Properties & Relations  
See Also
Tech Notes
Related Guides
History
Cite this Page

DownValues

DownValues[f]

gives a list of transformation rules corresponding to all downvalues (values for f[…]) defined for the symbol f.

DownValues["symbol"]

gives a list of transformation rules corresponding to all downvalues defined for the symbol named "symbol" if it exists.

Details and Options

  • You can specify the downvalues for f by making an assignment of the form DownValues[f]=list.
  • The list returned by DownValues has elements of the form HoldPattern[lhs]:>rhs.

Examples

open all close all

Basic Examples  (1)

Define values for a function f:

Wolfram Language code: f[1] = 2;
Wolfram Language code: f[2] = 3;
Wolfram Language code: f[x_] := x ^ 2

These are the downvalues associated with f:

Wolfram Language code: DownValues[f]

Scope  (3)

DownValues returns rules corresponding to definitions made for a symbol:

Wolfram Language code: f[x_] := x ^ 2
Wolfram Language code: DownValues[f]

Create several functions:

Wolfram Language code: f[x_] := x g[x_] := x ^ 2 fg[x_] := f[g[x]]

Obtain the downvalues of functions whose names start with f:

Wolfram Language code: DownValues /@ Names["f*"]

DownValues can be used to set the values directly:

Wolfram Language code: DownValues[g] = {HoldPattern[g[1]] :> 1, HoldPattern[g[x_]] :> 2g[x - 1]};
Wolfram Language code: Definition[g]
Wolfram Language code: g[5]

Applications  (2)

The resulting rules are in the order given:

Wolfram Language code: f[x_ /; x > -2] := g1[x] f[x_ /; x < 2] := g2[x]
Wolfram Language code: DownValues[f]
Wolfram Language code: f[0]

Now reorder the definitions:

Wolfram Language code: DownValues[f] = Reverse[DownValues[f]]
Wolfram Language code: f[0]

Copy a symbol's definitions to another symbol:

Wolfram Language code: f[1] = 1; f[x_] := 2f[x - 1]
Wolfram Language code: DownValues[g] = DownValues[f] /. f -> g
Wolfram Language code: g[10]
Wolfram Language code: % == f[10]

Properties & Relations  (5)

Values can be defined by immediate or delayed assignments:

Wolfram Language code: f[1] = 1; f[n_] := n * f[n - 1]
Wolfram Language code: DownValues[f]

HoldPattern is used to protect the rules from their own definitions:

Wolfram Language code: f[x_] := x ^ 2
Wolfram Language code: DownValues[f]

Without the HoldPattern, the left-hand side would have evaluated:

Wolfram Language code: f[x_] :> x ^ 2

DownValues["sym"] will issue a message if the specified symbol does not exist:

Wolfram Language code: DownValues["f"]

If the symbol exists but has no definitions, an empty list is returned:

Wolfram Language code: f; DownValues["f"]

Definition and Information display downvalues but do not return them as values:

Wolfram Language code: f[x_] := x ^ 3
Wolfram Language code: Definition[f]
Wolfram Language code: %//FullForm

DownValues returns a value that can be used in a program:

Wolfram Language code: DownValues[f]

Evaluation of an expression involves applying rules for its head:

Wolfram Language code: f[x_] := x ^ 3
Wolfram Language code: Hold[f[2]] /. DownValues[f]
Wolfram Research (1991), DownValues, Wolfram Language function, https://reference.wolfram.com/language/ref/DownValues.html (updated 2022).

Text

Wolfram Research (1991), DownValues, Wolfram Language function, https://reference.wolfram.com/language/ref/DownValues.html (updated 2022).

CMS

Wolfram Language. 1991. "DownValues." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2022. https://reference.wolfram.com/language/ref/DownValues.html.

APA

Wolfram Language. (1991). DownValues. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/DownValues.html

BibTeX

@misc{reference.wolfram_2026_downvalues, author="Wolfram Research", title="{DownValues}", year="2022", howpublished="\url{https://reference.wolfram.com/language/ref/DownValues.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_downvalues, organization={Wolfram Research}, title={DownValues}, year={2022}, url={https://reference.wolfram.com/language/ref/DownValues.html}, note=[Accessed: 13-June-2026]}