WOLFRAM

Wolfram Language & System Documentation Center

FrequencySamplingFilterKernel[{a1,…,ak}]

creates a finite impulse response (FIR) filter kernel using a frequency sampling method from amplitude values ai.

FrequencySamplingFilterKernel[{a1,…,ak},m]

creates an FIR filter kernel of type m.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Options  
"Shifted"  
WorkingPrecision  
Applications  
Properties & Relations  
See Also
Related Guides
History
Cite this Page

FrequencySamplingFilterKernel

FrequencySamplingFilterKernel[{a1,…,ak}]

creates a finite impulse response (FIR) filter kernel using a frequency sampling method from amplitude values ai.

FrequencySamplingFilterKernel[{a1,…,ak},m]

creates an FIR filter kernel of type m.

Details and Options

  • Possible types m for FIR filters created for a list {a1,a2,…,ak} of amplitudes are:
  • The default type is .
  • The frequency sampling method uniformly samples the frequency domain from 0 to .
  • FrequencySamplingFilterKernel by default uses a sampling of the frequency domain at integer multiples of , where is the length of the filter. With "Shifted"->True, the frequencies are shifted from 0 by . »
  • Amplitude values should be non-negative. Typically, values ai=0 specify a stopband, and values ai=1 specify a passband.
  • The kernel ker returned by FrequencySamplingFilterKernel can be used in ListConvolve[ker,data] to apply the filter to data.
  • The following options can be given:
  • "Shifted" Falsewhether the first frequency is offset from 0
    WorkingPrecision MachinePrecisionprecision to use in internal computations

Examples

open all close all

Basic Examples  (1)

A lowpass FIR filter:

Wolfram Language code: h = FrequencySamplingFilterKernel[{1, 1, 1, 0, 0, 0, 0}]

Magnitude response of the filter:

Wolfram Language code: Plot[Abs[ListFourierSequenceTransform[h, ω]], {ω, 0, π}, PlotRange -> All]

Scope  (7)

A type 1 FIR kernel with even symmetry and odd length:

Wolfram Language code: h = FrequencySamplingFilterKernel[{1, 1, 1, 0, 0, 0}, 1]
Wolfram Language code: Plot[Abs[ListFourierSequenceTransform[h, ω]], {ω, 0, π}]

A type 2 FIR kernel with even symmetry and even length:

Wolfram Language code: h = FrequencySamplingFilterKernel[{1, 1, 1, 0, 0, 0}, 2]
Wolfram Language code: Plot[Abs[ListFourierSequenceTransform[h, ω]], {ω, 0, π}]

An odd-symmetry odd-length (type 3) bandpass kernel:

Wolfram Language code: h = FrequencySamplingFilterKernel[{0, 0, 1, 1, 0, 0}, 3]
Wolfram Language code: Plot[Abs[ListFourierSequenceTransform[h, ω]], {ω, 0, π}, PlotRange -> All]

An odd-symmetry even-length (type 4) highpass kernel:

Wolfram Language code: h = FrequencySamplingFilterKernel[{0, 0, 0, 1, 1, 1}, 4]
Wolfram Language code: Plot[Abs[ListFourierSequenceTransform[h, ω]], {ω, 0, π}]

A full-band differentiator FIR kernel:

Wolfram Language code: h = FrequencySamplingFilterKernel[(Range[4] - 1 / 2) / 4, 4, "Shifted" -> True]; Plot[Abs[ListFourierSequenceTransform[h, ω]], {ω, 0, π}]

Create a filter from a random list of amplitude values:

Wolfram Language code: a = RandomReal[1, 6]
Wolfram Language code: h = FrequencySamplingFilterKernel[a, 1]; Plot[Abs[ListFourierSequenceTransform[h, ω]], {ω, 0, π}, PlotRange -> All]

Create a filter from an arbitrary function:

Wolfram Language code: a = Table[1 / 2(Cos[x] + 1), {x, 0, π, π / 5}]//N
Wolfram Language code: h = FrequencySamplingFilterKernel[a, 1]; Plot[Abs[ListFourierSequenceTransform[h, ω]], {ω, 0, π}, PlotRange -> All]

Options  (2)

"Shifted"  (1)

By default, first frequency is sampled at 0:

Wolfram Language code: a = FrequencySamplingFilterKernel[{1, 1, 0, 0}]
Wolfram Language code: Show[Plot[Abs[ListFourierSequenceTransform[a, x]], {x, 0, π}, PlotRange -> All], ListPlot[{{(0Pi / 14), 1}, {(4Pi / 14), 1}, {(8Pi / 14), 0}, {12Pi / 14, 0}}, Filling -> 0, PlotStyle -> {Red, PointSize[Large]}]]

With "Shifted"->True, first frequency is offset from 0 by :

Wolfram Language code: a = FrequencySamplingFilterKernel[{1, 1, 0, 0}, "Shifted" -> True]
Wolfram Language code: Show[Plot[Abs[ListFourierSequenceTransform[a, x]], {x, 0, π}, PlotRange -> All], ListPlot[{{(2Pi / 14), 1}, {(6Pi / 14), 1}, {(10Pi / 14), 0}, {Pi, 0}}, Filling -> 0, PlotStyle -> {Red, PointSize[Large]}]]

WorkingPrecision  (1)

By default, MachinePrecision is used:

Wolfram Language code: h = FrequencySamplingFilterKernel[{1, 1, 1, 1, 0, 0, 0, 0}]

Use 2-digit precision arithmetic:

Wolfram Language code: g = Rationalize[#, 0]& /@ FrequencySamplingFilterKernel[{1, 1, 1, 1, 0, 0, 0, 0}, WorkingPrecision -> 2]

Compare the two results:

Wolfram Language code: Plot[Evaluate[{Abs[ListFourierSequenceTransform[h, x]], Abs[ListFourierSequenceTransform[g, x]]}], {x, 0, π}, PlotRange -> All]

Applications  (2)

Smooth data by convolving it with a lowpass filter kernel:

Wolfram Language code: data = Table[ Sin[x] + RandomReal[.2], {x, 0, 2 Pi, 0.05}]; ker = FrequencySamplingFilterKernel[{1, 1, 0, 0, 0, 0, 0}]; ListLinePlot /@ {data, ListConvolve[ker, data, 7]}

Apply a derivative filter to rows of an image:

Wolfram Language code: a = FrequencySamplingFilterKernel[{(1/8), (3/8), (5/8), (7/8)}, 4, "Shifted" -> True]; ImageConvolve[[image], {a}]//ImageAdjust

Properties & Relations  (1)

Apply a window to an FIR filter to reduce ripple in its magnitude response:

Wolfram Language code: fir = FrequencySamplingFilterKernel[{1, 1, 1, 0, 0, 0}]
Wolfram Language code: win = Array[BlackmanWindow, Length[fir], {-1 / 2, 1 / 2}];
Wolfram Language code: Plot[Evaluate[Abs[ListFourierSequenceTransform[#, x]]& /@ {fir, win fir}], {x, 0, π}]
Wolfram Research (2012), FrequencySamplingFilterKernel, Wolfram Language function, https://reference.wolfram.com/language/ref/FrequencySamplingFilterKernel.html.

Text

Wolfram Research (2012), FrequencySamplingFilterKernel, Wolfram Language function, https://reference.wolfram.com/language/ref/FrequencySamplingFilterKernel.html.

CMS

Wolfram Language. 2012. "FrequencySamplingFilterKernel." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/FrequencySamplingFilterKernel.html.

APA

Wolfram Language. (2012). FrequencySamplingFilterKernel. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/FrequencySamplingFilterKernel.html

BibTeX

@misc{reference.wolfram_2026_frequencysamplingfilterkernel, author="Wolfram Research", title="{FrequencySamplingFilterKernel}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/FrequencySamplingFilterKernel.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_frequencysamplingfilterkernel, organization={Wolfram Research}, title={FrequencySamplingFilterKernel}, year={2012}, url={https://reference.wolfram.com/language/ref/FrequencySamplingFilterKernel.html}, note=[Accessed: 13-June-2026]}