FullMoon
Details and Options
- The instant of full moon is defined by the opposition of the Moon and the Sun in ecliptic longitude.
- In FullMoon[date], date can be any DateObject expression.
- Options of FullMoon include:
-
CalendarType Automatic calendar used to return dates DateFormat Automatic format used to display output dates DateGranularity Automatic calendar granularity of output dates Method "EclipticLongitude" method to define moon phases TimeDirection 1 whether to return the next or last full moon TimeSystem Automatic time system of output dates TimeZone $TimeZone time zone of output dates - Possible settings for the Method option include:
-
"Illumination" phase defined by fraction of illumination of the Moon "EclipticLongitude" phase defined by Moon‐Sun ecliptic longitude difference
Examples
open all close allBasic Examples (2)
Scope (3)
FullMoon[]Find the next full moon after a given date:
FullMoon[DateObject[{2024, 3, 21}]]Find full moons very far in the past:
FullMoon[DateObject[{-10000, 1, 1}]]Find full moons very far in the future:
FullMoon[DateObject[{10000, 1, 1}]]Options (7)
CalendarType (1)
FullMoon returns dates in the Gregorian calendar by default:
FullMoon[]Return dates in the Jewish calendar:
FullMoon[CalendarType -> "Jewish"]DateFormat (1)
FullMoon returns dates in a long format by default:
FullMoon[]FullMoon[DateFormat -> {"Day", "/", "Month", "/", "Year"}]DateGranularity (1)
FullMoon returns dates with granularity "Instant" by default:
FullMoon[]Return dates with "Day" granularity:
FullMoon[DateGranularity -> "Day"]Method (1)
FullMoon uses differences of ecliptic longitudes between the Sun and the Moon by default:
FullMoon[]FullMoon[Method -> "EclipticLongitude"]Use the minimum value of illumination to define the instant of new moon instead:
FullMoon[Method -> "Illumination"]TimeDirection (1)
FullMoon finds the next full moon by default:
FullMoon[]FullMoon[TimeDirection -> -1]TimeSystem (1)
FullMoon returns dates in universal time by default:
FullMoon[]Return dates in "TT" time instead:
FullMoon[TimeSystem -> "TT"]TimeZone (1)
FullMoon returns dates in your local time zone by default:
FullMoon[]Return dates in the GMT time zone:
FullMoon[TimeZone -> "GMT"]Applications (1)
A full moon occurring near perigee, i.e. when the Moon is closest to Earth, is known as a supermoon.
Define a function computing the distance from the Earth to the Moon in kilometers:
distanceMoon[year_ ? NumericQ] := QuantityMagnitude[AstroDistance["Moon", Dated["Earth", year]], "Kilometers"]Find all the full moons between years 2023 and 2026:
fullmoons = Rest@NestList[FullMoon[# + Quantity[1, "Days"]]&, DateObject[{2023, 1, 1}], 38];Plot distances during that period and mark the full moons as purple points:
Plot[distanceMoon[year], {year, 2023, 2026}, AspectRatio -> 1 / 6, Epilog -> {Orange, Line[{{2023, 360000}, {2026, 360000}}], Purple, PointSize[Large], Point[{#, distanceMoon[#]}]& /@ DateValue[fullmoons, "YearExact"]}]The full moons occurring at smaller distances from Earth, say under 360,000 km, are the supermoons:
Select[fullmoons, AstroDistance["Moon", Dated["Earth", #]] < Quantity[360000, "Kilometers"]&]Properties & Relations (9)
At the instant of full moon, the Moon and the Sun have opposite ecliptic longitudes:
date = FullMoon[]AstroPosition[Entity["Star", "Sun"], {"Ecliptic", date}]AstroPosition[Entity["PlanetaryMoon", "Moon"], {"Ecliptic", date}]fullmoons = NestList[FullMoon[# + Quantity[1, "Days"]]&, FullMoon[], 19]The distance between full moons varies between 29.26 and 29.80 days:
luns = Differences[fullmoons]ListPlot[luns]The average synodic month is about 29.53 days:
MeanAround[luns]UnitConvert[Quantity[1, "SynodicMonths"], "Days"]FullMoon returns the date of the next full moon:
FullMoon[]Use NewMoon to find the date of the next new moon, which may be before or after that full moon:
NewMoon[]Use MoonPhaseDate to find the date of any phase of the Moon:
MoonPhaseDate["FirstQuarter"]MoonPhase computes the phase fraction of illumination, which is close to 1 for a full moon:
date = DateObject[{2025, 1, 1}];fullmoon = FullMoon[date]MoonPhase[fullmoon]The maximum of illumination is given by this alternative method of computation:
fullmoon0 = FullMoon[date, Method -> "Illumination"]MoonPhase[fullmoon0]This curve represents fraction of illumination for an hour around the maximum, with fullmoon in red:
Plot[MoonPhase[fullmoon0 + Quantity[m, "Minutes"]], {m, -30, 30}, GridLines -> {{QuantityMagnitude[fullmoon - fullmoon0, "Minutes"]}}, GridLinesStyle -> Red]Full moons correspond to semi-integer lunation numbers:
FullMoon[]LunationNumber[%]Therefore, an alternative way of finding full moons is calling FromLunationNumber with semi-integers:
FromLunationNumber[%]FullMoon[date] is equivalent to FindAstroEvent["FullMoon",date]:
FullMoon[]FindAstroEvent["FullMoon"]FullMoon defines Moon phases as observed from Earth's center:
FullMoon[]This is also the default in FindAstroEvent:
FindAstroEvent["FullMoon"]FindAstroEvent will take parallax effects into account if an observer location is specified:
FindAstroEvent["FullMoon", Now, Entity["City", {"LosAngeles", "California", "UnitedStates"}]]Full moons are oppositions of the Moon with respect to the Sun, as observed from the center of the Earth:
FullMoon[]FindAstroEvent[{"Opposition", "Moon", "Sun"}]Every lunar eclipse happens within a few minutes of a full moon:
LunarEclipse[]{FullMoon[%, TimeDirection -> -1], FullMoon[%, TimeDirection -> 1]}Only some of the 12 or 13 full moons in a year are close to lunar eclipses:
LunarEclipse[{FullMoon[DateObject[{2020, 1, 1}]], FullMoon[DateObject[{2021, 1, 1}]], All}]Text
Wolfram Research (2024), FullMoon, Wolfram Language function, https://reference.wolfram.com/language/ref/FullMoon.html (updated 2025).
CMS
Wolfram Language. 2024. "FullMoon." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2025. https://reference.wolfram.com/language/ref/FullMoon.html.
APA
Wolfram Language. (2024). FullMoon. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/FullMoon.html