WOLFRAM

Wolfram Language & System Documentation Center

ImageLines[image]

finds line segments in image and returns the coordinates of their endpoints.

ImageLines[image,t]

uses the threshold t for selecting image lines.

ImageLines[image,t,d]

uses the parameter d to control the distinctness of the detected lines.

ImageLines[video,…]

finds lines in frames of video.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Options  
MaxFeatures  
Method  
Applications  
Possible Issues  
See Also
Related Guides
History
Cite this Page

ImageLines

ImageLines[image]

finds line segments in image and returns the coordinates of their endpoints.

ImageLines[image,t]

uses the threshold t for selecting image lines.

ImageLines[image,t,d]

uses the parameter d to control the distinctness of the detected lines.

ImageLines[video,…]

finds lines in frames of video.

Details and Options

  • ImageLines returns a list of line segments in the form Line[{p1,p2}], where each pi={xi,yi} is expressed in the standard image coordinate system.
  • ImageLines[image,t] finds lines in the image whose normalized strength is larger than the specified threshold t.
  • ImageLines sorts the result based on the normalized strength.
  • In ImageLines[image,t,d], the parameter d controls how close lines are suppressed. If the value is set to zero, all detected lines are returned. With d set to 1, only the strongest line may be returned.
  • The following options can be given:
  • MaxFeatures Allmaximum number of features to return
    Method "Hough"method to detect lines
  • With a setting MaxFeatures->n, at most n lines with largest normalized strength are returned.
  • Possible line detection methods are:
  • "Hough"lines based on Hough transform (default)
    "RANSAC"lines using the RANSAC algorithm
  • With Method->"Hough", lines are detected by iteratively selecting the strongest peaks in the Hough transform. Using the distinctness parameter, peaks that are within a rectangular range from the already selected peaks are excluded from the set of line candidates.
  • With Method->"RANSAC", lines are detected using random sampling. For each sampling, pixels that are within a distance specified by the distinctness parameter d are used for computing the strength of the line. The pixels on the selected line are not used in the following iterations.
  • By default, ImageLines returns lines that span from border to border. With a setting Method->{"Segmented"->True}, detected lines may be divided into smaller line segments.

Examples

open all close all

Basic Examples  (1)

Detect and visualize straight lines in an image:

Wolfram Language code: i = [image]; lines = ImageLines[i, 1 / 3]

Highlight detected lines:

Wolfram Language code: HighlightImage[i, lines]

Scope  (2)

Specify the distinctness parameter:

Wolfram Language code: ImageLines[[image], .2, .2]

Detect the line going through the foreground pixels:

Wolfram Language code: ImageLines[[image], .05]

Options  (3)

MaxFeatures  (1)

Specify the maximum number of lines to be to be detected:

Wolfram Language code: img = [image]; lines = ImageLines[EdgeDetect[img], MaxFeatures -> 5]
Wolfram Language code: HighlightImage[img, {Orange, lines}]

Method  (2)

By default, lines are detected using Method->"Hough":

Wolfram Language code: img = [image]; lines = ImageLines[img, .23, Method -> "Hough"]; HighlightImage[img, lines]

Use a random sampling method:

Wolfram Language code: lines = ImageLines[img, .23, Method -> "RANSAC"]; HighlightImage[img, lines]

Detect segmented lines in a grayscale image:

Wolfram Language code: img = [image]; lines = ImageLines[img, .2, Method -> {"Hough", "Segmented" -> True}]; HighlightImage[img, lines, ImageSize -> 240]

Segmented lines using the random sampling method:

Wolfram Language code: lines = ImageLines[img, .23, Method -> {"RANSAC", "Segmented" -> True}];HighlightImage[img, lines, ImageSize -> 240]

Applications  (6)

Detect and visualize straight trajectories in a bubble chamber image:

Wolfram Language code: img = [image]; lines = ImageLines[img]; HighlightImage[img, lines]

Detect segments on a color image:

Wolfram Language code: img = [image]; lines = ImageLines[img, .53, .03, Method -> {"Segmented" -> True}]; HighlightImage[img, {Black, lines}, ImageSize -> 320]

Visualize vanishing points:

Wolfram Language code: img = [image]; lines = ImageLines[EdgeDetect[img], .28, .06]; HighlightImage[img, lines]

Detect segments on a gradient magnitude map:

Wolfram Language code: img = [image]; lines = ImageLines[ImageAdjust@GradientFilter[img, 3, Method -> {"NonMaxSuppression" -> True}], .09, Method -> {"Segmented" -> True}]; HighlightImage[img, {Yellow, lines}]

Find wide lines using edge detection:

Wolfram Language code: img = [image]; lines = ImageLines[EdgeDetect[img, 13], .18]; HighlightImage[img, lines]

Straighten the tower of Pisa:

Wolfram Language code: image = [image];

Compute the gradient of the image to highlight edges:

Wolfram Language code: (g = GradientFilter[image, 2])//ImageAdjust

Find the most significant straight lines in the gradient image:

Wolfram Language code: HighlightImage[image, lines = ImageLines[g, MaxFeatures -> 10]]

FInd the angles corresponding to each line:

Wolfram Language code: angles = Mod[ArcTan@@@Flatten[Differences@@@lines, 1], π]

Compute the average angle of the vertical lines:

Wolfram Language code: θ = Mean@Select[angles, Abs[# - π / 2] < π / 4&]

Rotate the image by to make almost-vertical lines vertical:

Wolfram Language code: ImageRotate[image, π / 2 - θ]

Possible Issues  (2)

Use the distinctness parameter to prevent detecting duplicated lines:

Wolfram Language code: Length@ImageLines[[image], .1, #]& /@ {0, .1}

Thin lines in binary images might not be correctly detected:

Wolfram Language code: i = [image];
Wolfram Language code: lines = ImageLines[i, MaxFeatures -> 3, Method -> {"Segmented" -> True}]; HighlightImage[i, lines]

Blurring the image typically improves line detection:

Wolfram Language code: lines = ImageLines[Blur[i], MaxFeatures -> 3, Method -> {"Segmented" -> True}]; HighlightImage[i, lines]

Rescaling the image to a larger size might also help in some cases:

Wolfram Language code: i2 = ImageResize[i, Scaled[2]];
Wolfram Language code: lines = ImageLines[i2, MaxFeatures -> 3, Method -> {"Segmented" -> True}]; HighlightImage[i2, lines]
Wolfram Research (2010), ImageLines, Wolfram Language function, https://reference.wolfram.com/language/ref/ImageLines.html (updated 2025).

Text

Wolfram Research (2010), ImageLines, Wolfram Language function, https://reference.wolfram.com/language/ref/ImageLines.html (updated 2025).

CMS

Wolfram Language. 2010. "ImageLines." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2025. https://reference.wolfram.com/language/ref/ImageLines.html.

APA

Wolfram Language. (2010). ImageLines. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ImageLines.html

BibTeX

@misc{reference.wolfram_2026_imagelines, author="Wolfram Research", title="{ImageLines}", year="2025", howpublished="\url{https://reference.wolfram.com/language/ref/ImageLines.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_imagelines, organization={Wolfram Research}, title={ImageLines}, year={2025}, url={https://reference.wolfram.com/language/ref/ImageLines.html}, note=[Accessed: 13-June-2026]}