WOLFRAM

Wolfram Language & System Documentation Center

HankelTransform[expr,r,s]

gives the Hankel transform of order 0 for expr.

HankelTransform[expr,r,s,ν]

gives the Hankel transform of order ν for expr.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Basic Uses  
Elementary Functions  
Special Functions  
Piecewise Functions and Distributions  
Options  
GenerateConditions  
Assumptions  
Applications  
Properties & Relations  
Neat Examples  
See Also
Related Guides
History
Cite this Page

HankelTransform

HankelTransform[expr,r,s]

gives the Hankel transform of order 0 for expr.

HankelTransform[expr,r,s,ν]

gives the Hankel transform of order ν for expr.

Details and Options

Examples

open all close all

Basic Examples  (2)

Compute the Hankel transform of a function:

Wolfram Language code: HankelTransform[Exp[-r], r, s]

Hankel transform for a product of functions:

Wolfram Language code: HankelTransform[Cos[r] / (1 + r ^ 2), r, s]

Scope  (16)

Basic Uses  (5)

Compute the Hankel transform of order ν for a function:

Wolfram Language code: HankelTransform[1 / r ^ 3, r, s, ν]

Use the default value 0 for the parameter ν:

Wolfram Language code: HankelTransform[1 / r ^ 3, r, s]

Compute the Hankel transform of a function for a symbolic parameter s:

Wolfram Language code: HankelTransform[Sin[r] / r, r, s]

Use an exact value for s:

Wolfram Language code: HankelTransform[Sin[r] / r, r, 1 / 3]

Use a numerical value for s:

Wolfram Language code: HankelTransform[Sin[r] / r, r, 0.23]

Obtain the conditions for the convergence:

Wolfram Language code: HankelTransform[Exp[-m r], r, s, GenerateConditions -> True]

Specify assumptions:

Wolfram Language code: HankelTransform[Exp[-m r] / r, r, s, Assumptions -> m > 0 && s ≥ 0]

Display in TraditionalForm:

Wolfram Language code: HankelTransform[f[r], r, s]//TraditionalForm
Wolfram Language code: HankelTransform[f[r], r, s, 2]//TraditionalForm

Elementary Functions  (4)

Hankel transforms of rational functions:

Wolfram Language code: HankelTransform[1 / r, r, s, ν]
Wolfram Language code: HankelTransform[1 / (r ^ 2 + a ^ 2), r, s]

Exponential and logarithmic functions:

Wolfram Language code: HankelTransform[E ^ (-r), r, s]
Wolfram Language code: HankelTransform[E ^ (-r) / r, r, s]
Wolfram Language code: HankelTransform[(1 - Exp[-m r]) / r ^ 2, r, s]
Wolfram Language code: HankelTransform[Exp[-a ^ 2 r ^ 2] / r, r, s]
Wolfram Language code: HankelTransform[Log[1 + a ^ 2 / r ^ 2], r, s]

Trigonometric functions:

Wolfram Language code: HankelTransform[Sin[r] / (b ^ 2 + r ^ 2), r, s]
Wolfram Language code: HankelTransform[Cos[r], r, s]

Algebraic functions:

Wolfram Language code: HankelTransform[1 / Sqrt[1 + r ^ 2], r, s]
Wolfram Language code: HankelTransform[1 / (1 + r ^ 2) ^ (3 / 2), r, s]
Wolfram Language code: HankelTransform[1 / (1 + r ^ 2) ^ (n / 2), r, s]//FullSimplify

Special Functions  (5)

Hankel transforms of Bessel functions:

Wolfram Language code: HankelTransform[(1 - BesselJ[0, a r]) / r ^ 2, r, s, 1]
Wolfram Language code: HankelTransform[BesselK[0, r], r, s]

Airy functions:

Wolfram Language code: HankelTransform[AiryAi[r], r, s]
Wolfram Language code: HankelTransform[AiryBi[r], r, s]

Elliptic functions:

Wolfram Language code: HankelTransform[EllipticK[r], r, s, 1]
Wolfram Language code: HankelTransform[EllipticE[r], r, s]

Error functions:

Wolfram Language code: HankelTransform[Erf[r], r, s]
Wolfram Language code: HankelTransform[Erfc[r] / r, r, s]

Integral functions:

Wolfram Language code: HankelTransform[ExpIntegralE[1, r] / r, r, s]
Wolfram Language code: HankelTransform[SinIntegral[r ^ 2], r, s]

Piecewise Functions and Distributions  (2)

Hankel transform of a piecewise function:

Wolfram Language code: HankelTransform[UnitStep[a - r], r, s]//FunctionExpand

Hankel transforms of distributions:

Wolfram Language code: HankelTransform[HeavisideTheta[a - r], r, s]//FunctionExpand
Wolfram Language code: HankelTransform[r ^ 2 DiracDelta[r - 2], r, s]

Options  (2)

GenerateConditions  (1)

Obtain conditions for validity of the result:

Wolfram Language code: HankelTransform[(1/Sqrt[r^2 + a^2]), r, s, GenerateConditions -> True]

Assumptions  (1)

Compute the Hankel transform of a function depending on a parameter a:

Wolfram Language code: HankelTransform[(1/Sqrt[r^2 + a^2]), r, s]

Obtain a simpler result by specifying assumptions on the parameter:

Wolfram Language code: HankelTransform[(1/Sqrt[r^2 + a^2]), r, s, Assumptions -> a > 0 && s ≥ 0]

Applications  (3)

The Fourier transform of a radially symmetric function in the plane can be expressed as a Hankel transform. Verify this relation for the function defined by:

Wolfram Language code: f[x_, y_] := E ^ (-Sqrt[x ^ 2 + y ^ 2])

Plot the function:

Wolfram Language code: Plot3D[f[x, y], {x, -3, 3}, {y, -3, 3}, PlotRange -> All, Mesh -> False]

Compute its Fourier transform:

Wolfram Language code: FourierTransform[f[x, y], {x, y}, {u, v}]

Obtain the same result using HankelTransform:

Wolfram Language code: HankelTransform[f[x, y] /. {x -> r Cos[m], y -> r Sin[m]}//Simplify, r, s] /.  {s -> Sqrt[u^2 + v^2]}

Plot the Fourier transform:

Wolfram Language code: Plot3D[%, {u, -3, 3}, {v, -3, 3}, PlotRange -> All, Mesh -> False]

Generate a gallery of Fourier transforms for a list of radially symmetric functions:

Wolfram Language code: flist = {(1/Sqrt[r^2 + 1]), (Sin[2 π r]/r), (1/r), E^-r, BesselJ[0, r]^2, E^-r^2};

Compute the Hankel transforms for these functions:

Wolfram Language code: tlist = FullSimplify[HankelTransform[flist, r, s], Assumptions -> 0 < s < 2]

Generate the gallery of Fourier transforms as required:

Wolfram Language code: (Grid[#1, Alignment -> {{Right, {Left}}, Center}, Spacings -> 0]&)[Table[{Text[flist[[i]] /.  {r -> Sqrt[x^2 + y^2]}], Plot3D[Evaluate[N[flist[[i]] /.  {r -> Sqrt[x^2 + y^2]}]], {x, -2, 2}, {y, -2, 2}, PlotRange -> All, Exclusions -> None, Axes -> None, Ticks -> None, Boxed -> False], Style["→︀", 24, Bold], Plot3D[Evaluate[N[tlist[[i]]] /.  {s -> Sqrt[u^2 + v^2]}], {u, -2, 2}, {v, -2, 2}, PlotRange -> All, Exclusions -> None, Axes -> None, Ticks -> None, Boxed -> False], Text[tlist[[i]] /.  {s -> Sqrt[u^2 + v^2]}]}, {i, 6}]]

Obtain a particular solution for an inhomogeneous equation involving the radial Laplacian:

Wolfram Language code: eqn = Laplacian[f[r], {r, θ}, "Polar"] == 5 / Sqrt[r];

Apply HankelTransform to the equation:

Wolfram Language code: HankelTransform[eqn, r, s]

Solve for the Hankel transform:

Wolfram Language code: sol = Solve[%, HankelTransform[f[r], r, s, 0]]

Apply InverseHankelTransform to obtain a particular solution:

Wolfram Language code: dsol = InverseHankelTransform[HankelTransform[f[r], r, s, 0] /. sol[[1]], s, r]

Verify the solution:

Wolfram Language code: eqn /. {f -> Function[{r}, Evaluate[dsol]]}//FullSimplify

Properties & Relations  (6)

Use Asymptotic to compute an asymptotic approximation:

Wolfram Language code: Asymptotic[Inactive[HankelTransform][E ^ (-r), r, s], s -> 0]

HankelTransform computes the integral int_0^inftyr f(r) TemplateBox[{nu, {r, , s}}, BesselJ]dr:

Wolfram Language code: f[r_] := 1 / r
Wolfram Language code: HankelTransform[f[r], r, s, ν]
Wolfram Language code: Integrate[r f[r] BesselJ[ν, r s], {r, 0, ∞}, Assumptions -> s > 0 && ν > 0]

HankelTransform is its own inverse:

Wolfram Language code: f[r_] := E ^ (-r)
Wolfram Language code: HankelTransform[f[r], r, s]
Wolfram Language code: HankelTransform[%, s, r]

HankelTransform is a linear operator:

Wolfram Language code: HankelTransform[a f[r] + b g[r], r, s]

Hankel transform of a derivative:

Wolfram Language code: HankelTransform[Derivative[1][f][r], r, s, ν]

Derivative of a Hankel transform with respect to s:

Wolfram Language code: D[HankelTransform[f[r], r, s, ν], s]

Neat Examples  (1)

Create a table of basic Hankel transforms:

Wolfram Language code: flist = {UnitStep[a - r], 1 / r, 1 / Sqrt[1 + r ^ 2], Log[1 + a ^ 2 / r ^ 2], Sin[r] / (1 + r ^ 2), E ^ (-a r), E ^ (-r ^ 2), 1 / (E ^ (2r ^ 2) * r)};
Wolfram Language code: Grid[Join[{{f[r], HankelTransform[f[r], r, s]}}, Transpose[{flist, Map[HankelTransform[#, r, s]&, flist]}]], IconizedObject[«Grid options»]]//TraditionalForm
Wolfram Research (2017), HankelTransform, Wolfram Language function, https://reference.wolfram.com/language/ref/HankelTransform.html.

Text

Wolfram Research (2017), HankelTransform, Wolfram Language function, https://reference.wolfram.com/language/ref/HankelTransform.html.

CMS

Wolfram Language. 2017. "HankelTransform." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/HankelTransform.html.

APA

Wolfram Language. (2017). HankelTransform. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/HankelTransform.html

BibTeX

@misc{reference.wolfram_2026_hankeltransform, author="Wolfram Research", title="{HankelTransform}", year="2017", howpublished="\url{https://reference.wolfram.com/language/ref/HankelTransform.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_hankeltransform, organization={Wolfram Research}, title={HankelTransform}, year={2017}, url={https://reference.wolfram.com/language/ref/HankelTransform.html}, note=[Accessed: 13-June-2026]}