WOLFRAM

Wolfram Language & System Documentation Center

FindSequenceFunction[{a1,a2,a3,…}]

attempts to find a simple function that yields the sequence an when given successive integer arguments.

FindSequenceFunction[{{n1,a1},{n2,a2},…}]

attempts to find a simple function that yields ai when given argument ni.

FindSequenceFunction[n1a1,n2a2,…]

gives a function that yields ai when given argument ni.

FindSequenceFunction[{n1a1,n2a2,…}]

gives a function that yields ai when given argument ni.

FindSequenceFunction[list,n]

gives the function applied to n.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Generalizations & Extensions  
Applications  
Properties & Relations  
See Also
Related Guides
Related Links
History
Cite this Page

FindSequenceFunction

FindSequenceFunction[{a1,a2,a3,…}]

attempts to find a simple function that yields the sequence an when given successive integer arguments.

FindSequenceFunction[{{n1,a1},{n2,a2},…}]

attempts to find a simple function that yields ai when given argument ni.

FindSequenceFunction[n1a1,n2a2,…]

gives a function that yields ai when given argument ni.

FindSequenceFunction[{n1a1,n2a2,…}]

gives a function that yields ai when given argument ni.

FindSequenceFunction[list,n]

gives the function applied to n.

Details and Options

  • The sequence elements an can be either exact numbers or symbolic expressions.
  • FindSequenceFunction finds results in terms of a wide range of integer functions, as well as implicit solutions to difference equations represented by DifferenceRoot.
  • If FindSequenceFunction cannot find a simple function that yields the specified sequence, it returns unevaluated.
  • The following options can be used:
  • FunctionSpaceAutomaticwhere to look for candidate simple functions
    MethodAutomaticmethod to use
    TimeConstraint10how many seconds to search a particular function space or perform a transformation
    ValidationLengthAutomaticsequence length used to validate a candidate function found
  • FindSequenceFunction[list] by default uses earlier elements in list to find candidate simple functions, then validates the functions by looking at later elements.
  • FindSequenceFunction[list] only returns functions that correctly reproduce all elements of list.

Examples

open all close all

Basic Examples  (2)

Find a function that yields the sequence 1, 1, 2, 3, 5, 8, 13, …:

Wolfram Language code: FindSequenceFunction[{1, 1, 2, 3, 5, 8, 13}, n]
Wolfram Language code: Table[Fibonacci[n], {n, 7}]

Find a function that yields the given sequence as a subsequence:

Wolfram Language code: Table[{2n, 2 ^ n}, {n, 8}]
Wolfram Language code: FindSequenceFunction[Table[{2n, 2 ^ n}, {n, 10}], n]

Check the even subsequence:

Wolfram Language code: Table[{n, %}, {n, 2, 16, 2}]

Scope  (5)

Periodic sequences:

Wolfram Language code: FindSequenceFunction[{-1, 1, -1, 1, -1, 1}, n]

Polynomial functions:

Wolfram Language code: FindSequenceFunction[{2, 5, 10, 17, 26, 37, 50}, n]

Rational functions:

Wolfram Language code: FindSequenceFunction[{2, 5 / 2, 10 / 3, 17 / 4, 26 / 5, 37 / 6, 50 / 7}, n]

Hypergeometric terms:

Wolfram Language code: FindSequenceFunction[{1, 2, 6, 24, 120, 720, 5040}, n]

Recurrence equations:

Wolfram Language code: FindSequenceFunction[{2, 3 / 2, 7 / 3, 13 / 4, 26 / 5, 49 / 6, 92 / 7, 169 / 8, 307 / 9, 551 / 10, 980 / 11, 1729 / 12, 3030 / 13, 5279 / 14, 9151 / 15, 15793 / 16, 27150 / 17, 46513 / 18}, n]

Generalizations & Extensions  (1)

FindSequenceFunction works on arbitrary exact numbers or symbolic expressions:

Wolfram Language code: FindSequenceFunction[{1 + E, Sqrt[2] + E, 2 + E, 2Sqrt[2] + E, 4 + E}, n]//FullSimplify
Wolfram Language code: FindSequenceFunction[{1 + a, 1 + a ^ 2, 1 + a ^ 3, 1 + a ^ 4, 1 + a ^ 5}, n]

Applications  (6)

Find formulas for complex sequences:

Wolfram Language code: Table[Det[HilbertMatrix[n]], {n, 10}]
Wolfram Language code: f = FindSequenceFunction[%, n]

Use additional values to validate the result:

Wolfram Language code: Table[Det[HilbertMatrix[n]], {n, 10, 50}] - Table[f, {n, 10, 50}]

Find a closed form for a sequence of definite integrals:

Wolfram Language code: Table[Integrate[x ^ n(1 - 2x) ^ n, {x, 0, 1}], {n, 10}]
Wolfram Language code: FindSequenceFunction[%, n]

Find a closed form for the number of 0,1 sequences of length containing two adjacent 1s:

Wolfram Language code: Table[Count[Tuples[{1, 0}, n], {___, 1, 1, ___}], {n, 10}]
Wolfram Language code: FindSequenceFunction[%, n]//FullSimplify

Generate a sequence from a power series expansion:

Wolfram Language code: CoefficientList[Series[Exp[x ^ 2], {x, 0, 20}], x]

Find its formula:

Wolfram Language code: s1 = FindSequenceFunction[%, n]

Use SeriesCoefficient to find an alternative formula:

Wolfram Language code: s2 = SeriesCoefficient[Exp[x ^ 2], {x, 0, n}]

FindSequenceFunction assumes that sequences start with index 1:

Wolfram Language code: s1 = s1 /. n -> n + 1

Compare the result:

Wolfram Language code: Table[s1 - s2, {n, 0, 20}]

Compute a finite number of Fourier coefficients:

Wolfram Language code: Table[FourierCoefficient[SquareWave[x / (2Pi)], x, n], {n, 1, 10}]

Find the formula:

Wolfram Language code: FindSequenceFunction[%, n]

Use a FourierCoefficient directly:

Wolfram Language code: FourierCoefficient[SquareWave[x / (2Pi)], x, n]

Verify the consistency of formulas:

Wolfram Language code: Simplify[%% - %, n∈Integers && n > 0]

Construct the Cantor set by starting with a {0,1} interval and removing the middle third of each interval in each step:

Wolfram Language code: cantor = {a_, b_} :> {{a, a + (b - a) / 3}, {a + (b - a)2 / 3, b}};
Wolfram Language code: CantorRegion[n_Integer ? NonNegative] := Interval@@Nest[Flatten[Map[Function[s, s /. cantor], #], 1]&, {{0, 1}}, n]

Some steps:

Wolfram Language code: CantorRegion[1]
Wolfram Language code: CantorRegion[2]
Wolfram Language code: NumberLinePlot[Table[CantorRegion[i], {i, 3}], PlotRange -> {{0, 1}, Automatic}]

Find the length of the region:

Wolfram Language code: Table[RegionMeasure[CantorRegion[i]], {i, 5}]

Find a formula for the sequence of lengths using FindSequenceFunction:

Wolfram Language code: FindSequenceFunction[%, n]

Properties & Relations  (2)

Sum, Product, and other general discrete functions may be used:

Wolfram Language code: FindSequenceFunction[{1, 2, 3, 5, 17, 305, 34865, 24918065, 125436246065, 5056710181206065}, n]

Find the generating function of a sequence:

Wolfram Language code: FindSequenceFunction[{3, 7, 13, 21, 31, 43, 57}, n]
Wolfram Language code: GeneratingFunction[% /. n -> n + 1, n, x]

Use FindGeneratingFunction:

Wolfram Language code: FindGeneratingFunction[{3, 7, 13, 21, 31, 43, 57}, x]//Together
Wolfram Research (2008), FindSequenceFunction, Wolfram Language function, https://reference.wolfram.com/language/ref/FindSequenceFunction.html (updated 2015).

Text

Wolfram Research (2008), FindSequenceFunction, Wolfram Language function, https://reference.wolfram.com/language/ref/FindSequenceFunction.html (updated 2015).

CMS

Wolfram Language. 2008. "FindSequenceFunction." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2015. https://reference.wolfram.com/language/ref/FindSequenceFunction.html.

APA

Wolfram Language. (2008). FindSequenceFunction. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/FindSequenceFunction.html

BibTeX

@misc{reference.wolfram_2026_findsequencefunction, author="Wolfram Research", title="{FindSequenceFunction}", year="2015", howpublished="\url{https://reference.wolfram.com/language/ref/FindSequenceFunction.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_findsequencefunction, organization={Wolfram Research}, title={FindSequenceFunction}, year={2015}, url={https://reference.wolfram.com/language/ref/FindSequenceFunction.html}, note=[Accessed: 13-June-2026]}