WOLFRAM

Wolfram Language & System Documentation Center

GeoLength[g]

gives the length of the geo path g.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Generalizations & Extensions  
Options  
UnitSystem  
GeoModel  
Applications  
Properties & Relations  
See Also
Tech Notes
Related Guides
Related Links
History
Cite this Page

GeoLength

GeoLength[g]

gives the length of the geo path g.

Details and Options

Examples

open all close all

Basic Examples  (4)

Compute the total length of a geo path on the Earth:

Wolfram Language code: GeoLength[GeoPath[{Entity["City", {"NewYork", "NewYork", "UnitedStates"}], Entity["City", {"Chicago", "Illinois", "UnitedStates"}], Entity["City", {"Toronto", "Ontario", "Canada"}]}]]

Compute the total length of a path formed by geodesic segments:

Wolfram Language code: GeoLength[GeoPath[{{0, 0}, {0, 40}, {40, 70}}]]

Compute the total length of the rhumb lines joining the same points:

Wolfram Language code: GeoLength[GeoPath[{{0, 0}, {0, 40}, {40, 70}}, "RhumbLine"]]

Length of the Earth's equator:

Wolfram Language code: GeoLength[GeoPath["Equator"]]

Length of a full meridian:

Wolfram Language code: 2GeoLength[GeoPath["PrimeMeridian"]]

Compute the perimeter of a geo disk:

Wolfram Language code: GeoLength[GeoCircle[Entity["City", {"London", "GreaterLondon", "UnitedKingdom"}], Quantity[500, "Miles"]]]

Scope  (3)

Compute the length of different one-dimensional geo elements:

Wolfram Language code: GeoLength[GeoPath[{{0, 0}, {40, 30}, {20, -10}}]]
Wolfram Language code: GeoLength[GeoCircle[{0, 0}, Quantity[500, "Miles"]]]
Wolfram Language code: GeoLength[DayNightTerminator[DateObject[{2015, 12, 21}]]]
Wolfram Language code: GeoLength[GeoHemisphereBoundary[Here]]

Length of the perimeter of a region with holes, as a single joined object:

Wolfram Language code: outer = GeoPath[{{0, 0}, {40, 0}, {40, 100}, {0, 100}, {0, 0}}]; inner1 = GeoPath[{{10, 10}, {30, 10}, {30, 40}, {10, 40}, {10, 10}}]; inner2 = GeoPath[{{10, 60}, {30, 60}, {30, 90}, {10, 90}, {10, 60}}];
Wolfram Language code: g = JoinedCurve[{{outer}, {inner1}, {inner2}}];
Wolfram Language code: GeoGraphics[{Red, g}]
Wolfram Language code: GeoLength[g]

It can also be obtained by adding the lengths of the outer and inner curves:

Wolfram Language code: GeoLength[outer] + GeoLength[inner1] + GeoLength[inner2]

Paths of different types can be combined with GeoGroup:

Wolfram Language code: g1 = GeoCircle[Entity["City", {"NewYork", "NewYork", "UnitedStates"}], Quantity[600, "Miles"]]; g2 = GeoPath[{Entity["City", {"NewYork", "NewYork", "UnitedStates"}], Entity["City", {"Chicago", "Illinois", "UnitedStates"}], Entity["City", {"Toronto", "Ontario", "Canada"}]}];
Wolfram Language code: GeoLength[GeoGroup[{g1, g2}]]
Wolfram Language code: % == Total[GeoLength[{g1, g2}]]

Generalizations & Extensions  (1)

GeoLength[Line[{p1,p2,…}]] is equivalent to GeoLength[GeoPath[{p1,p2,…}]] for geo locations pi:

Wolfram Language code: GeoLength[Line[GeoPosition[{{0, 0}, {0, 40}, {40, 70}}]]]
Wolfram Language code: % == GeoLength[GeoPath[{{0, 0}, {0, 40}, {40, 70}}]]

Options  (2)

UnitSystem  (1)

Use the units determined by the value of $UnitSystem:

Wolfram Language code: $UnitSystem
Wolfram Language code: GeoLength[GeoPath["NorthernTropic"]]

Specify the unit system to use:

Wolfram Language code: GeoLength[GeoPath["NorthernTropic"], UnitSystem -> "Metric"]

GeoModel  (1)

Length of a geo path on the Earth:

Wolfram Language code: g = GeoPath[{{10, 40}, {20, 50}, {-40, 120}}]; GeoLength[g]

Length of the corresponding path on Mars:

Wolfram Language code: GeoLength[g, GeoModel -> "Mars"]

Applications  (2)

Compute the length of the boundary of a country from its polygon:

Wolfram Language code: GeoLength[GeoBoundary[Entity["Country", "Spain"]["Polygon"]]]

That value is shorter than the actual length of the boundary, due to approximations in the polygon:

Wolfram Language code: Entity["Country", "Spain"]["BoundaryLength"]

The length of a segment of parallel, or the projection on a parallel of any geo path, is called departure:

Wolfram Language code: GeoLength[GeoPath[{"Parallel", 38, {0, 5}}]]

Express it in nautical miles:

Wolfram Language code: UnitConvert[%, "NauticalMiles"]

Properties & Relations  (1)

For a geo path defined by a list of points, GeoLength[GeoPath[list]] is equivalent to GeoDistance[list]:

Wolfram Language code: list = RandomReal[{-90, 90}, {10, 2}]
Wolfram Language code: GeoLength[GeoPath[list]]
Wolfram Language code: % == GeoDistance[list]
Wolfram Research (2016), GeoLength, Wolfram Language function, https://reference.wolfram.com/language/ref/GeoLength.html.

Text

Wolfram Research (2016), GeoLength, Wolfram Language function, https://reference.wolfram.com/language/ref/GeoLength.html.

CMS

Wolfram Language. 2016. "GeoLength." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/GeoLength.html.

APA

Wolfram Language. (2016). GeoLength. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/GeoLength.html

BibTeX

@misc{reference.wolfram_2026_geolength, author="Wolfram Research", title="{GeoLength}", year="2016", howpublished="\url{https://reference.wolfram.com/language/ref/GeoLength.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_geolength, organization={Wolfram Research}, title={GeoLength}, year={2016}, url={https://reference.wolfram.com/language/ref/GeoLength.html}, note=[Accessed: 13-June-2026]}