WOLFRAM

Wolfram Language & System Documentation Center

FactorList[poly]

gives a list of the factors of a polynomial, together with their exponents.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Basic Uses  
Advanced Uses  
Options  
Extension  
GaussianIntegers  
Modulus  
Trig  
Applications  
Properties & Relations  
See Also
Tech Notes
Related Guides
History
Cite this Page

FactorList

FactorList[poly]

gives a list of the factors of a polynomial, together with their exponents.

Details and Options

  • The first element of the list is always the overall numerical factor. It is {1,1} if there is no overall numerical factor.
  • FactorList takes the following options:
  • Extension Nonecoefficient field to be used
    GaussianIntegers Falsewhether to allow Gaussian integer coefficients
    Modulus 0modulus to assume for integers
    Trig Falsewhether to do trigonometric as well as algebraic transformations
  • FactorList[poly,Modulus->p] requires that p be prime.
  • FactorList[poly,Extension->{a1,a2,…}] allows coefficients that are arbitrary rational combinations of the ai.

Examples

open all close all

Basic Examples  (2)

List the irreducible factors of polynomials:

Wolfram Language code: FactorList[x ^ 2 - 1]
Wolfram Language code: FactorList[2x ^ 3 + 2x ^ 2 - 2x - 2]

List the irreducible factors of multivariate polynomials:

Wolfram Language code: FactorList[x ^ 3 + 2x ^ 2y + x y ^ 2 + x ^ 2z - y ^ 2z - x z ^ 2 - 2y z ^ 2 - z ^ 3]

Scope  (11)

Basic Uses  (4)

A univariate polynomial:

Wolfram Language code: FactorList[x ^ 3 - 6x ^ 2 + 11x - 6]

A multivariate polynomial:

Wolfram Language code: FactorList[2x ^ 3 y - 2a ^ 2x y - 3a ^ 2x ^ 2 + 3a ^ 4]

A polynomial with multiple factors:

Wolfram Language code: FactorList[x ^ 8 + 11x ^ 7 + 43x ^ 6 + 59x ^ 5 - 35x ^ 4 - 151x ^ 3 - 63x ^ 2 + 81x + 54]

A rational function:

Wolfram Language code: FactorList[(x ^ 3 + 2x ^ 2) / (x ^ 2 - 4y ^ 2) - (x + 2) / (x ^ 2 - 4y ^ 2)]

Advanced Uses  (7)

The irreducible factors over the Gaussian integers:

Wolfram Language code: FactorList[x ^ 2 + 1, GaussianIntegers -> True]

The irreducible factors over an algebraic extension:

Wolfram Language code: FactorList[x ^ 4 - 2, Extension -> Sqrt[2]]

The irreducible factors over the integers modulo 2:

Wolfram Language code: FactorList[x ^ 4 + 1, Modulus -> 2]

The irreducible factors over a finite field:

Wolfram Language code: ℱ = FiniteField[17, 3];
Wolfram Language code: FactorList[ℱ[3]x ^ 2 + ℱ[1771]]
Wolfram Language code: FactorList[x ^ 3 + 5x + 19, Extension -> ℱ]

The irreducible factors over an extension of a finite field:

Wolfram Language code: ℱ = FiniteField[29, 3]; 𝒢 = FiniteField[29, 6]; ℰ = FiniteFieldEmbedding[ℱ, 𝒢];

A polynomial irreducible over factors after embedding in a larger field :

Wolfram Language code: FactorList[ℱ[12]x ^ 2 + ℱ[34]x + ℱ[56]]
Wolfram Language code: FactorList[ℱ[12]x ^ 2 + ℱ[34]x + ℱ[56], Extension -> ℰ]

List factors of non-polynomial expressions:

Wolfram Language code: FactorList[E ^ (2 x) - 2E ^ x + 1]
Wolfram Language code: FactorList[x ^ 2 - Sqrt[x]]

List factors of a polynomial of degree :

Wolfram Language code: rpoly[n_] := RandomInteger[{-2 ^ 10, 2 ^ 10}, {n + 1}].x ^ Range[0, n] SeedRandom[1234]; p = rpoly[1000]; q = rpoly[1000]; r = Expand[p q];
Wolfram Language code: (facs = FactorList[r]);//AbsoluteTiming
Wolfram Language code: {Exponent[#[[1]], x], #[[2]]}& /@ facs

Options  (7)

Extension  (4)

Factor over algebraic number fields:

Wolfram Language code: FactorList[1 + x ^ 4, Extension -> Sqrt[2]]
Wolfram Language code: FactorList[1 + x ^ 4, Extension -> {Sqrt[2], I}]

Extension->Automatic automatically extends to a field that covers the coefficients:

Wolfram Language code: FactorList[2 + 2Sqrt[2]x + x ^ 2]
Wolfram Language code: FactorList[2 + 2Sqrt[2]x + x ^ 2, Extension -> Automatic]

Factor a polynomial with integer coefficients over a finite field:

Wolfram Language code: ℱ = FiniteField[73, 3];
Wolfram Language code: FactorList[x ^ 3 + 21x + 3, Extension -> ℱ]

Factor a polynomial with coefficients in a finite field:

Wolfram Language code: ℱ = FiniteField[7, 2];
Wolfram Language code: FactorList[ℱ[1]x ^ 4 + ℱ[234]x + ℱ[567]]

Embedding in a larger field allows further factorization:

Wolfram Language code: 𝒢 = FiniteField[7, 4]; ℰ = FiniteFieldEmbedding[ℱ, 𝒢];
Wolfram Language code: FactorList[ℱ[1]x ^ 4 + ℱ[234]x + ℱ[567], Extension -> ℰ]

GaussianIntegers  (1)

Factor over Gaussian integers:

Wolfram Language code: FactorList[1 + x ^ 2, GaussianIntegers -> True]
Wolfram Language code: FactorList[1 + x ^ 2, Extension -> I]

Modulus  (1)

Factor over finite fields:

Wolfram Language code: FactorList[5 + x ^ 12]
Wolfram Language code: FactorList[5 + x ^ 12, Modulus -> 7]

Trig  (1)

Factor a trigonometric expression:

Wolfram Language code: FactorList[Sin[x] + Sin[y], Trig -> True]

Applications  (2)

FactorList can be useful in determining the behavior of functions:

Wolfram Language code: f = x ^ 3 - x ^ 2 - 16x - 20;
Wolfram Language code: FactorList[f]

has roots at and , at it does not cross the axis, and at it crosses the axis:

Wolfram Language code: Plot[-20 - 16 x - x^2 + x^3, {x, -4, 6}]

Show that a polynomial is a perfect square:

Wolfram Language code: f = 62500 - 112500 x + 15625 x^2 + 47500 x^3 - 3500 x^4 - 9380 x^5 - 1106 x^6 + 628 x^7 + 208 x^8 + 24 x^9 + x^10;

Compute the factors and note that the constant factor is positive:

Wolfram Language code: fac = FactorList[f]

Extract the exponents of nonconstant factors:

Wolfram Language code: exp = Transpose[Rest[fac]][[2]]

Check that every factor has even exponent and thus is a square:

Wolfram Language code: AllTrue[exp, EvenQ]

Properties & Relations  (3)

FactorList gives a list of irreducible factors:

Wolfram Language code: FactorList[x ^ 8 + 11x ^ 7 + 43x ^ 6 + 59x ^ 5 - 35x ^ 4 - 151x ^ 3 - 63x ^ 2 + 81x + 54]

This multiplies the factors together:

Wolfram Language code: Times@@Power@@@%

Factor gives a product of factors:

Wolfram Language code: Factor[x ^ 8 + 11x ^ 7 + 43x ^ 6 + 59x ^ 5 - 35x ^ 4 - 151x ^ 3 - 63x ^ 2 + 81x + 54]

Expand combines all the factors back together:

Wolfram Language code: Expand[%]

FactorSquareFreeList gives a list of square-free factors:

Wolfram Language code: FactorSquareFreeList[x ^ 8 + 11x ^ 7 + 43x ^ 6 + 59x ^ 5 - 35x ^ 4 - 151x ^ 3 - 63x ^ 2 + 81x + 54]

FactorInteger gives a list of prime factors of an integer:

Wolfram Language code: FactorInteger[1234567]
Wolfram Language code: Times@@Power@@@%
Wolfram Research (1988), FactorList, Wolfram Language function, https://reference.wolfram.com/language/ref/FactorList.html (updated 2023).

Text

Wolfram Research (1988), FactorList, Wolfram Language function, https://reference.wolfram.com/language/ref/FactorList.html (updated 2023).

CMS

Wolfram Language. 1988. "FactorList." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2023. https://reference.wolfram.com/language/ref/FactorList.html.

APA

Wolfram Language. (1988). FactorList. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/FactorList.html

BibTeX

@misc{reference.wolfram_2026_factorlist, author="Wolfram Research", title="{FactorList}", year="2023", howpublished="\url{https://reference.wolfram.com/language/ref/FactorList.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_factorlist, organization={Wolfram Research}, title={FactorList}, year={2023}, url={https://reference.wolfram.com/language/ref/FactorList.html}, note=[Accessed: 13-June-2026]}