Wolfram Language & System Documentation Center

FunctionConvexity

finds the convexity of the function f with variables x₁,x₂,… over the reals.

FunctionConvexity[{f,cons},{x₁,x₂,…}]

finds the convexity when variables are restricted by the constraints cons representing a convex region.

Details and Options

Convexity is also known as convex, concave, strictly convex and strictly concave.
By default, the following definitions are used:

		+1	convex, i.e. for all and all and
		0	affine , i.e. for all and all and
		-1	concave, i.e. for all and all and
		Indeterminate	neither convex nor concave

The affine function is both convex and concave.
With the setting StrictInequalitiesTrue, the following definitions are used:

		+1	strictly convex, i.e. for all and all and with
		-1	strictly concave, i.e. for all and all and and
		Indeterminate	neither strictly convex nor strictly concave

The function should be a real-valued function for all real that satisfy the constraints cons.
cons can contain equations, inequalities or logical combinations of these representing a convex region.
The following options can be given:

Assumptions	$Assumptions	assumptions on parameters
GenerateConditions	Automatic	whether to generate conditions on parameters
PerformanceGoal	$PerformanceGoal	whether to prioritize speed or quality
StrictInequalities	False	whether to require strict convexity

Possible settings for GenerateConditions include:
Automatic nongeneric conditions only

True all conditions

False no conditions

None return unevaluated if conditions are needed
Possible settings for PerformanceGoal are "Speed" and "Quality".

Examples

open all close all

Basic Examples (3)

Find the convexity of a univariate function:

Wolfram Language code: FunctionConvexity[Abs[x], x]

Find the convexity of a multivariate function:

Wolfram Language code: FunctionConvexity[-Exp[x + y], {x, y}]

Find the convexity of a function with variables restricted by constraints:

Wolfram Language code: FunctionConvexity[{x ^ 3 + y ^ 3, x ≥ 0 && y ≥ 0}, {x, y}]

Scope (7)

Univariate functions:

Wolfram Language code: FunctionConvexity[Sin[x], x]

Wolfram Language code: FunctionConvexity[2 ^ x, x]

Wolfram Language code: FunctionConvexity[x - Sqrt[x ^ 2], x]

Wolfram Language code: Plot[{Sin[x], 2 ^ x, x - Sqrt[x ^ 2]}, {x, -3, 3}]

A function that is not real valued has Indeterminate convexity:

Wolfram Language code: FunctionConvexity[Log[x], x]

The function is real valued and concave for positive :

Wolfram Language code: FunctionConvexity[{Log[x], x > 0}, x]

Univariate functions with constraints on the variable:

Wolfram Language code: FunctionConvexity[{Sin[x], 0 ≤ x ≤ Pi}, x]

Wolfram Language code: FunctionSign[{x - Sqrt[x ^ 2], x ≥ 0}, x]

The strict convexity of a function:

Wolfram Language code: FunctionConvexity[Abs[x], x, StrictInequalities -> True]

Wolfram Language code: FunctionConvexity[x ^ 2 Abs[x], x, StrictInequalities -> True]

is convex, but not strictly convex. $x^2 TemplateBox[{x}, Abs]$ is strictly convex:

Wolfram Language code: Plot[{Abs[x], x ^ 2Abs[x]}, {x, -2, 2}]

Multivariate functions:

Wolfram Language code: FunctionConvexity[x ^ 2 + y ^ 2, {x, y}]

Wolfram Language code: Plot3D[x ^ 2 + y ^ 2, {x, -2, 2}, {y, -2, 2}]

Wolfram Language code: FunctionConvexity[x ^ 2 - y ^ 2, {x, y}]

Wolfram Language code: Plot3D[x ^ 2 - y ^ 2, {x, -2, 2}, {y, -2, 2}]

Multivariate functions with constraints on variables:

Wolfram Language code: FunctionConvexity[{x ^ 3 + x ^ 2 y ^ 2 + y ^ 3, -2 < x < 2 && -2 < y < 2}, {x, y}]

Wolfram Language code: Plot3D[x ^ 3 + x ^ 2 y ^ 2 + y ^ 3, {x, -2, 2}, {y, -2, 2}]

In a different region, the same function is convex:

Wolfram Language code: FunctionConvexity[{x ^ 3 + x ^ 2 y ^ 2 + y ^ 3, 0 < x < 2 && y > 0}, {x, y}]

Wolfram Language code: Plot3D[x ^ 3 + x ^ 2 y ^ 2 + y ^ 3, {x, 0, 2}, {y, 0, 2}]

Functions with symbolic parameters:

Wolfram Language code: FunctionConvexity[a x ^ 2 + b x + c, x]

Wolfram Language code: FunctionConvexity[x ^ 2 + a x y + y ^ 2, {x, y}]

Options (5)

Assumptions (1)

FunctionConvexity gives a conditional answer here:

Wolfram Language code: FunctionConvexity[x ^ 4 + a x ^ 2, x]

Check convexity for other values of :

Wolfram Language code: FunctionConvexity[x ^ 4 + a x ^ 2, x, Assumptions -> a < 0]

GenerateConditions (2)

By default, FunctionConvexity may generate conditions on symbolic parameters:

Wolfram Language code: FunctionConvexity[a x ^ 2 + b y ^ 2, {x, y}]

With GenerateConditionsNone, FunctionConvexity fails instead of giving a conditional result:

Wolfram Language code: FunctionConvexity[a x ^ 2 + b y ^ 2, {x, y}, GenerateConditions -> None]

This returns a conditionally valid result without stating the condition:

Wolfram Language code: FunctionConvexity[a x ^ 2 + b y ^ 2, {x, y}, GenerateConditions -> False]

By default, all conditions are reported:

Wolfram Language code: FunctionConvexity[E ^ x / a ^ 2, x]

With GenerateConditionsAutomatic, conditions that are generically true are not reported:

Wolfram Language code: FunctionConvexity[E ^ x / a ^ 2, x, GenerateConditions -> Automatic]

PerformanceGoal (1)

Use PerformanceGoal to avoid potentially expensive computations:

Wolfram Language code: FunctionConvexity[x ^ 6 + a x ^ 2 y ^ 4 + b x ^ 4 y ^ 2 + y ^ 6, {x, y}, PerformanceGoal -> "Speed"]

The default setting uses all available techniques to try to produce a result:

Wolfram Language code: FunctionConvexity[x ^ 6 + a x ^ 2 y ^ 4 + b x ^ 4 y ^ 2 + y ^ 6, {x, y}]

StrictInequalities (1)

By default, FunctionConvexity computes the non-strict convexity:

Wolfram Language code: FunctionConvexity[#, {x, y}]& /@ {x ^ 2, x ^ 2 + y ^ 2}

With StrictInequalitiesTrue, FunctionConvexity computes the strict sign:

Wolfram Language code: FunctionConvexity[#, {x, y}, StrictInequalities -> True]& /@ {x ^ 2, x ^ 2 + y ^ 2}

is convex, but not strictly convex. is strictly convex:

Wolfram Language code: GraphicsRow[Plot3D[#, {x, -2, 2}, {y, -2, 2}]& /@ {x ^ 2, x ^ 2 + y ^ 2}, ImageSize -> 400]

Applications (17)

Basic Applications (8)

Check the convexity of :

Wolfram Language code: FunctionConvexity[x ^ 2 - 1, x]

The segment connecting any two points on the graph lies above the graph:

Wolfram Language code: Plot[x ^ 2 - 1, {x, -5, 5}, Rule[...]]

Check the convexity of :

Wolfram Language code: FunctionConvexity[x - E ^ x, x]

The segment connecting any two points on the graph lies below the graph:

Wolfram Language code: Plot[x - E ^ x, {x, -3, 3}, Rule[...]]

Check the convexity of :

Wolfram Language code: FunctionConvexity[Sin[x], x]

is neither a convex function nor a concave function:

Wolfram Language code: Plot[Sin[x], {x, -3Pi, 3Pi}, Rule[...]]

Show that restricted to is a strictly concave function:

Wolfram Language code: FunctionConvexity[{Sin[x], 0 ≤ x ≤ Pi}, x, StrictInequalities -> True]

is convex, but not strictly convex:

Wolfram Language code: FunctionConvexity[Abs[x], x]

Wolfram Language code: FunctionConvexity[Abs[x], x, StrictInequalities -> True]

Wolfram Language code: Plot[Abs[x], {x, -5, 5}, Rule[...]]

restricted to positive reals is an affine function:

Wolfram Language code: FunctionConvexity[{Abs[x], x > 0}, x]

is convex for , but not strictly convex:

Wolfram Language code: FunctionConvexity[Norm[{x, y}, p], {x, y}, Assumptions -> p ≥ 1]

Wolfram Language code: FunctionConvexity[Norm[{x, y, z}, Infinity], {x, y, z}]

Wolfram Language code: FunctionConvexity[Norm[{x, y}, p], {x, y}, Assumptions -> p ≥ 1, StrictInequalities -> True]

Wolfram Language code: Plot3D[{Norm[{x, y}, 1], Norm[{x, y}, 2], Norm[{x, y}, Infinity]}, ...]

The sum of functions with convexity has convexity :

Wolfram Language code:

f = x ^ 2 + Sin[x];
g = x Erf[x] + E ^ (-x ^ 2);

Wolfram Language code: FunctionConvexity[f, x]

Wolfram Language code: FunctionConvexity[g, x]

Wolfram Language code: FunctionConvexity[f + g, x]

Wolfram Language code: Plot[{f, g, f + g}, {x, -3, 3}]

The negation of a convex function is concave:

Wolfram Language code: f = E ^ (x ^ 2);

Wolfram Language code: FunctionConvexity[f, x]

Wolfram Language code: FunctionConvexity[-f, x]

Wolfram Language code: Plot[{f, -f}, {x, -2, 2}]

The maximum of convex functions is convex:

Wolfram Language code:

f = 3Abs[x];
g = E ^ x;

Wolfram Language code: FunctionConvexity[f, x]

Wolfram Language code: FunctionConvexity[g, x]

Wolfram Language code: FunctionConvexity[Max[f, g], x]

Wolfram Language code: Plot[{f, g, Max[f, g]}, {x, -2, 2}]

Affine functions are both convex and concave, hence their maximum is convex:

Wolfram Language code: aff = Table[RandomReal[{-1, 1}]x + RandomReal[{-1, 1}]y + RandomReal[], {10}];

Wolfram Language code: FunctionConvexity[Max@@aff, {x, y}]

Wolfram Language code: Plot3D[Evaluate[Max@@aff], {x, -1, 1}, {y, -1, 1}, Mesh -> None]

Minimum of affine functions is concave:

Wolfram Language code: FunctionConvexity[Min@@aff, {x, y}]

Wolfram Language code: Plot3D[Evaluate[Min@@aff], {x, -1, 1}, {y, -1, 1}, Mesh -> None]

A quadratic is convex iff is positive semidefinite:

Wolfram Language code:

Subscript[A, 1] = {{1, 2}, {3, 4}};
Subscript[f, 1] = {x, y}.Subscript[A, 1].{x, y};

Wolfram Language code: PositiveSemidefiniteMatrixQ[Subscript[A, 1]]

Wolfram Language code: FunctionConvexity[Subscript[f, 1], {x, y}]

Wolfram Language code: Plot3D[Subscript[f, 1], {x, -1, 1}, {y, -1, 1}, Mesh -> None]

Wolfram Language code:

Subscript[A, 2] = {{1, -2}, {3, 4}};
Subscript[f, 2] = {x, y}.Subscript[A, 2].{x, y};

Wolfram Language code: PositiveSemidefiniteMatrixQ[Subscript[A, 2]]

Wolfram Language code: FunctionConvexity[Subscript[f, 2], {x, y}]

Wolfram Language code: Plot3D[Subscript[f, 2], {x, -1, 1}, {y, -1, 1}, Mesh -> None]

Calculus (2)

If is non-decreasing, then is a convex function of :

Wolfram Language code: f = 5t + Cos[5t];

Wolfram Language code: FunctionMonotonicity[f, t]

Wolfram Language code: Plot[f, {t, -3, 3}]

Wolfram Language code: g = Integrate[f, {t, 0, x}]

Wolfram Language code: FunctionConvexity[g, x]

Wolfram Language code: Plot[g, {x, -3, 3}]

The derivative of a convex function is non-decreasing:

Wolfram Language code: f = E ^ -x + 25x ^ 2 + Sin[5x] - 100;

Wolfram Language code: FunctionConvexity[f, x]

Wolfram Language code: df = D[f, x]

Wolfram Language code: FunctionMonotonicity[df, x]

The second derivative of a convex function is non-negative:

Wolfram Language code: ddf = D[df, x]

Wolfram Language code: FunctionSign[ddf, x]

Wolfram Language code: Plot[{f, df, ddf}, {x, -5, 5}]

Geometry (4)

If is a convex function $TemplateBox[{}, Reals]^n->TemplateBox[{}, Reals]$ , then the region ${x in TemplateBox[{}, Reals]^n|f(x)<=c}$ is convex:

Wolfram Language code: f = Log[3 ^ (x + 2 y) + Exp[y + z]] + x ^ 2 + y ^ 2 + z ^ 2;

Wolfram Language code: FunctionConvexity[f, {x, y, z}]

Use ConvexRegionQ to verify that is a convex region:

Wolfram Language code: reg = ImplicitRegion@@{f ≤ 1, {x, y, z}};

Wolfram Language code: ConvexRegionQ[reg]

Wolfram Language code: RegionPlot3D[f ≤ 1, ...]

If is a concave function $TemplateBox[{}, Reals]^n->TemplateBox[{}, Reals]$ , then the region ${x in TemplateBox[{}, Reals]^n|f(x)>=c}$ is convex:

Wolfram Language code: f = 3 - Exp[Norm[{x, y}, 3]];

Wolfram Language code: FunctionConvexity[f, {x, y}]

Use ConvexRegionQ to verify that is a convex region:

Wolfram Language code: reg = ImplicitRegion@@{f ≥ 1, {x, y}};

Wolfram Language code: ConvexRegionQ[reg]

Wolfram Language code: RegionPlot[f ≥ 1, {x, -1, 1}, {y, -1, 1}]

If is a convex function, then the epigraph is a convex set:

Wolfram Language code: f = Cosh[x];

Wolfram Language code: FunctionConvexity[f, x]

Use ConvexRegionQ to verify that is a convex region:

Wolfram Language code: reg = ImplicitRegion@@{f ≤ y, {x, y}};

Wolfram Language code: ConvexRegionQ[reg]

Wolfram Language code: Plot[f, {x, -2, 2}, Filling -> Top]

If is a concave function, then the hypograph is a convex set:

Wolfram Language code: f = Log[x];

Wolfram Language code: FunctionConvexity[{f, x > 0}, x]

The region is convex:

Wolfram Language code: Plot[f, {x, 0, 2}, Filling -> Bottom]

Optimization (3)

A local minimum of a convex function is a global minimum:

Wolfram Language code: f = Ramp[x];

Wolfram Language code: FunctionConvexity[f, x]

The set of local and global minima is the non-positive half-line:

Wolfram Language code: Plot[f, {x, -1, 1}]

A strictly convex function has at most one local minimum:

Wolfram Language code: f = (x - 3y - 7) ^ 2 + (x + y - 5) ^ 2 + (2x - 3y - 4) ^ 2;

Wolfram Language code: FunctionConvexity[f, {x, y}, StrictInequalities -> True]

Wolfram Language code: {mval, mpoint} = Minimize[f, {x, y}]

Wolfram Language code:

Show[{Plot3D[{f, mval}, {x, -5, 5}, {y, -5, 5}, PlotStyle -> Opacity[0.7]], Graphics3D[{Red, PointSize[Large], Point[{x, y, mval} /. mpoint]}]}]

A strictly convex function may have no local minima:

Wolfram Language code: f = Exp[x] + Exp[y];

Wolfram Language code: FunctionConvexity[f, {x, y}, StrictInequalities -> True]

Wolfram Language code: Minimize[f, {x, y}]

Wolfram Language code: Plot3D[f, {x, -3, 3}, {y, -3, 3}]

Properties & Relations (2)

Sum and Max of convex functions are convex:

Wolfram Language code:

f = (Abs[x] ^ 3 + Abs[y] ^ 3) ^ (1 / 3);
g = Log[E ^ x + E ^ y];

Wolfram Language code: FunctionConvexity[#, {x, y}]& /@ {f, g, f + g, Max[f, g]}

Wolfram Language code: GraphicsGrid[Map[Plot3D[#, {x, -2, 2}, {y, -2, 2}]&, {{f, g}, {f + g, Max[f, g]}}, {2}], ImageSize -> 400]

The second derivative of a convex function is non-negative:

Wolfram Language code: f = x ^ 4 - 12x Cos[x] - 4x ^ 2 Sin[x] + 12Sin[x]

Wolfram Language code: FunctionConvexity[f, x]

Use D to compute the derivative:

Wolfram Language code: g = D[f, {x, 2}]

Use FunctionSign to verify that the derivative is non-negative:

Wolfram Language code: FunctionSign[g, x]

Plot the function and the derivative:

Wolfram Language code: Plot[{f, g}, {x, -7, 7}]

Top

More Learning

Tech Support

Wolfram Solutions

Wolfram Solutions For Education

Get Started

Grow Your Skills

Work with Us

Educational Programs for Adults

Educational Programs for Youth

Read

FunctionConvexity

Details and Options

Examples

Basic Examples (3)

Scope (7)

Options (5)

Assumptions (1)

GenerateConditions (2)

PerformanceGoal (1)

StrictInequalities (1)

Applications (17)

Basic Applications (8)

Calculus (2)

Geometry (4)

Optimization (3)

Properties & Relations (2)

Text

CMS

APA

BibTeX

BibLaTeX

FunctionConvexity

Details and Options

Examples

Basic Examples (3)

Scope (7)

Options (5)

Assumptions (1)

GenerateConditions (2)

PerformanceGoal (1)

StrictInequalities (1)

Applications (17)

Basic Applications (8)

Calculus (2)

Geometry (4)

Optimization (3)

Properties & Relations (2)

See Also

Related Guides

History

Text

CMS

APA

BibTeX

BibLaTeX