WOLFRAM

Wolfram Language & System Documentation Center

lhs=rhs

evaluates rhs and assigns the result to be the value of lhs. From then on, lhs is replaced by rhs whenever it appears.

{l1,l2,…}={r1,r2,…}

evaluates the ri, and assigns the results to be the values of the corresponding li.

Details
Details and Options Details and Options
Background & Context
Examples  
Basic Examples  
Scope  
Left-Hand Sides  
Different Kinds of Values  
Generalizations & Extensions  
Applications  
Properties & Relations  
Possible Issues  
Neat Examples  
See Also
Tech Notes
Related Guides
Related Links
History
Cite this Page

Set

lhs=rhs

evaluates rhs and assigns the result to be the value of lhs. From then on, lhs is replaced by rhs whenever it appears.

{l1,l2,…}={r1,r2,…}

evaluates the ri, and assigns the results to be the values of the corresponding li.

Details

  • lhs can be any expression, including a pattern.
  • f[x_]=x^2 is a typical assignment for a pattern. Notice the presence of _ on the left‐hand side, but not the right‐hand side.
  • An assignment of the form f[args]=rhs sets up a transformation rule associated with the symbol f.
  • Different rules associated with a particular symbol are usually placed in the order that you give them. If a new rule that you give is determined to be more specific than existing rules, it is, however, placed before them. When the rules are used, they are tested in order. »
  • New assignments with identical lhs overwrite old ones. »
  • You can see all the assignments associated with a symbol f using ?f or Definition[f].
  • If you make assignments for functions that have attributes like Flat and Orderless, you must make sure to set these attributes before you make assignments for the functions.
  • Set has attribute HoldFirst.
  • If lhs is of the form f[args], then args are evaluated. »
  • There are some special functions for which an assignment to s[f[args]] is automatically associated with f rather than s. These functions include: Attributes, Default, Format, MessageName, Messages, N, and Options. »
  • When it appears in an unevaluated symbolic form, Set is treated as a scoping construct so that variables in nested occurrences are renamed if necessary. »
  • lhs=rhs returns rhs even if for some reason the assignment specified cannot be performed.
  • Some global variables such as $RecursionLimit can only be assigned a certain range or class of values.

Background & Context

  • Set is a function that evaluates and assigns an expression to be the value of a variable. The expression Set[lhs,rhs] is commonly represented using the shorthand syntax lhs=rhs. After Set is evaluated, lhs is replaced by rhs whenever it appears. Depending on the form of lhs, the result is stored as in the associated OwnValues, DownValues, or a specialized data structure.
  • Set often contains patterns on the lhs that are assigned transformed values as indicated on the rhs, e.g. f[x_] = x^2. lhs=rhs evaluates rhs immediately, so in situations where rhs should be evaluated only after the assignment is made, SetDelayed (written in shorthand as :=) should be used instead.
  • The assignments associated with a given symbol can be seen using Definition[f]. Individual assignments may be removed from a symbol using Unset; Clear and ClearAll remove all definitions at once.

Examples

open all close all

Basic Examples  (2)

Set a value for :

Wolfram Language code: x = a + b

Now use it:

Wolfram Language code: 1 + x ^ 2

Unset :

Wolfram Language code: x=.

Set multiple values:

Wolfram Language code: {x, y, z} = Range[3]

Evaluate an expression using those set values:

Wolfram Language code: x + y ^ 2 + z ^ 3

Scope  (15)

Left-Hand Sides  (7)

Ordinary program variables:

Wolfram Language code: i = 1; While[Prime[i] < 100, i = i + 1];i

Set values for "indexed variables":

Wolfram Language code: a[1] = x;a[2] = y;
Wolfram Language code: {a[1], a[2], a[3]}

Define a function from an expression:

Wolfram Language code: Expand[(1 + x) ^ 3]
Wolfram Language code: f[x_] = %
Wolfram Language code: f[a + b]

Use Block to temporarily set variables:

Wolfram Language code: Block[{$RecursionLimit = 20}, x = x + 1]

Set part of a list:

Wolfram Language code: v = {a, b, c, d}
Wolfram Language code: v[[2]] = x
Wolfram Language code: v

Set part of an expression:

Wolfram Language code: v = 1 + x ^ 5
Wolfram Language code: v[[2, 2]] = 77777
Wolfram Language code: v
Wolfram Language code: mat = (| | | | | - | - | - | | 1 | 2 | 3 | | 4 | 5 | 6 | | 7 | 8 | 9 |);

Replace a row of a matrix:

Wolfram Language code: mat[[2]] = mat[[2]] + 10; MatrixForm[mat]

Replace a column of a matrix:

Wolfram Language code: mat[[All, 3]] = {100, 101, 102}; MatrixForm[mat]

Different Kinds of Values  (8)

Ownvalues:

Wolfram Language code: x = 7;
Wolfram Language code: OwnValues[x]

Downvalues:

Wolfram Language code: a[1] = 17;
Wolfram Language code: DownValues[a]

Subvalues:

Wolfram Language code: derivative[1][f] = fg;
Wolfram Language code: SubValues[derivative]

Upvalues:

Wolfram Language code: sq/:area[sq] = s ^ 2;
Wolfram Language code: UpValues[sq]

Default values and options:

Wolfram Language code: Default[f] = 0;
Wolfram Language code: Options[f] = {opt1 -> def1, opt2 -> def2};
Wolfram Language code: DefaultValues[f]

Numerical values:

Wolfram Language code: N[const] = Product[1 - 2 ^ -i, {i, 2, 10}];
Wolfram Language code: NValues[const]
Wolfram Language code: N[const]

Format values:

Wolfram Language code: Format[a] = α;
Wolfram Language code: FormatValues[a]
Wolfram Language code: a

A definition for Attributes is associated with , rather than Attributes:

Wolfram Language code: Attributes[f] = HoldAll
Wolfram Language code: Definition[f]

Generalizations & Extensions  (5)

Set and to the same value:

Wolfram Language code: x = y = 77

Check:

Wolfram Language code: {x, y}

Set and to different values:

Wolfram Language code: {x, y} = {a, b}

Interchange values:

Wolfram Language code: {x, y} = {y, x}

Check that they were swapped:

Wolfram Language code: {x, y}

A sparse array:

Wolfram Language code: v = SparseArray[{1 -> 1, 4 -> 4}]

Set a part:

Wolfram Language code: v[[2]] = 3

v is still a sparse array, with its second part changed:

Wolfram Language code: {v, Normal[v]}

Assign multiple return values of a function to individual variables:

Wolfram Language code: {time, res} = Timing[N[Catalan, 100000]];

See the results:

Wolfram Language code: {time, N[res]}

A definition for a pattern with a specific head is associated with that head:

Wolfram Language code: _a = α

Show the definition:

Wolfram Language code: Definition[a]

Evaluate with it:

Wolfram Language code: {a, a[1]}

Applications  (6)

Compute the GCD of two numbers:

Wolfram Language code: {a, b} = {27, 6}; While[b ≠ 0, {a, b} = {b, Mod[a, b]}]; a

Find a fixed point:

Wolfram Language code: x = 1.0; While[Cos[x] ≠ x, x = Cos[x]]; x

Compute using Newton's method:

Wolfram Language code: x = 1.0; Do[x = (x + 2 / x) / 2, {5}]; x

Use a variable as an abbreviation for a complicated expression used more than once:

Wolfram Language code: x = (a + b)^2;
Wolfram Language code: 1 + x + 1 / x

A scalar implementation of backsubstitution in a system of linear equations:

Wolfram Language code: upperTriangularLinearSolve[ U_, v_ ] := Module[ {x, m, n}, {m, n} = Dimensions[U]; x = Range[n]; Do[x[[i]] = (v[[i]] - Subsuperscript[∑, j = i + 1, n]U[[i, j]] x[[j]]) / U[[i, i]], {i, n, 1, -1}]; x ]
Wolfram Language code: upperTriangularLinearSolve[{{1, 2}, {0, 3}}, {1, 2} ]

A vector implementation of backsubstitution in a system of linear equations:

Wolfram Language code: upperTriangularLinearSolve[ U_, v_ ] := Module[ {x, m, n}, {m, n} = Dimensions[U]; x = Range[n]; Do[x[[i]] = (v[[i]] - U[[i, i + 1 ;; n]].x[[i + 1 ;; n]]) / U[[i, i]], {i, n, 1, -1}]; x ];
Wolfram Language code: upperTriangularLinearSolve[{{1, 2}, {0, 3}}, {1, 2} ]

Properties & Relations  (9)

The right side of an immediate definition is evaluated when the definition is made:

Wolfram Language code: x = RandomReal[];

Multiple copies are the same value:

Wolfram Language code: {x, x, x}

The right side of a delayed definition is evaluated each time the definition is used:

Wolfram Language code: y := RandomReal[];

Now it evaluates three different times:

Wolfram Language code: {y, y, y}

The arguments of the left side of a definition are evaluated before the definition is made:

Wolfram Language code: x = 5;
Wolfram Language code: f[x] = 17
Wolfram Language code: Definition[f]

Definitions with the same left side overwrite earlier ones:

Wolfram Language code: a = 5;

Redefine:

Wolfram Language code: a = 6;

See that it has the new value:

Wolfram Language code: a

Make definitions for special and general cases using immediate and delayed assignments:

Wolfram Language code: fact[1] = 1; fact[n_] := n fact[n - 1] fact[10]

More specific definitions are put in front of more general ones:

Wolfram Language code: fact[n_] := n fact[n - 1]; fact[1] = 1; Definition[fact]

Use this definition of fact:

Wolfram Language code: fact[10]

The pattern variable is renamed if necessary inside a nested scope:

Wolfram Language code: makedef[z_] := (f[x_] = z ^ 2;) makedef[x]

Inspect it:

Wolfram Language code: Definition[f]

Use it:

Wolfram Language code: f[5]

Module introduces new symbols, distinct from global ones:

Wolfram Language code: x = 5; Module[{x}, x = 17;x]

Check that the global value of x is retained:

Wolfram Language code: x

Set a value for a:

Wolfram Language code: a = Sqrt[2]

Definition prints definitions associated with a symbol:

Wolfram Language code: Definition[a]

Information prints various information about a symbol, including any definitions:

Wolfram Language code: ? a

OwnValues returns a list of rules corresponding to any downvalues defined:

Wolfram Language code: OwnValues[a]

Define a function fact to compute factorials:

Wolfram Language code: fact[1] = 1; fact[n_] := n fact[n - 1]

Use Unset (=.) to clear definitions with a particular left-hand side:

Wolfram Language code: fact[1]=.

Check that the cleared definition is no longer present:

Wolfram Language code: Definition[fact]

Clear all definitions:

Wolfram Language code: Clear[fact]
Wolfram Language code: Definition[fact]

Possible Issues  (4)

In the presence of global variables, pattern variables may show unexpected behavior:

Wolfram Language code: x = 5;

Using a non-delayed assignment means the right side is evaluated before Set is done:

Wolfram Language code: f[x_] = x ^ 2;

So the evaluation uses the global setting and not the actual input to f:

Wolfram Language code: f[2]

Delayed assignments behave as expected:

Wolfram Language code: g[x_] := x ^ 2

Check that the value 2 is used and not the global value of 5:

Wolfram Language code: g[2]

Runaway definitions:

Wolfram Language code: x = x + 1

Setting an initial value avoids this:

Wolfram Language code: y = 5; y = y + 1

Pattern variables are not symbols; you cannot normally assign to them:

Wolfram Language code: wrong[x_] := (x = x ^ 2) wrong[5]

Use local variables for this purpose:

Wolfram Language code: right[x0_] := Module[{x}, x = x0 ^ 2] right[5]

Use upvalues to assign to subscripted variables:

Wolfram Language code: a/:Subscript[a, 1] = 5; FullForm[UpValues[a]]

Subscripted variables are distinct from indexed variables:

Wolfram Language code: a[1] = 6; FullForm[DownValues[a]]

Neat Examples  (1)

Compute the arithmetic-geometric mean of two numbers [more info]:

Wolfram Language code: {x, y} = N[{1, 2}, 20]; While[x ≠ y, {x, y} = {(x + y/2), Sqrt[x y]}];x
Wolfram Research (1988), Set, Wolfram Language function, https://reference.wolfram.com/language/ref/Set.html.

Text

Wolfram Research (1988), Set, Wolfram Language function, https://reference.wolfram.com/language/ref/Set.html.

CMS

Wolfram Language. 1988. "Set." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/Set.html.

APA

Wolfram Language. (1988). Set. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Set.html

BibTeX

@misc{reference.wolfram_2026_set, author="Wolfram Research", title="{Set}", year="1988", howpublished="\url{https://reference.wolfram.com/language/ref/Set.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_set, organization={Wolfram Research}, title={Set}, year={1988}, url={https://reference.wolfram.com/language/ref/Set.html}, note=[Accessed: 13-June-2026]}