WOLFRAM

Wolfram Language & System Documentation Center

HazardFunction[dist,x]

gives the hazard function for the distribution dist evaluated at x.

HazardFunction[dist,{x1,x2,…}]

gives the multivariate hazard function for the distribution dist evaluated at {x1,x2,…}.

HazardFunction[dist]

gives the hazard function as a pure function.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Parametric Distributions  
Nonparametric Distributions  
Derived Distributions  
Random Processes  
Generalizations & Extensions  
Applications  
Properties & Relations  
Possible Issues  
See Also
Related Guides
History
Cite this Page

HazardFunction

HazardFunction[dist,x]

gives the hazard function for the distribution dist evaluated at x.

HazardFunction[dist,{x1,x2,…}]

gives the multivariate hazard function for the distribution dist evaluated at {x1,x2,…}.

HazardFunction[dist]

gives the hazard function as a pure function.

Details

  • HazardFunction is also known as a force of mortality.
  • For continuous distributions, HazardFunction[dist,x] dx gives the probability that an observed value lies between x and x+dx, given that it is larger than x for infinitesimal dx.
  • For continuous distributions, HazardFunction[dist,x] dx is equivalent to Probability[x≤ξ<x+dxξ≥x,ξdist] for infinitesimal dx. »
  • For discrete distributions, HazardFunction[dist,x] is equivalent to Probability[ξxξ≥x,ξdist].
  • For continuous multivariate distributions, HazardFunction[dist,{x1,…,xn}]dx1 ⋯ dxn is equivalent to Probability[x1≤ξ1<x1+dx1∧⋯∧xn≤ξn<xn+dxnξ1≥x1∧⋯∧ξn≥xn,{ξ1,…,ξn}dist].
  • For discrete multivariate distributions, HazardFunction[dist,{x1,…,xn}] is equivalent to Probability[ξ1x1∧⋯ ∧ξnxnξ1≥x1∧⋯∧ξn≥xn,{ξ1,…,ξn}dist].

Examples

open all close all

Basic Examples  (4)

A hazard function for a continuous univariate distribution:

Wolfram Language code: HazardFunction[WeibullDistribution[1 / 2, 2], x]
Wolfram Language code: Plot[%, {x, 0, 3}, Filling -> Axis]

The hazard function for a discrete univariate distribution:

Wolfram Language code: HazardFunction[PoissonDistribution[2], x]
Wolfram Language code: DiscretePlot[%, {x, 0, 20}, ExtentSize -> 0.5]

A hazard function for a continuous multivariate distribution:

Wolfram Language code: Plot3D[HazardFunction[BinormalDistribution[1 / 2], {x, y}], {x, -1, 3}, {y, -1, 3}, PlotRange -> All, MaxRecursion -> 0]

A hazard function for a discrete multivariate distribution:

Wolfram Language code: DiscretePlot3D[HazardFunction[MultivariatePoissonDistribution[1, {2, 3}], {x, y}], {x, 0, 20}, {y, 0, 20}, ExtentSize -> 0.5]

Scope  (22)

Parametric Distributions  (8)

Obtain exact numeric results:

Wolfram Language code: HazardFunction[WeibullDistribution[2, 5], 4]
Wolfram Language code: HazardFunction[NegativeBinomialDistribution[20, 1 / 3], 5]

Obtain a machine-precision result:

Wolfram Language code: HazardFunction[WeibullDistribution[2, 5], 4.]

Obtain a result at any precision for a continuous distribution:

Wolfram Language code: HazardFunction[WeibullDistribution[2, 5], N[4, 25]]

Obtain a result at any precision for a discrete distribution with inexact parameters:

Wolfram Language code: HazardFunction[NegativeBinomialDistribution[20, N[1 / 3, 30]], 1]

Hazard function for a multivariate distribution:

Wolfram Language code: HazardFunction[DirichletDistribution[{2, 4, 5}], {1 / 5, 2 / 3}]

Obtain a symbolic expression for the hazard function:

Wolfram Language code: HazardFunction[ChiSquareDistribution[ν], x]
Wolfram Language code: HazardFunction[UniformDistribution[{{a, b}, {c, d}}], {x, y}]

Obtain pure function result:

Wolfram Language code: HazardFunction[GammaDistribution[1, 2]]

Evaluate at a value:

Wolfram Language code: %[3]

HazardFunction threads elementwise over lists:

Wolfram Language code: HazardFunction[NormalDistribution[], {0.0, 0.2, 0.3}]

Multivariate distributions:

Wolfram Language code: HazardFunction[BinormalDistribution[1 / 2], {{0.0, 0.0}, {0.2, 0.2}, {0.3, 0.3}}]

Nonparametric Distributions  (3)

Hazard function for nonparametric distributions:

Wolfram Language code: r = RandomVariate[NormalDistribution[], 10 ^ 4];
Wolfram Language code: HazardFunction[HistogramDistribution[r], 0.2]
Wolfram Language code: HazardFunction[SmoothKernelDistribution[r], 0.2]
Wolfram Language code: HazardFunction[KernelMixtureDistribution[r], 0.2]

Compare with the value for the underlying parametric distribution:

Wolfram Language code: HazardFunction[NormalDistribution[], 0.2]

Plot the survival function for a histogram distribution:

Wolfram Language code: dist = HistogramDistribution[RandomVariate[NormalDistribution[], 10 ^ 3]];
Wolfram Language code: Plot[HazardFunction[dist, x]//Evaluate, {x, -3, 3}, Filling -> Axis, Exclusions -> None]

Plot of the survival function of a bivariate smooth kernel distribution:

Wolfram Language code: dist = SmoothKernelDistribution[RandomVariate[BinormalDistribution[1 / 3], 30]];
Wolfram Language code: Plot3D[HazardFunction[dist, {x, y}]//Evaluate, {x, -4, 4}, {y, -4, 4}, PlotRange -> All]

Derived Distributions  (8)

Product of independent distributions:

Wolfram Language code: hf = HazardFunction[ProductDistribution[TriangularDistribution[{2, 4}], TriangularDistribution[{1, 7}]], {x, y}]
Wolfram Language code: Plot3D[hf, {x, 1, 5}, {y, 0, 8}, PlotRange -> {0, 100}]

Component mixture distribution:

Wolfram Language code: hf = HazardFunction[MixtureDistribution[{1, 4}, {NormalDistribution[a, b], NormalDistribution[c, d]}], x]
Wolfram Language code: Plot[hf /. {a -> 0, b -> 1, c -> 6, d -> 3 / 2}, {x, -2, 6}, Filling -> Axis]

Quadratic transformation of a discrete distribution:

Wolfram Language code: HazardFunction[TransformedDistribution[x ^ 2, xExponentialDistribution[2]], y]
Wolfram Language code: Plot[%, {y, 0, 8}, Filling -> Axis, AxesOrigin -> {0, 0}]

Truncated distribution:

Wolfram Language code: hf = HazardFunction[TruncatedDistribution[{2, 3}, TriangularDistribution[{1, 4}]], x]
Wolfram Language code: Plot[hf, {x, 1.5, 5}, Filling -> Axis]

A copula distribution:

Wolfram Language code: HazardFunction[CopulaDistribution[{"AMH", 1 / 3}, {UniformDistribution[{2, 4}], UniformDistribution[{3, 7}]}], {x, y}]//Simplify

Formula distributions defined by its PDF:

Wolfram Language code: HazardFunction[ProbabilityDistribution[UnitBox[x], {x, -Infinity, Infinity}], x]//FullSimplify

Defined by its CDF:

Wolfram Language code: HazardFunction[ProbabilityDistribution[{"CDF", Piecewise[{{-2 + x, 2 ≤ x ≤ 3}, {1, x > 3}}, 0]}, {x, -Infinity, Infinity}], x]

Defined by its survival function:

Wolfram Language code: HazardFunction[ProbabilityDistribution[{"SF", Piecewise[{{1 - 2(-2 + x) ^ 2, 2 ≤ x ≤ 5 / 2}, {2(3 - x) ^ 2, 5 / 2 < x ≤ 3}, {1, x < 2}}, 0]}, {x, -Infinity, Infinity}], x]

Marginal distribution:

Wolfram Language code: HazardFunction[MarginalDistribution[ ProbabilityDistribution[1 / (E ^ (y ^ 2 / 2)(Pi ^ (3 / 2) * (1 + x ^ 4))), {x, -Infinity, Infinity}, {y, -Infinity, Infinity}], 2], y]

Hazard function for QuantityDistribution assumes the argument is a Quantity with compatible units:

Wolfram Language code: 𝒟 = NormalDistribution[Quantity[4, "Meters"], Quantity[1 / 2, "Meters"]]
Wolfram Language code: HazardFunction[𝒟, x]

This allows for direct quantity substitution:

Wolfram Language code: % /. x -> Quantity[387., "Centimeters"]

Compare with direct use of quantity argument:

Wolfram Language code: HazardFunction[𝒟, Quantity[387., "Centimeters"]]

Random Processes  (3)

Find the hazard function for a SliceDistribution of a discrete-state random process:

Wolfram Language code: HazardFunction[PoissonProcess[μ][2], x]
Wolfram Language code: DiscretePlot[Evaluate[% /. μ -> 2], {x, 0, 10}, ExtentSize -> 0.5]

A continuous-state random process:

Wolfram Language code: HazardFunction[WienerProcess[][2], x]
Wolfram Language code: Plot[%, {x, -1, 6}, Filling -> Axis]

Find the multiple time-slice hazard function for a discrete-state process:

Wolfram Language code: HazardFunction[PoissonProcess[μ][{2, 3}], {1, 2}]
Wolfram Language code: DiscretePlot3D[Evaluate[HazardFunction[PoissonProcess[1][{2, 3}], {x, y}]], {x, 0, 10}, {y, 0, 10}, ExtentSize -> 0.5]

A multi-slice for a continuous-state process:

Wolfram Language code: Plot3D[HazardFunction[WienerProcess[][{2, 3}], {x, y}], {x, -3, 3}, {y, -3, 3}, PlotRange -> All]

Hazard function for the StationaryDistribution of a discrete-state random process:

Wolfram Language code: HazardFunction[StationaryDistribution[QueueingProcess[λ, μ, Infinity]], x]//FullSimplify
Wolfram Language code: DiscretePlot[Evaluate[% /. {μ -> 7, λ -> 2.9}], {x, 1, 8}, ExtentSize -> 0.5]

Generalizations & Extensions  (1)

HazardFunction threads element-wise over lists:

Wolfram Language code: HazardFunction[NormalDistribution[], {0.2, 0.3}]
Wolfram Language code: {HazardFunction[NormalDistribution[], 0.2], HazardFunction[NormalDistribution[], 0.3]}

Multivariate distributions:

Wolfram Language code: HazardFunction[BinormalDistribution[1 / 2], {{0.0, 0.0}, {0.2, 0.2}, {0.3, 0.3}}]

Applications  (4)

Find the mortality rate for lifetime distributions including exponential distribution:

Wolfram Language code: Refine[HazardFunction[ExponentialDistribution[λ], x], x ≥ 0]

Gompertz distribution:

Wolfram Language code: HazardFunction[GompertzMakehamDistribution[λ, ξ], x]

Given the reliability function of a component, compute its failure rate:

Wolfram Language code: R[t_] = Exp[-t ^ 2];

Define the corresponding probability distribution:

Wolfram Language code: 𝒟 = ProbabilityDistribution[{"SF", R[t]}, {t, 0, ∞}];

Compute the failure rate using the distribution:

Wolfram Language code: FailureRate = HazardFunction[𝒟, t]

Study the hazard function for a family of Weibull distributions:

Wolfram Language code: w[α_, 1] := WeibullDistribution[α, 1]
Wolfram Language code: hf[α_, x_] = HazardFunction[w[α, 1], x]

With , used is better than new:

Wolfram Language code: Plot[Table[hf[α, x], {α, {0.2, 0.3, 0.7}}]//Evaluate, {x, 0, 3}]

With , used is as good as new:

Wolfram Language code: Plot[hf[1, x], {x, 0, 3}]

With , used is worse than new:

Wolfram Language code: Plot[Table[hf[α, x], {α, {1.6, 2.3, 3.1}}]//Evaluate, {x, 0, 2}]

A casino offers you a game where you pay amount to participate and then choose a stake amount . A positive continuous random variable following a known distribution is then generated. If you collect the stake; otherwise you lose. Find the value that maximizes the profit:

Wolfram Language code: ExpectedGain = c SurvivalFunction[𝒟, c] - P;

Find the equation for the maximum of the expected gain:

Wolfram Language code: D[ExpectedGain, c] == 0 /. {D[SurvivalFunction[𝒟, c], c] -> -SurvivalFunction[𝒟, c] HazardFunction[𝒟, c]}
Wolfram Language code: eq = Simplify[%, SurvivalFunction[𝒟, c] > 0]

Assuming WeibullDistribution, find the optimal stake size:

Wolfram Language code: Solve[(eq /. 𝒟 -> WeibullDistribution[α, β]), c, Reals]
Wolfram Language code: ExpectedGain /. 𝒟 -> WeibullDistribution[α, β] /. %//Simplify

Properties & Relations  (3)

Compute the hazard function using the definition as conditional probability:

Wolfram Language code: Probability[x ≤ ξ < x + dxξ ≥ x, ξExponentialDistribution[λ]] / dx
Wolfram Language code: Limit[%, dx -> 0, Assumptions -> λ > 0 && x > 0]

The hazard function is a ratio of the PDF and the survival function :

Wolfram Language code: HazardFunction[NormalDistribution[], x]
Wolfram Language code: PDF[NormalDistribution[], x] / SurvivalFunction[NormalDistribution[], x]

The hazard rate of an exponential distribution is constant:

Wolfram Language code: Refine[HazardFunction[ExponentialDistribution[λ], x], x ≥ 0]

Possible Issues  (2)

Symbolic closed forms do not exist for some distributions:

Wolfram Language code: HazardFunction[StableDistribution[0, 1.8, -0.5, 1, 2], x]

Numerical evaluation works:

Wolfram Language code: HazardFunction[StableDistribution[0, 1.8, -0.5, 1, 2], 0.3]

Substitution of invalid values into symbolic outputs gives results that are not meaningful:

Wolfram Language code: HazardFunction[CauchyDistribution[2, 3], y] /. {y -> 1. + I}

Passing it as an argument, it stays unevaluated:

Wolfram Language code: HazardFunction[CauchyDistribution[2, 3], 1. + I]
Wolfram Research (2010), HazardFunction, Wolfram Language function, https://reference.wolfram.com/language/ref/HazardFunction.html.

Text

Wolfram Research (2010), HazardFunction, Wolfram Language function, https://reference.wolfram.com/language/ref/HazardFunction.html.

CMS

Wolfram Language. 2010. "HazardFunction." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/HazardFunction.html.

APA

Wolfram Language. (2010). HazardFunction. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/HazardFunction.html

BibTeX

@misc{reference.wolfram_2026_hazardfunction, author="Wolfram Research", title="{HazardFunction}", year="2010", howpublished="\url{https://reference.wolfram.com/language/ref/HazardFunction.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_hazardfunction, organization={Wolfram Research}, title={HazardFunction}, year={2010}, url={https://reference.wolfram.com/language/ref/HazardFunction.html}, note=[Accessed: 13-June-2026]}